Splits de tekstreeks op een specifiek teken in een cel in Excel
In deze zelfstudie wordt uitgelegd hoe u tekstreeks op een specifiek teken kunt splitsen in afzonderlijke kolomcellen met formules in Excel.
Hoe een tekstreeks op een specifiek teken in een cel in Excel te splitsen?
Stel dat je een lijst met tekstreeksen hebt in kolom B zoals in de onderstaande schermafbeelding, en je wilt teksten splitsen bij het teken "-" en ze in drie afzonderlijke kolommen uitvoeren. In dit geval kunnen de onderstaande formules u een plezier doen.
Generieke formules
Algemene formule voor het splitsen van de linkertekst
=LEFT(text_string,FIND("Char", text_string)-1)
Generieke formule voor het splitsen van de middelste tekst
=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)
Generieke formule voor het splitsen van de juiste tekst
=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))
Argumenten van bovenstaande formules
Tekst reeks: De tekstreeks waaruit u tekst wilt splitsen;
Verkolen: Het teken waarop u tekst splitst op basis van.
Hoe gebruik je deze formules?
Splits eerst de eerste tekstreeks op basis van een specifiek teken
1. Selecteer een lege cel om het resultaat uit te voeren. Hier selecteer ik C3.
2. Voer de onderstaande formule in en druk op Enter sleutel. En sleep vervolgens de cel met uw LINKER-formule helemaal naar beneden om deze op andere cellen toe te passen.
=LEFT(B3,FIND("-",B3)-1)
Ten tweede, splits de middelste tekenreeks op basis van een specifiek teken
1. Selecteer een lege cel zoals D3 om het resultaat uit te voeren.
2. Voer de onderstaande formule in en druk op Enter sleutel. Selecteer de resultaatcel, sleep de vulhendel naar beneden om de formule op andere cellen toe te passen.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
Splits ten slotte de laatste tekstreeks op basis van een specifiek teken
1. Selecteer een lege cel zoals E3 om het resultaat uit te voeren.
2. Voer de onderstaande formule in en druk op Enter sleutel. Selecteer de resultaatcel, sleep de vulhendel naar beneden om de formule op andere cellen toe te passen.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
Nu is de tekenreeks in elke cel van kolom B opgesplitst in drie delen.
Tips: Als u de tekstreeks alleen in twee delen wilt splitsen op basis van een specifiek teken, kunt u na het splitsen van het eerste deel met de bovenstaande LINKS-formule de onderstaande RECHTER-formule toepassen om het tweede deel te extraheren, zoals in de onderstaande schermafbeelding wordt getoond.
=RIGHT(B3,LEN(B3)-FIND("-",B3))
Hoe werken deze formules?
=LEFT(B3,FIND("-",B3)-1)
- FIND("-",B3): De functie FIND retourneert de startpositie van het teken "-" in de tekstreeks KTE-Jan-359. Het resultaat is 4.
- LEFT(B3,4-1): De LEFT-functie haalt 3 tekens (4-1 = 3) uit de linkerkant van de tekstreeks KTE-Jan-359. Hier is het resultaat KTE.
Note: Aangezien het eerste teken "-" op de 4e positie van de tekstreeks staat, moet u 1 aftrekken om het uit te sluiten van extraheren.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
- FIND("-",B3) + 1: De functie FIND retourneert de startpositie van het teken "-" in de tekstreeks KTE-Jan-359. Hier is het resultaat 4.
Note: Aangezien het eerste teken "-" op de 4e positie van de tekstreeks staat, moet u 1 tot 4 optellen om de teksten erachter te extraheren, en tenslotte eindigen we met 4 + 1 = 5. - FIND("-",B3,FIND("-",B3)+1) hier wordt weergegeven als FIND ("-", KTE-Jan-359,4 + 1): De functie Zoeken zoekt de positie van het teken "-" vanaf het 5e teken in KTE-Jan-359. En retourneert het resultaat als 8.
- MID(B3, 5, 8 - 4 - 1): MID (KTE-Jan-359,5,3) wat betekent dat de MID-functie 3 aantal tekens extraheert vanaf het 5e teken in de tekststring KTE-Jan-359. En het resultaat is Jan.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
- LEN(B3): De functie LEN berekent de totale lengte van de tekstreeks KTE-Jan-359 en retourneert het resultaat als 11.
- FIND("-",B3,FIND("-",B3)+1): De functie Zoeken zoekt de positie van het teken "-" vanaf het 5e teken in KTE-Jan-359. En retourneert het resultaat als 8.
- RIGHT(B3,11 - 8)): De RIGHT-functie haalt 3 (11-8) tekens uit de rechterkant van KTE-Jan-359. Hier is het resultaat 359.
Gerelateerde functies
Excel LINKS-functie
De LEFT-functie haalt het opgegeven aantal tekens uit de linkerkant van een opgegeven string.
Excel FIND-functie
De functie FIND wordt gebruikt om een string binnen een andere string te vinden, en geeft de startpositie van de string in een andere string terug.
Excel MID-functie
De MID-functie wordt gebruikt om een bepaald aantal tekens uit het midden van een gegeven tekstreeks te zoeken en terug te sturen.
Excel RECHTS-functie
De functie RIGHT haalt een bepaald aantal tekens uit de rechterkant van de tekstreeks.
Excel LEN-functie
De Excel LEN-functie retourneert het aantal tekens in een tekstreeks.
Gerelateerde formules
Splits dimensies in twee delen in Excel
In dit artikel wordt uitgelegd hoe u formules kunt gebruiken om dimensies in een cel op te splitsen in twee delen zonder eenheden (individuele lengte en breedte).
Scheid getallen van meeteenheden
In dit artikel wordt uitgelegd hoe u formule gebruikt om getallen te scheiden van meeteenheden.
Splits tekst en cijfers in een cel in Excel
Als u tekst en getallen in een cel wilt splitsen in verschillende kolomcellen met formules, zal deze tutorial u een plezier doen.
Tekst splitsen met scheidingsteken in een cel in Excel
In dit artikel bieden we een stapsgewijze handleiding om u te helpen bij het splitsen van tekst in een cel met een specifiek scheidingsteken in Excel.
De beste tools voor kantoorproductiviteit
Kutools for Excel - Helpt u zich te onderscheiden van de menigte
Kutools voor Excel beschikt over meer dan 300 functies, Ervoor zorgen dat wat u nodig heeft slechts één klik verwijderd is...
Office-tabblad - Schakel lezen en bewerken met tabbladen in Microsoft Office in (inclusief Excel)
- Een seconde om te schakelen tussen tientallen geopende documenten!
- Verminder elke dag honderden muisklikken voor u, zeg maar dag tegen muishand.
- Verhoogt uw productiviteit met 50% bij het bekijken en bewerken van meerdere documenten.
- Brengt efficiënte tabbladen naar Office (inclusief Excel), net als Chrome, Edge en Firefox.
