Hoe stuurt u een agenda-indeling individueel naar meerdere ontvangers in Outlook?

Normaal gesproken kunt u een agenda snel en eenvoudig naar één ontvanger sturen met de functie Agenda per e-mail verzenden in Outlook. Als u een agenda als iCalendar-bestand individueel aan meerdere contacten wilt sturen, moet u dit helaas één voor één doen. In dit artikel bespreek ik een eenvoudige methode om een agenda toch individueel naar meerdere ontvangers te sturen in Outlook.

Stuur een agenda individueel naar meerdere ontvangers met VBA-code

---

Stuur een agenda individueel naar meerdere ontvangers met VBA-code

Om een agenda afzonderlijk naar meerdere ontvangers te sturen, helpt de volgende VBA-code u daarbij. Volg deze stappen:

1. Navigeer naar het Contacten-deelvenster en selecteer de contacten waarnaar u de agenda wilt sturen.

2. Houd vervolgens de toetsencombinatie ALT + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

3. Klik op Invoegen > Module en kopieer de onderstaande code naar de geopende lege module (zie schermafbeelding):

VBA-code: Stuur een agenda individueel naar meerdere ontvangers:

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. Nadat u de code hebt ingevoegd, drukt u op de toets F5 om deze code uit te voeren. Er verschijnt dan het dialoogvenster Map selecteren, waarin u de agenda selecteert die u wilt verzenden (zie schermafbeelding):

5.Klik op OKen geef vervolgens het Datumreeks op dat u wilt gebruiken voor het verzenden van de agenda in de volgende pop-upvensters (zie schermafbeelding):

6. Klik daarna op OK, waarna e-mails met de bijgevoegde agenda worden gemaakt, zoals op de volgende schermafbeelding is weergegeven. U hoeft ze daarna alleen nog maar één voor één te verzenden.

---

Gerelateerde artikelen:

Hoe stuurt u individueel een e-mail naar meerdere ontvangers in Outlook?

Hoe stuurt u gepersonaliseerde bulkmails vanuit Excel naar een lijst via Outlook?

Hoe verzendt u meerdere concepten tegelijk in Outlook?

Hoe stuurt u een e-mail naar meerdere ontvangers in Outlook zonder dat zij van elkaars ontvangst weten?