Hoe verbergt u het faxnummer in de Selecteer Namenlijst in Outlook?

In Outlook heeft u misschien gemerkt dat de kolom E-mailadres in de lijst „Namen selecteren” of in het Adresboek niet alleen e-mailadressen bevat, maar ook faxnummers — wat behoorlijk hinderlijk kan zijn. In dit artikel laat ik u enkele manieren zien om die faxnummers voor uzelf te verbergen.

Faxnummer verbergen in Selecteer Namenlijst met VBA

---

Faxnummer verbergen in Selecteer Namenlijst met VBA

Als u het bestaande faxnummer in Selecteer Namenlijst wilt verbergen, volgt u deze stappen:

1. Druk op Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

2. Klik op Invoegen > Module om een nieuwe lege module in te voegen en plak de onderstaande code in het script.

VBA: Bestaand faxnummer verbergen in Namen selecteren

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. Druk op F5 om de code uit te voeren; de faxnummers zijn nu verborgen.

Als u het faxnummer in Contactpersoon wilt verbergen, volgt u deze stappen:

1. Druk op Alt + F11om het venster Microsoft Visual Basic for Applicationste openen.

2. Dubbelklik op ThisOutlookSession in het deelvenster Project-1 en plak de onderstaande code in het script.

VBA: Faxnummer verbergen bij nieuwe Contact toevoegen

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. Sla de code op en start Outlook opnieuw om de code te activeren.

Vanaf nu worden faxnummers van nieuw aangemaakte contactpersonen standaard verborgen in het venster „Namen selecteren: Contactpersonen”.