Hoe zoekt en vervangt u het onderwerp van afspraken in uw Outlook-agenda?

Zoeken en vervangen van het onderwerp van afspraken in de Outlook-agenda is handig als u merkt dat bepaalde onderwerpen in bulk moeten worden vervangen door dezelfde tekst, of wanneer u het woord „Copy” uit het onderwerpveld wilt verwijderen na het importeren van gegevens in Outlook. Dit artikel biedt u VBA-code om meerdere afspraakonderwerpen te zoeken en te vervangen — lees verder voor meer informatie.

Zoek en vervang het onderwerp van afspraken met VBA-code

---

Zoek en vervang het onderwerp van afspraken met VBA-code

In deze sectie kunt u het onderwerp van afspraken zoeken en vervangen met de volgende VBA-code.

1. Stel eerst de macro-beveiligingsinstellingen in Outlook in op Laag.

1) Klik in Outlook 2010 en 2013 op **Bestand** > **Opties**. Selecteer in het dialoogvenster **Outlook-opties** **Trustcentrum** in de linkerzijbalk en klik daarna op de knop **Trustcentruminstellingen**.

Klik in het dialoogvenster „Trustcentrum” op „Macro-instellingen” in de linkerzijbalk, selecteer daarna de optie „Alle macro’s inschakelen” in het gedeelte „Macro-instellingen” en klik op „OK”. Zie schermafbeelding:

2) Klik in Outlook 2007 op **Extra** > **Trustcentrum**. In het dialoogvenster **Trustcentrum**, klikt u in de linkerzijbalk op **Macro-instellingen**, selecteert u de optie **Geen beveiligingscontrole voor macro’s** en klikt u op **OK**.

2. Druk op de toetsencombinatie Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

3. Dubbelklik in het venster „Microsoft Visual Basic for Applications” om achtereenvolgens „Project1” > „Microsoft Outlook-objecten” > „ThisOutlookSession” uit te vouwen en de VBA-editor te openen. Zie schermafbeelding:

4. Kopieer en plak de volgende VBA-code in de VBA-editor en druk op F5 om de code direct uit te voeren.

VBA: Zoeken en Vervangen onderwerp van afspraken

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5. Na het uitvoeren van de code verschijnt het dialoogvenster „Microsoft Outlook” – klik op „OK”.

6. Voer in het tweede Microsoft Outlook-dialoogvenster de tekst in die u wilt vervangen en klik op „OK”.

7. Voer in het derde Microsoft Outlook-dialoogvenster de tekst in die u als vervanging wilt gebruiken en klik op „OK”.

Opmerking: Als u alleen alle „Copy”-woorden uit het onderwerp in de opgegeven agenda wilt verwijderen, laat dit vak dan leeg.

8. Klik op de knop „OK” in het dialoogvenster hieronder.

9. Selecteer in het dialoogvenster „Map selecteren” uw agenda onder het opgegeven e-mailaccount en klik op „OK”. Zie de schermafbeelding:

10. Vervolgens verschijnt een dialoogvenster met de melding dat de vervanging is geslaagd. Klik op „OK”.

11. Vervolgens worden alle teksten in de onderwerpen van de geselecteerde agenda automatisch vervangen door de nieuwe inhoud.