Hoe reageert u doorgaans op e-mails in de map Verzonden items vanuit Outlook?

Normaal gesproken wordt uw eigen E-mailadres weergegeven in het Aan-veld wanneer u op de functie Beantwoorden klikt in de map Verzonden Items om een extra bericht te sturen naar de personen waarnaar u al hebt gestuurd, zoals op de volgende schermafbeelding is te zien. Dit kan vervelend zijn omdat u telkens het adres moet wijzigen. Hoe kunt u Outlook zo instellen dat het het oorspronkelijke ontvangeradres gebruikt in plaats van het uwe?

Reageer normaal op e-mails in de map Verzonden Items vanuit Outlook met de functie Allen beantwoorden

Reageer normaal op e-mails in de map Verzonden Items vanuit Outlook met VBA-code

---

Reageer normaal op e-mails in de map Verzonden Items vanuit Outlook met de functie Allen beantwoorden

In Outlook helpt de Allen beantwoorden-functie u dit probleem op te lossen. Volg deze stappen:

Wanneer u de verzonden e-mail opnieuw wilt beantwoorden en het oorspronkelijke ontvangeradres wilt behouden, klikt u op de knop Allen beantwoorden, en het oorspronkelijke ontvangeradres verschijnt dan in het Aan-veld, zoals op de volgende schermafbeelding wordt getoond:

---

Reageer normaal op e-mails in de map Verzonden Items vanuit Outlook met VBA-code

Soms vergeet u misschien de Allen beantwoorden-functie te gebruiken bij het beantwoorden van een verzonden bericht. Met de onderstaande VBA-code reageert u dan gewoon in de map Verzonden items via de Beantwoorden-functie. Volg deze stappen:

1. Houd de toetsen ALT + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

2. Dubbelklik in het venster Microsoft Visual Basic for Applications op ThisOutlookSession in het deelvenster Project1 (VbaProject.OTM) om de module te openen, en kopieer en plak vervolgens de volgende code in de lege module.

VBA-code: Reageer normaal op e-mails in de map Verzonden Items vanuit Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Sla de code op en start Outlook opnieuw, zodat de wijziging van kracht wordt. Vanaf nu wordt, wanneer u op Beantwoorden klikt om een e-mail opnieuw te verzenden vanuit de map Verzonden Items, het oorspronkelijke ontvangeradres weergegeven in het Aan-veld—precies zoals gewenst.