Aantal datums tellen in een bereik op basis van de dag van de week

Excel biedt de combinatie van de functies SOMPRODUCT en WEEKDAG om ons te helpen eenvoudig het aantal gespecificeerde weekdagen binnen een bereik te tellen. Deze handleiding biedt een stap-voor-stap uitleg om je erdoorheen te helpen.

Hoe tel je datumcellen op basis van de dag van de week?

Zoals in de onderstaande schermafbeelding te zien is, is B3:B9 het originele gegevensbereik waarin je de datums wilt tellen, D3:D9 bevat de opeenvolgende namen van de weekdagen, en E3:E9 bevat de opeenvolgende nummers van 1 tot 7 om de weekdagnummers te vertegenwoordigen. Om te tellen hoeveel datums in B3:B9 gelijk zijn aan maandag, dinsdag, woensdag enzovoort, kun je als volgt te werk gaan.

Algemene formule

=SOMPRODUCT(--(WEEKDAG(datums)=dag_num))

Argumenten

Hoe gebruik je deze formule?

1. Selecteer een lege cel om het resultaat weer te geven.

2. Voer de onderstaande formule in en druk op de Enter-toets. Selecteer de resultaatcel en sleep vervolgens de automatische vulgreep naar beneden naar andere cellen in de huidige kolom om de formule toe te passen.

=SOMPRODUCT(--(WEEKDAG($B$3:$B$9,2)=E3))

Opmerking: Als er lege cellen in het originele bereik zijn, krijg je onjuiste resultaten. Om lege cellen uit te sluiten, pas dan de onderstaande formule toe:

=SOMPRODUCT((WEEKDAG($B$3:$B$9,2)=E3)*($B$3:$B$9<>""))

Hoe werkt deze formule?

=SOMPRODUCT(--(WEEKDAG($B$3:$B$9,2)=E3))

• WEEKDAG($B$3:$B$9,2): De functie WEEKDAG retourneert een geheel getal van 1 tot 7 om de dag van de week van B3:B9 te vertegenwoordigen. Hier is het resultaat {5;3;1;2;2;4;1}.
• {5;3;1;2;2;4;1}=E3: {5;3;1;2;2;4;1}=1 Hier wordt gecontroleerd of elk getal in de array gelijk is aan 1, en retourneert een array van WAAR/ONWAAR waarden als {ONWAAR;ONWAAR;WAAR;ONWAAR;ONWAAR;ONWAAR;WAAR}.
• --({ONWAAR;ONWAAR;WAAR;ONWAAR;ONWAAR;ONWAAR;WAAR}): Deze twee mintekens converteren “WAAR” naar 1 en “ONWAAR” naar 0. Hier krijg je een nieuwe array als {0;0;1;0;0;0;1}.
• SOMPRODUCT{0;0;1;0;0;0;1}: De functie SOMPRODUCT somt alle getallen in de array op en retourneert het eindresultaat als 2.

Gerelateerde functies

Gerelateerde formules