Hoe de categorie te behouden tijdens het beantwoorden of doorsturen van e-mail in Outlook? 

Normaal gesproken, wanneer u een e-mail beantwoordt of doorstuurt die ik heb gecategoriseerd, wordt de categorie automatisch verwijderd uit de verzonden e-mail. Als u de categorie op uitgaande e-mails wilt behouden bij het beantwoorden of doorsturen, zal dit artikel een methode introduceren om hiermee om te gaan.

Houd categorie bij het beantwoorden of doorsturen van e-mail met VBA-code

---

Houd categorie bij het beantwoorden of doorsturen van e-mail met VBA-code

1. Houd de toets ingedrukt ALT + F11 toetsen om de te openen Microsoft Visual Basic voor toepassingen venster.

2. In de Microsoft Visual Basic voor toepassingen venster, dubbelklik DezeOutlookSessie van de Project1 (VbaProject.OTM) deelvenster om de modus te openen en kopieer en plak vervolgens de volgende code in de lege module.

VBA-code: categorie behouden tijdens het beantwoorden of doorsturen van e-mail:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Sla vervolgens dit codevenster op en sluit het, sluit en start Outlook opnieuw, nu, wanneer u een e-mail beantwoordt of doorstuurt met een categorie, wordt de categorie bewaard in het uitgaande bericht in Verzonden items, zie screenshot: