Excel VLOOKUP-functie

De Excel-functie VERT.ZOEKEN is een krachtig hulpmiddel waarmee u een opgegeven waarde verticaal zoekt in de eerste kolom van een tabel of bereik en vervolgens de bijbehorende waarde uit een andere kolom in dezelfde rij ophaalt. Hoewel VERT.ZOEKEN uiterst nuttig is, kan het voor beginners soms lastig te begrijpen zijn. Deze handleiding helpt u de functie onder de knie te krijgen met een stapsgewijze uitleg van de argumenten, handige voorbeelden en oplossingen voor veelvoorkomende fouten die u kunt tegenkomen bij het gebruik van VERT.ZOEKEN.

• Stapsgewijze uitleg van argumenten
• Syntaxis en argumenten
• VLOOKUP-voorbeelden
  Exacte overeenkomst versus benaderende overeenkomst|VLOOKUP met meerdere voorwaarden
• Veelvoorkomende VLOOKUP-fouten & oplossingen
  #N/B-fout|#WAARDE-fout|#VERW-fout|Onjuiste waarde

VERT.ZOEKEN-voorbeelden.xlsx VERT.ZOEKEN-fouten.xlsx

Gerelateerde video's

Stapsgewijze uitleg van argumenten

Zoals in de bovenstaande schermafbeelding te zien is, wordt de VERT.ZOEKEN-functie gebruikt om een e-mailadres op te halen op basis van een opgegeven ID-nummer. Ik leg nu stap voor stap elk argument uit, zodat u precies begrijpt hoe u VERT.ZOEKEN in dit voorbeeld toepast.

Stap 1: Start de VERT.ZOEKEN-functie

Selecteer een cel (H6 in dit geval) om het resultaat weer te geven en start de VERT.ZOEKEN-functie door het volgende in de formulebalk in te typen.

=VLOOKUP(

Stap 2: Geef de opzoekwaarde op

Geef eerst de opzoekwaarde op (dat is wat u zoekt) in de VERT.ZOEKEN-functie. Hier geef ik een verwijzing naar cel G6, die het ID-nummer 1005 bevat.

=VLOOKUP(G6

Stap 3: Geef de tabelmatrix op

Geef vervolgens een celbereik op dat zowel de gezochte waarde als de te retourneren waarde bevat. In dit geval selecteer ik het bereik B6:E12. De formule ziet er nu als volgt uit:

=VLOOKUP(G6,B6:E12

=VLOOKUP(G6,$B$6:$E$12

Stap 4: Geef de kolom op waaruit u een waarde wilt retourneren

Geef vervolgens op uit welke kolom u een waarde wilt retourneren.

In dit voorbeeld zoek ik het e-mailadres op basis van een ID-nummer, dus geef ik het getal 4 op zodat VERT.ZOEKEN weet dat het de waarde uit de vierde kolom van het gegevensbereik moet retourneren.

=VLOOKUP(G6,B6:E12,4

Stap 5: Zoek een benaderende of exacte overeenkomst

Bepaal ten slotte of u op zoek bent naar een benaderende of een exacte overeenkomst.

• Om een exacte overeenkomst te vinden, moet u ONWAAR als laatste argument gebruiken.
• Gebruik WAAR als laatste argument of laat dit argument leeg om een benaderende overeenkomst te vinden.

In dit voorbeeld gebruik ik ONWAAR voor een exacte overeenkomst. De formule ziet er nu als volgt uit:

=VLOOKUP(G6,B6:E12,4,FALSE

Druk op Enter om het resultaat te verkrijgen

Door elk argument in het bovenstaande voorbeeld stap voor stap uit te leggen, wordt de syntaxis en worden de argumenten van de VERT.ZOEKEN-functie nu veel gemakkelijker te begrijpen.

Syntaxis en argumenten

=VLOOKUP (lookup_value, table_array, col_index, [range_lookup])

• Zoekwaarde (vereist): de waarde die u zoekt (een concrete waarde of een celverwijzing). Let op: deze waarde moet voorkomen in de eerste kolom van de tabelmatrix.
• Tabelmatrix (vereist): een celbereik dat zowel de kolom met de zoekwaarde als de kolom met de retourneerwaarde bevat.
• Kolomindex (vereist): een geheel getal dat het kolomnummer aangeeft waarin de retourneerwaarde staat. Het begint bij 1 voor de meest linkse kolom van de tabelmatrix.
• Benaderend_zoeken(optioneel): Een logische waarde die bepaalt of VLOOKUP een benaderende of exacte overeenkomst moet zoeken.
  • Benaderende overeenkomst – stel dit argument in op WAAR, 1 of laat het leeg.
    Belangrijk: om een benaderende overeenkomst te vinden, moeten de waarden in de eerste kolom van de tabel_matrix oplopend gesorteerd zijn; anders kan VLOOKUP een verkeerd resultaat geven.
  • Exacte overeenkomst – stel dit argument in op ONWAAR of 0.

Voorbeelden

In deze sectie vindt u enkele voorbeelden die u een beter inzicht geven in de werking van de VERT.ZOEKEN-functie.

Voorbeeld 1: Exacte versus benaderende overeenkomst in VERT.ZOEKEN

Als u twijfelt over exacte en benaderende overeenkomsten bij het gebruik van VERT.ZOEKEN, helpt deze sectie u die verwarring helder en eenvoudig uit de weg te ruimen.

Exacte overeenkomst in VERT.ZOEKEN

In dit voorbeeld zoek ik de bijbehorende namen op basis van de scores in het bereik E6:E8. Daarom voer ik de volgende formule in cel F6 in en sleep ik de automatische invulgreep naar F8. In deze formule is het laatste argument ingesteld op ONWAAR om een exacte overeenkomst te vinden.

=VLOOKUP(E6,$B$6:$C$12,2,FALSE)

Omdat de score 98 niet voorkomt in de eerste kolom van het gegevensbereik, retourneert VERT.ZOEKEN een #N/B-fout.

Benaderende overeenkomst in VERT.ZOEKEN

In hetzelfde voorbeeld als hierboven voert VERT.ZOEKEN een benaderende zoekopdracht uit als u het laatste argument wijzigt in WAAR. Als er geen overeenkomst wordt gevonden, zoekt het de grootste waarde die kleiner is dan de opzoekwaarde en retourneert het het bijbehorende resultaat.

=VLOOKUP(E6,$B$6:$C$12,2,TRUE)

Omdat de score 98 niet bestaat, zoekt VERT.ZOEKEN de grootste waarde die kleiner is dan 98 – namelijk 95 – en retourneert de bijbehorende naam als het dichtstbijzijnde resultaat.

Voorbeeld 2: VERT.ZOEKEN gebruiken met meerdere criteria

In deze sectie ziet u hoe u VERT.ZOEKEN met meerdere voorwaarden in Excel toepast. Zoals in de onderstaande schermafbeelding te zien is, volgt u deze stappen om het salaris op te zoeken op basis van de opgegeven naam (in cel H5) en afdeling (in cel H6).

Stap 1: Voeg een hulpkolom toe om de waarden uit de opzoekkolommen samen te voegen

In dit geval moeten we een hulpkolom maken om de waarden uit de Naam-kolom en de Afdeling-kolom samen te voegen.

1. Voeg links van uw gegevensbereik een hulpkolom toe en voorzie deze kolom van een duidelijke kop. Zie de schermafbeelding:
   
   
2. Selecteer in deze hulpkolom de eerste cel onder de kop, typ de volgende formule in de formulebalk en druk op Enter.
   

   =C6&" "&D6

   
   Opmerkingen: In deze formule gebruiken we een ampersand (&) om de tekst uit twee kolommen samen te voegen tot één stuk tekst.

   • C6 is de voornaam uit de Naam-kolom die u wilt samenvoegen; D6 is de eerste afdeling uit de Afdeling-kolom die u wilt samenvoegen.
   • De waarden van deze twee cellen worden samengevoegd, met een spatie ertussen.
3. Selecteer deze resultaatcel en sleep vervolgens de automatische invulgreep omlaag om de formule toe te passen op andere cellen in dezelfde kolom.
   
   

Stap 2: Pas de VERT.ZOEKEN-functie toe met de opgegeven criteria

Selecteer een cel waarin u het resultaat wilt weergeven (hier kies ik I7), typ de volgende formule in de Formulebalk en druk vervolgens op Enter.

=VLOOKUP(I5& " "&I6,B6:F12,5,FALSE)

Resultaat

Veelvoorkomende VERT.ZOEKEN-fouten en oplossingen

In deze sectie worden de meest voorkomende fouten bij het gebruik van VERT.ZOEKEN opgesomd, inclusief praktische oplossingen om ze snel en eenvoudig te verhelpen.

#N/B-fout wordt geretourneerd

De meest voorkomende fout bij VERT.ZOEKEN is de #N/B-fout, wat aangeeft dat Excel de opgegeven zoekwaarde niet kon vinden. Hier zijn enkele mogelijke oorzaken waarom VERT.ZOEKEN een #N/B-fout retourneert.

Reden 1: De opzoekwaarde staat niet in de eerste kolom van de tabelmatrix

Een van de beperkingen van VERT.ZOEKEN in Excel is dat u alleen naar links kunt zoeken Links naar rechts. Daarom moet de Zoekwaardebereik in de eerste kolom van de tabelmatrix staan.

Zoals in de onderstaande schermafbeelding te zien is, wil ik een naam ophalen op basis van de opgegeven functietitel. De opzoekwaarde ()salesmanager) bevindt zich in de tweede kolom van de tabelmatrix, terwijl de retourneerwaarde links van de opzoekkolom staat—daardoor geeft VERT.ZOEKEN een #N/B-fout terug.

Oplossingen

U kunt een van de volgende oplossingen toepassen om deze fout op te lossen.

• Herorden de kolommen
  
  U kunt de kolommen herordenen zodat de zoekkolom in de eerste kolom van de tabelmatrix komt te staan.
• Gebruik de functies INDEX en VERGELIJKEN samen
  
  Hier combineren we de functies INDEX en VERGELIJKEN als krachtig alternatief voor VLOOKUP om dit probleem op te lossen.

  =INDEX(B6:B12,MATCH(F6,C6:C12,0))

  
• Gebruik de X.ZOEKEN-functie (beschikbaar in Excel 365, Excel 2021 en nieuwere versies)
  

  =XLOOKUP(F6,C6:C12,B6:B12)

Reden 2: De opzoekwaarde komt niet voor in de opzoekkolom (exacte overeenkomst)

Een van de meest voorkomende redenen dat VERT.ZOEKEN een #N/B-fout geeft, is dat de opgezochte waarde niet wordt gevonden.

Zoals in het onderstaande voorbeeld te zien is, proberen we de naam te vinden die hoort bij de score 98 in cel E6. Omdat deze score niet voorkomt in de eerste kolom van het gegevensbereik, geeft VERT.ZOEKEN een #N/B-foutwaarde terug.

Oplossingen

Om deze fout op te lossen, kunt u een van de volgende oplossingen proberen.

• Als u wilt dat VLOOKUP zoekt naar de eerstvolgende grootste waarde die kleiner is dan de zoekwaarde, wijzigt u het laatste argument ONWAAR (exacte overeenkomst) in WAAR (benaderende overeenkomst). Zie voor meer informatie Voorbeeld 1: Exacte versus benaderende overeenkomst met VLOOKUP.
• Om te voorkomen dat u het laatste argument moet wijzigen en een herinnering te krijgen als de zoekwaarde niet wordt gevonden, kunt u de VLOOKUP-functie insluiten in de ALS.FOUT-functie:
  

  =IFERROR(VLOOKUP(E8,$B$6:$C$12,2,FALSE),"Not found")

Reden 3: De opzoekwaarde is kleiner dan de kleinste waarde in de opzoekkolom (benaderende overeenkomst)

Zoals in de onderstaande schermafbeelding te zien is, voert u een benaderende zoekopdracht uit. Omdat de waarde die u zoekt (in dit geval het ID-nummer 1001) kleiner is dan de kleinste waarde in de opzoekkolom (1002), retourneert VERT.ZOEKEN een #N/B-fout.

Oplossingen

Hier zijn twee oplossingen voor u.

• Zorg ervoor dat de zoekwaarde groter dan of gelijk is aan de kleinste waarde in de zoekkolom.
• Als u wilt dat Excel u eraan herinnert dat de zoekwaarde niet is gevonden, plaatst u de VLOOKUP-functie in de ALS.FOUT-functie zoals hieronder:
  

  =IFERROR(VLOOKUP(G6,B6:E12,4,TRUE),"Not found")

Reden 4: Getallen zijn opgemaakt als tekst

Zoals u in de onderstaande schermafbeelding ziet, wordt de #N/B-fout in dit voorbeeld veroorzaakt door een typeverschil tussen de opzoekcel (G6) en de opzoekkolom (B6:B12) van de oorspronkelijke tabel. De waarde in G6 is een getal, terwijl de waarden in het bereik B6:B12 getallen zijn die als tekst zijn opgemaakt.

Oplossingen

Om dit probleem op te lossen, moet u de opzoekwaarde terugzetten naar een getal. Hieronder vindt u twee methoden.

• Pas de functie Converteren naar getal toe
  
  Klik op de cel die u wilt converteren van Tekst naar getal, selecteer deze knop naast de cel en selecteer vervolgens Converteren naar getal.
  
• Pas een handige tool toe om batchgewijs Tekst naar getal conversie
  
  De Tekst naar getal conversie-functie van Kutools voor Excelhelpt u eenvoudig een bereik van cellen te converteren van Tekst naar getal en vice versa.Start vandaag nog uw gratis 30-daagse volledige proefversie!

Reden 5: De tabelmatrix is niet constant wanneer u de VLOOKUP-formule naar andere cellen sleept

Zoals in de onderstaande schermafbeelding te zien is, bevinden zich twee zoekwaarden in E6 en E7. Nadat het eerste resultaat in F6 is verkregen, sleept u de VLOOKUP-formule van cel F6 naar F7 — maar dan verschijnt er een #N/B-fout. Dit komt doordat de celverwijzingen (B6:C12) standaard relatief zijn en automatisch aanpassen wanneer u de formule naar beneden kopieert. Hierdoor verschuift het tabelbereik naar B7:C13, dat de opzoekwaarde 73 niet meer bevat.

Oplossing

Vergrendel de tabelmatrix om deze constant te houden door een $-teken toe te voegen vóór de rij- en kolomletters in de celverwijzingen. Voor meer informatie over absolute verwijzingen in Excel, bekijk deze handleiding: Absolute verwijzing in Excel (hoe maken en gebruiken).

#WAARDE!-fout wordt geretourneerd

De volgende voorwaarden kunnen ervoor zorgen dat VLOOKUP een #WAARDE!-fout retourneert.

Reden 1: De opzoekwaarde bestaat uit meer dan 255 tekens

Zoals in de onderstaande schermafbeelding te zien is, levert de opzoekwaarde in cel H4—met meer dan 255 tekens—een #WAARDE!-fout op bij gebruik van VLOOKUP.

Oplossingen

Om deze beperking te omzeilen, kunt u een andere opzoekfunctie gebruiken die langere tekenreeksen kan verwerken. Probeer een van de volgende formules.

• INDEX en VERGELIJKEN:
  

  =INDEX(E5:E11, MATCH(TRUE, INDEX(B5:B11=H4, 0), 0))

  
• X.ZOEKEN-functie(beschikbaar in Excel 365, Excel 2021 en nieuwere versies):
  

  =XLOOKUP(H4,B5:B11,E5:E11)

Reden 2: Het argument kolom_index is kleiner dan 1

De kolomindex geeft aan in welke kolom van de tabelmatrix de waarde staat die u wilt retourneren. Dit argument moet een positief getal zijn dat overeenkomt met een geldige kolom in de tabelmatrix.

Als u een kolomindex opgeeft die kleiner is dan 1 (dus nul of negatief), kan VLOOKUP de betreffende kolom in de tabelmatrix niet vinden.

Oplossing

Los dit probleem op door ervoor te zorgen dat het kolomindex-argument in uw VLOOKUP-formule een positief getal is dat overeenkomt met een geldige kolom in de tabelmatrix.

#VERWIJZ!-fout wordt geretourneerd

In dit gedeelte wordt één reden genoemd waarom VLOOKUP een #VERWIJZ!-fout retourneert, inclusief oplossingen voor dit probleem.

Reden: Het kolom_index-argument is groter dan het aantal kolommen

Zoals u in de onderstaande schermafbeelding ziet, bevat de tabelmatrix slechts 4 kolommen. U hebt echter in de VLOOKUP-formule een kolomindex van 5 opgegeven—groter dan het aantal kolommen in de tabelmatrix. Daardoor kan VLOOKUP de kolom niet vinden en retourneert het een #VERWIJZ!-fout.

Oplossingen

• Geef een juist kolomnummer op
  Zorg ervoor dat het kolomindexargument in uw VLOOKUP-formule een getal is dat overeenkomt met een geldige kolom in de tabelmatrix.
• Haal automatisch het kolomnummer op op basis van de opgegeven kolomkop
  VERGELIJKEN

  =VLOOKUP(G6,B6:E12,MATCH("Email",B5:E5,0),FALSE)

  Opmerking: In de bovenstaande formule wordt de VERGELIJKEN(„E-mail",B5:E5, 0)-functie gebruikt om het kolomnummer van de "E-mail"-kolom in het bereik B6:E12 te bepalen. Het resultaat is 4, wat als kolomindex wordt gebruikt in de VLOOKUP-functie.

Onjuiste waarde wordt geretourneerd

Als u merkt dat VLOOKUP niet het juiste resultaat retourneert, kan dit door de volgende redenen komen

Reden 1: De opzoekkolom is niet oplopend gesorteerd

Als u het laatste argument instelt op WAAR(of)het leeg laat) voor een benaderende zoekopdracht, terwijl de opzoekkolom niet oplopend is gesorteerd, kan de resulterende waarde onjuist zijn.

Oplossing

Het oplopend sorteren van de opzoekkolom helpt u dit probleem op te lossen. Volg hiervoor de onderstaande stappen:

1. Selecteer de gegevenscellen in de zoekkolom, ga naar het Gegevens-tabblad en klik op Sorteren Kleinste naar grootste in de groep Sorteren en filteren.
2. In het dialoogvenster Waarschuwing sorteren selecteert u de optie Selectie uitbreiden en klikt u op OK.

Reden 2: Er is een kolom ingevoegd of verwijderd

Zoals in de onderstaande schermafbeelding te zien is, stond de waarde die ik oorspronkelijk wilde retourneren in de vierde kolom van de tabelmatrix, dus heb ik het kolom_index-nummer ingesteld op 4. Nu er echter een nieuwe kolom is ingevoegd, is de resultaatkolom de vijfde kolom van de tabelmatrix geworden, waardoor VLOOKUP het resultaat uit een verkeerde kolom haalt.

Oplossingen

Hier zijn twee oplossingen voor u.

• U kunt het kolomindexnummer handmatig aanpassen zodat het overeenkomt met de positie van de retourneerkolom. De formule hier moet als volgt worden gewijzigd:

  =VLOOKUP(H6,B6:F12,5,FALSE)

• Als u altijd het resultaat uit een specifieke kolom wilt retourneren – zoals de E-mail-kolom in dit voorbeeld – helpt de volgende formule automatisch de juiste kolomindex te bepalen op basis van de opgegeven kolomkop, ongeacht of er kolommen worden ingevoegd of verwijderd in de tabelmatrix.

  =VLOOKUP(H6,B6:F12,MATCH("Email",B5:E5,0),FALSE)

Opmerkingen over andere functies

• VLOOKUP zoekt alleen van links naar rechts.
  De zoekwaarde moet in de meest linkse kolom staan en de resultaatwaarde moet zich in een kolom rechts van de zoekkolom bevinden.
• Als u het laatste argument leeg laat, gebruikt VLOOKUP standaard een benaderende overeenkomst.
• VLOOKUP voert een zoekopdracht uit die niet hoofdlettergevoelig is.
• Bij meerdere overeenkomsten retourneert VLOOKUP alleen de eerste overeenkomst die het tegenkomt in de tabelmatrix, en dat op basis van de rijvolgorde in die matrix.

Gerelateerde artikelen