Hoe verkrijgt u een lijst met mappen in Outlook?

Soms ondersteunt de boomstructuur van alle e-mailmappen – inclusief uw persoonlijke mappen – Outlook-gebruikers tijdens hun werk. Met VBA-code kunt u de volledige mapboomstructuur snel weergeven. In deze handleiding leert u hoe u eenvoudig een lijst met mappen maakt met behulp van VBA-code.

Verkrijg een lijst met mappen in Outlook met VBA-code

---

Verkrijg een lijst met mappen in Outlook met VBA-code

Volg deze stappen om met VBA-code een lijst van mappen in Outlook te verkrijgen.

1. Druk op de toetsencombinatie Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

2. Dubbelklik vervolgens op „Project1” > „Microsoft Outlook-object” > „ThisOutlookSession” om het venster „Project1 – ThisOutlookSession” te openen. Zie de schermafbeelding:

3. Kopieer en plak vervolgens de onderstaande VBA-code in het venster „Project1 – ThisOutlookSession”.

VBA: verkrijg een lijst met mappen in Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. Druk op de F5-toets om de VBA-code uit te voeren.

5. Er verschijnt nu een „Macro”-dialoogvenster; klik op de knop „Uitvoeren”.

6. Wacht tot de macro is uitgevoerd. Vervolgens verschijnt de lijst met al uw e-mailmappen direct in een nieuw berichtvenster – klaar om eenvoudig te worden afgedrukt. Zie schermafbeelding:

Opmerking: Deze VBA-code werkt in Outlook 2007, 2010 en 2013.