Bestandnaam extraheren uit een pad in Excel

In deze handleiding wordt uitgelegd hoe u formules kunt gebruiken om de bestandsnaam, met of zonder extensie, te extraheren uit een bestandspad in een specifieke cel in Excel.

Bestandsnaam met extensie extraheren uit een pad
Bestandsnaam zonder extensie extraheren uit een pad

Bestandsnaam met extensie extraheren uit een pad

Zoals in de onderstaande schermafbeelding te zien is, is er een lijst met verschillende bestandspaden en wilt u alleen de bestandsnamen met extensies daaruit extraheren. De volgende formule zal u helpen bij het oplossen van dit probleem.

Algemene formule

=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))

Argumenten

Hoe gebruik je deze formule?

1. Selecteer een lege cel om de bestandsnaam weer te geven. In dit geval selecteer ik cel D3.

2. Voer de onderstaande formule in en druk op de Enter-toets. Selecteer de resultaatcel en sleep vervolgens de vulgreep naar beneden om de formule toe te passen op andere cellen.

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

Nu zijn alle bestandsnamen met extensies uit de specifieke bestandspaden geëxtraheerd zoals in de bovenstaande schermafbeelding te zien is.

Opmerkingen:

• In deze formule is B3 de cel die het bestandspad bevat. Pas deze indien nodig aan.
• Als de bestandsnaam niet langer is dan 99 tekens, kan ook de volgende kortere formule worden gebruikt om het probleem op te lossen. Zie de onderstaande schermafbeelding.
  =TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
  

Hoe werkt deze formule?

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))

• LEN(B3): De LEN-functie berekent de totale lengte van "D:\\files\work\Q1\Jan\text.txt" en retourneert het resultaat als 30;
• LEN(SUBSTITUTE(B3,"\","")): De SUBSTITUTE-functie vervangt het teken "\" door niets. Het resultaat is "D:filesworkQ1Jantext.txt". Vervolgens berekent de LEN-functie de totale lengte van "D:filesworkQ1Jantext.txt" en krijgt het resultaat 24;
• SUBSTITUTE(B3,"\","*",30-24): De SUBSTITUTE-functie vervangt het derde teken (30-24=6) "\" in "D:\\files\work\Q1\Jan\text.txt" door een enkel teken "*". Hier is het resultaat "D:\\files\work\Q1\Jan*text.txt";
• FIND("*","D:\\files\work\Q1\Jan*text.txt"): De FIND-functie lokaliseert de positie van het teken "*" in "D:\\files\work\Q1\Jan*text.txt" en retourneert uiteindelijk 22. Dit betekent dat het teken "*" zich op de 22e positie bevindt in "D:\\files\work\Q1\Jan*text.txt".

2. =MID(B3,22+1,LEN(B3))

• Zoals hierboven uitgelegd, retourneert LEN(B3) het resultaat als 30. Hier kan de MID-functie worden weergegeven als =MID("D:\\files\work\Q1\Jan\text.txt",23,30). Dit betekent dat de MID-functie 30 tekens extraheert uit de string "D:\\files\work\Q1\Jan\text.txt", beginnend bij het 23e teken. Hier is het resultaat text.txt.

Bestandsnaam zonder extensie extraheren uit een pad

Een andere situatie is dat u mogelijk alleen de bestandsnaam zonder extensie uit een pad wilt extraheren, zoals in de onderstaande schermafbeelding te zien is. Deze sectie biedt een lange formule om u hierbij te helpen.

Algemene formule

=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")

Argumenten

Hoe gebruik je deze formule?

1. Selecteer een lege cel om de bestandsnaam zonder extensie weer te geven.

2. Voer de onderstaande formule in en druk op de Enter-toets. Selecteer de resultaatcel en sleep vervolgens de vulgreep naar beneden om de formule toe te passen op andere cellen.

=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")

Opmerking: In deze formule is B3 de cel die het bestandspad bevat. Pas deze indien nodig aan.

Gerelateerde functies

Gerelateerde formules