Extraheer de bestandsnaam van een pad in Excel
In deze zelfstudie wordt uitgelegd hoe u formules kunt toepassen om een bestandsnaam met of zonder extensie uit een bestandspad in een specifieke cel in Excel te extraheren.
Pak de bestandsnaam met extensie uit een pad
Pak de bestandsnaam zonder extensie uit een pad
Pak de bestandsnaam met extensie uit een pad
Zoals de onderstaande schermafbeelding laat zien, is er een lijst met verschillende bestandspaden, en u wilt alleen de bestandsnamen met extensies eruit extraheren, de volgende formule zal u helpen het probleem op te lossen.
Generieke formule
=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))
argumenten
A1: Vertegenwoordigt de cel met het bestandspad waar u de bestandsnaam uit wilt halen.
Hoe gebruik je deze formule?
1. Selecteer een lege cel om de bestandsnaam uit te voeren. In dit geval selecteer ik de cel D3.
2. Voer de onderstaande formule in en druk op Enter sleutel. Selecteer de resultaatcel en sleep de vulhendel helemaal naar beneden om deze op andere cellen toe te passen.
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
Nu worden alle bestandsnamen met extensies in specifieke bestandspaden geëxtraheerd zoals het bovenstaande screenshot laat zien.
Opmerkingen:
- In deze formule is B3 de cel met het bestandspad. Wijzig het indien nodig.
- Als de bestandsnaam niet langer is dan 99 tekens, kan de onderstaande kortere formule ook worden gebruikt om het probleem op te lossen. Zie de onderstaande schermafbeelding.
=TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
Hoe werkt deze formule?
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))
- LEN(B3): De LEN-functie berekent de totale lengte in "D: \\ bestanden \ werk \ Q1 \ Jan \ text.txt" en retourneert het resultaat als 30;
- LEN(SUBSTITUTE(B3,"\","")): De functie SUBSTITUTE vervangt het teken "\" door niets. Het resultaat is "D: filesworkQ1Jantext.txt". En dan berekent de LEN-functie de totale lengte van "D: filesworkQ1Jantext.txt" en krijgt het resultaat 24;
- SUBSTITUTE(B3,"\","*",30-24): De functie SUBSTITUTE vervangt het derde teken (30-24 = 6) "\" in "D: \\ bestanden \ werk \ Q1 \ Jan \ text.txt" door een enkel teken "*". Hier is het resultaat "D: \\ files \ work \ Q1 \ Jan * text.txt";
- FIND("*","D:\\files\work\Q1\Jan*text.txt"): De functie FIND lokaliseert de positie van teken "*" in "D: \\ bestanden \ werk \ Q1 \ Jan * text.txt" en retourneert tenslotte 22. Dit betekent dat het teken "*" op de 22e positie staat in " D: \\ bestanden \ werk \ Q1 \ Jan * text.txt ".
2. =MID(B3,22+1,LEN(B3))
- Zoals de bovenstaande uitleg laat zien, retourneert LEN (B3) het resultaat als 30, hier kan de MID-functie worden weergegeven als = MID ("D: \\ files \ work \ Q1 \ Jan \ text.txt", 23,30). Dit betekent dat de MID-functie 30 tekens extraheert uit de string "D: \\ files \ work \ Q1 \ Jan \ text.txt", beginnend bij het 23e teken. Hier is het resultaat text.txt.
Pak de bestandsnaam zonder extensie uit een pad
Een andere omstandigheid is dat u misschien de bestandsnaam zonder extensie uit een pad hoeft te extraheren, zoals de onderstaande schermafbeelding laat zien. Dit gedeelte biedt een lange formule om u te helpen het op te lossen.
Generieke formule
=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")
argumenten
A1: Vertegenwoordigt de cel met het bestandspad waar u de bestandsnaam uit wilt halen.
CHAR (1): De CHAR (1) hier kan naar behoefte worden vervangen door elk CHAR-nummer. Of het kan worden vervangen door een specifiek symbool tussen aanhalingstekens, zoals "*".
Hoe gebruik je deze formule?
1. Selecteer een lege cel om de bestandsnaam zonder de extensie uit te voeren.
2. Voer de onderstaande formule in en druk op Enter sleutel. Selecteer de resultaatcel en sleep de vulhendel helemaal naar beneden om deze op andere cellen toe te passen.
=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")
Note: In deze formule is B3 de cel met het bestandspad. Wijzig het indien nodig.
Gerelateerde functies
Excel MID-functie
De Excel MID-functie wordt gebruikt om een bepaald aantal tekens uit het midden van een bepaalde tekstreeks te zoeken en te retourneren.
Excel FIND-functie
De Excel FIND-functie wordt gebruikt om een string binnen een andere string te zoeken, en geeft de startpositie van de string in een andere string terug.
Excel SUBSTITUTE-functie
De Excel SUBSTITUTE-functie vervangt tekst of tekens binnen een tekstreeks door een andere tekst of tekens.
Excel LEN-functie
De Excel LEN-functie retourneert het aantal tekens in een tekstreeks.
Excel IFERROR-functie
De functie ALS.FOUT wordt gebruikt om een aangepast resultaat te retourneren wanneer een formule een fout evalueert, en om een normaal resultaat te retourneren wanneer er geen fout is opgetreden.
Gerelateerde formules
Extraheer meerdere regels uit een cel
Als je een lijst met tekstreeksen hebt die zijn gescheiden door regeleinden (dat gebeurt door op Alt + Enter te drukken bij het invoeren van tekst), en je wilt deze regels tekst extraheren in meerdere cellen, dan zal de formule in deze tutorial je een gunst.
Extraheer de laatste regel tekst uit een cel met meerdere regels
Als u de laatste regel tekst wilt extraheren uit een tekstreeks die is gescheiden door regeleinden, kan een formule in deze zelfstudie u helpen bij het uitvoeren van deze taak in Excel.
Extraheer N-de woord uit tekststring in Excel
In dit artikel wordt uitgelegd hoe u een formule gebruikt om het specifieke n-de woord uit een tekstreeks in een cel in Excel te extraheren.
Haal de laatste twee woorden uit een cel in Excel
In deze zelfstudie wordt uitgelegd hoe u de formule gebruikt om de laatste twee woorden uit een cel in Excel te extraheren.
Extraheer een woord dat begint met een specifiek teken in Excel
Deze zelfstudie biedt een formule met gedetailleerde stappen om u te helpen het woord te extraheren dat begint met een specifiek teken uit een tekstreeks in een cel in Excel.
Pak alle woorden uit, behalve de eerste of de laatste
In deze zelfstudie leert u hoe u formules gebruikt om alle woorden uit een cel te extraheren, behalve de eerste of de laatste in Excel.
De beste tools voor kantoorproductiviteit
Kutools for Excel - Helpt u zich te onderscheiden van de menigte
Kutools voor Excel beschikt over meer dan 300 functies, Ervoor zorgen dat wat u nodig heeft slechts één klik verwijderd is...
Office-tabblad - Schakel lezen en bewerken met tabbladen in Microsoft Office in (inclusief Excel)
- Een seconde om te schakelen tussen tientallen geopende documenten!
- Verminder elke dag honderden muisklikken voor u, zeg maar dag tegen muishand.
- Verhoogt uw productiviteit met 50% bij het bekijken en bewerken van meerdere documenten.
- Brengt efficiënte tabbladen naar Office (inclusief Excel), net als Chrome, Edge en Firefox.
