Skip to main content

Kutools voor Office — Eén Suite. Vijf Tools. Verwezenlijkt Meer.

Waarden optellen op basis van weeknummer of weekdag in Excel

Author Siluvia Last modified

Deze handleiding demonstreert stap voor stap formules om u te helpen waarden in een bepaald bereik op te tellen op basis van het gespecificeerde weeknummer of de weekdag in Excel.

Hoe voeg je waarden op basis van weeknummer op in Excel?
Hoe voeg je waarden op basis van weekdag op in Excel?

Hoe voeg je waarden op basis van weeknummer op in Excel?

Zoals in de onderstaande schermafbeelding te zien is, om de waarden in de kolom Bedrag op te tellen op basis van de datums waarin een bepaald weeknummer valt, bieden we twee formules aan.

doc-sum-by-week-number-weekday-1

Algemene Formules

=SOM.ALS( waarde_bereik, hulpkolom_bereik, weeknummer)

=SOMPRODUCT(--(WEEKNUM(datumbereik+0,1)=weeknummer),waarde_bereik)

Argumenten

Waarde_bereik: Het bereik van waarden dat u wilt optellen op basis van het weeknummer;
Hulpkolom_bereik: Het bereik van weeknummers dat uit de datum is gehaald;
Weeknummer: Het weeknummer dat wordt gebruikt als criterium voor het optellen van waarden.

Hoe gebruik je deze formule?

Met behulp van de SOM.ALS-formule en een hulpkolom

Om de SOM.ALS-formule te gebruiken, moet je eerst de WEEKNUM-functie toepassen om een hulpkolom te maken om de bijbehorende weeknummers voor de datums in de Datum-kolom te berekenen.

=WEEKNUM (volgnummer, [return_type])

De WEEKNUM-functie retourneert het weeknummer van de gegeven datum in een jaar.

1. In dit geval selecteer ik een cel (F5) naast de eerste waarde in de kolom Bedrag.

2. Voer de onderstaande formule erin in en druk op de Enter-toets om het weeknummer van de eerste datum te krijgen. Selecteer de resultaatcel en sleep vervolgens de AutoVul-handgreep naar beneden om de andere weeknummers te krijgen. Zie schermafbeelding:

=WEEKNUM(C5)

doc-sum-by-week-number-weekday-2

3. Selecteer een cel om het totaalbedrag weer te geven, voer de onderstaande formule erin in en druk op de Enter-toets. Selecteer deze resultaatcel, sleep de AutoVul-handgreep naar beneden om de andere resultaten te krijgen.

=SOM.ALS($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

Met behulp van de SOMPRODUCT-formule

Je hoeft geen hulpkolom te maken wanneer je de SOMPRODUCT-formule gebruikt om dit probleem op te lossen.

1. Selecteer een lege cel, voer de onderstaande formule erin in en druk op de Enter-toets.

=SOMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. Selecteer de resultaatcel, sleep de AutoVul-handgreep naar beneden om de andere resultaten te krijgen volgens uw behoeften.

doc-sum-by-week-number-weekday-4

Uitleg van de formule

=SOM.ALS($E$5:$E$14, $F$5:$F$14, H6)

Nadat de weeknummers zijn berekend met de WEEKNUM-functie, somt de SOM.ALS-functie de waarden in bereik E5:E14 op als de weeknummers in de hulpkolom F5:F14 overeenkomen met het gegeven weeknummer in H6.

=SOMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

WEEKNUM($C$5:$C$14+0,1): De WEEKNUM-functie berekent elk weeknummer van de datums in bereik C5:C14 en retourneert een array zoals deze: {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6: Hier wordt elk weeknummer in de array vergeleken met het gegeven weeknummer in G6, en retourneert een nieuwe array: {WAAR;WAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR};
--{WAAR;WAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR;ONWAAR}: Deze twee mintekens converteren de “WAAR” en “ONWAAR” in 1-en en 0-en. Hier krijg je een nieuwe array als {1;1;0;0;0;0;0;0;0;0};
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100}: Elk paar invoerwaarden in de arrays wordt vermenigvuldigd en retourneert {1428;2010;0;0;0;0;0;0;0;0};
SOMPRODUCT({1428;2010;0;0;0;0;0;0;0;0}): De SOMPRODUCT-functie telt alle getallen in de array op en retourneert het eindresultaat 1428+2010=3438.

Hoe voeg je waarden op basis van weekdag op in Excel?

Zoals in de onderstaande schermafbeelding te zien is, om de waarden in de kolom Bedrag op te tellen op basis van een bepaalde weekdag in Excel, kun je de SOMPRODUCT-functie samen met de WEEKDAG-functie toepassen om dit te doen.

In dit geval, aangezien we het totale bedrag voor elke weekdag moeten optellen, maken we voordat we de formule toepassen een hulpkolom met nummers 1 tot 7 om respectievelijk maandag tot zondag aan te geven.

doc-sum-by-week-number-weekday-6

Algemene formule

=SOMPRODUCT((WEEKDAG(datumbereik,2)=weekdag_nummer)*waarde_bereik)

Argumenten

Datumbereik: Het datumbereik waarin je de gegeven weekdagen wilt evalueren;
Waarde_bereik: Het bereik van waarden dat je wilt optellen op basis van de weekdag;
2: Het getal 2 vertegenwoordigt de getallen 1 (maandag) tot 7 (zondag);
Weekdag_nummer: Het weekdagnummer dat wordt gebruikt als criterium voor het optellen van waarden. Dit kan een celverwijzing of een getal van 1 tot 7 zijn.

Hoe gebruik je deze formule?

1. Selecteer een cel naast de cel met nummer 1. Hier selecteer ik I6.

2. Kopieer of voer de onderstaande formule erin in en druk op de Enter-toets. Selecteer de resultaatcel en sleep vervolgens de AutoVul-handgreep naar beneden om de resultaten voor andere weekdagen te krijgen.

=SOMPRODUCT((WEEKDAG($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

Opmerking: Als je alleen waarden wilt optellen op basis van één gespecificeerde weekdag zoals vrijdag, kun je direct het getal 5 in de formule invoeren zoals hieronder.

=SOMPRODUCT((WEEKDAG($C$5:$C$14,2)=5)*$E$5:$E$14)

Uitleg van de formule

=SOMPRODUCT((WEEKDAG($C$5:$C$14,2)=H6)*$E$5:$E$14)

WEEKDAG($C$5:$C$14,2): De WEEKDAG-functie retourneert gehele getallen van 1 tot 7 om de dag van de week van maandag tot zondag in bereik C5:C14 te vertegenwoordigen: {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6: Hier wordt elke dag van de week in de array vergeleken met het gegeven weekdagnummer in H6, en retourneert een nieuwe array: {ONWAAR;ONWAAR;WAAR;ONWAAR;ONWAAR;ONWAAR;WAAR;ONWAAR;ONWAAR;ONWAAR};
{ONWAAR;ONWAAR;WAAR;ONWAAR;ONWAAR;ONWAAR;WAAR;ONWAAR;ONWAAR;ONWAAR}*$E$5:$E$14: Hier worden de WAAR en ONWAAR geconverteerd naar 1-en en 0-en, en vervolgens vermenigvuldigd met de waarden in E5:E14 om de array te retourneren: {0;0;2288;0;0;0;1325;0;0;0};
SOMPRODUCT{0;0;2288;0;0;0;1325;0;0;0}: De SOMPRODUCT-functie telt alle getallen in de array op en retourneert het eindresultaat 2288+1325=3613.

Gerelateerde functies

Excel WEEKNUM-functie
De Excel SOM.ALS-functie retourneert het weeknummer van de gegeven datum in een jaar, die begint met het tellen van weken vanaf 1 januari.

Excel SOMPRODUCT-functie
De Excel SOMPRODUCT-functie kan worden gebruikt om twee of meer kolommen of arrays met elkaar te vermenigvuldigen, en vervolgens de som van de producten te krijgen.

Excel WEEKDAG-functie
De Excel EOMAAND-functie retourneert een geheel getal van 1 tot 7 om de dag van de week voor een gegeven datum in Excel te vertegenwoordigen.

Gerelateerde formules

Waarden optellen per maand (met of zonder jaar)
Deze handleiding demonstreert twee formules in detail om waarden op te tellen op basis van een bepaalde maand en jaar of om waarden op te tellen op basis van een bepaalde maand, ongeacht het jaar, in Excel.

Waarden optellen per week van een gegeven datum
Deze handleiding bespreekt hoe je waarden kunt optellen per week waarin een gegeven datum valt.

Elke n rijen of kolommen in een bereik optellen
Deze handleiding legt twee formules uit op basis van de SOM- en VERSCHUIVINGSfuncties om elke n rijen of kolommen in een gespecificeerd bereik in Excel op te tellen.

Elke n-de rij of kolom in een bereik optellen
Deze handleiding laat zien hoe je een formule maakt op basis van de SOMPRODUCT-, MOD- en KOLOMfuncties om elke n-de rij of kolom in een bereik in Excel op te tellen.

De Beste Office Productiviteitstools

Kutools voor Excel - Helpt U Om Uit Te Blinken Tussen de Menigte

🤖 KUTOOLS AI Assistent: Revolutioneer data-analyse op basis van: Slimme Uitvoering   |  Genereer Code  |  Maak Aangepaste Formules  |  Analyseer Data en Genereer Grafieken  |  Roep Kutools Functies aan…
Populaire Functies: Zoek, Markeer of Identificeer Dubbele Waarden  |  Verwijder Lege Rijen  |  Combineer Kolommen of Cellen zonder Gegevensverlies  |  Afronden zonder Formule ...
Super VLookup: Meerdere Criteria  |  Meerdere Waarden  |  Over Meerdere Bladen  |  Fuzzy Match...
Geavanceerde Keuzelijst: Eenvoudige Keuzelijst  |  Afhankelijke Keuzelijst  |  Multi-select Keuzelijst...
Kolommenbeheer: Voeg een Specifiek Aantal Kolommen Toe  |  Verplaats Kolommen  |  Wissel Zichtbaarheidsstatus van Verborgen Kolommen  |  Vergelijk Kolommen om Dezelfde & Verschillende Cellen te Selecteren ...
Uitgelichte Functies: Rasterfocus  |  Ontwerpweergave  |  Verbeterde Formulebalk  |  Werkboek & Werkblad Beheer | AutoTekstbibliotheek (Auto Tekst)  |  Datumkiezer  |  Combineer Werkbladen  |  Versleutel/Decodeer Cellen  |  Verzend E-mails via Lijst  |  Superfilter  |  Speciaal Filter (filter vet/cursief/doorgehaald...) ...
Top 15 Toolsets:  12 Tekst Tools (Tekst toevoegen, Specifieke tekens verwijderen ...)  |  50+ Grafiek Types (Gantt-diagram ...)  |  40+ Praktische Formules (Leeftijd berekenen op basis van geboortedatum ...)  |  19 Invoeg Tools (QR-code invoegen, Afbeelding invoegen vanaf Pad ...)  |  12 Conversie Tools (Omzetten naar woorden, Valutaconversie ...)  |  7 Samenvoegen & Opsplits Tools (Geavanceerd samenvoegen van rijen, Splits Excel Cellen ...)  |  ... en meer
Gebruik Kutools in uw voorkeurstaal – ondersteunt Engels, Spaans, Duits, Frans, Chinees en meer dan 40 andere talen!

Kutools voor Excel Beschikt Over Meer Dan 300 Functies, Waardoor Wat U Nodig Hebt Maar Een Klik Verwijderd Is...

Office Tab - Schakel Tabbladgestuurd Lezen en Bewerken in Microsoft Office (inclusief Excel)

  • Eén seconde om te schakelen tussen tientallen open documenten!
  • Verminder honderden muisklikken voor u elke dag, zeg vaarwel tegen muisarm.
  • Verhoogt uw productiviteit met 50% bij het bekijken en bewerken van meerdere documenten.
  • Brengt Efficiënte Tabs naar Office (inclusief Excel), Net Als Chrome, Edge en Firefox.