Voeg ruimte toe tussen cijfer en tekst in een cel in Excel
In dit artikel zullen we leren hoe u ruimte toevoegt tussen getal en tekst met formules in Excel.
Geval 1: voeg ruimte toe tussen cijfer en tekst - de tekst komt altijd op de eerste plaats
Geval 2: voeg ruimte toe tussen nummer en tekst - het nummer komt altijd op de eerste plaats
Voeg ruimte toe tussen cijfer en tekst - de tekst komt altijd op de eerste plaats
Stel dat er een lijst met tekstreeksen is die nummer en tekst bevat waarbij de tekst altijd als eerste komt, zoals de onderstaande schermafbeelding laat zien, dan kunt u ruimte toevoegen tussen het nummer en de tekst met de onderstaande formule.
Generieke formule
=TRIM(REPLACE(text_string,MIN(FIND({1,2,3,4,5,6,7,8,9,0},text_string&”1234567890”)),0,” “))
argumenten
Tekst reeks: De tekstreeks die u toevoegt tussen de tekst en het cijfer. Het kan zijn:
- De tekstreeks tussen aanhalingstekens;
- Of een verwijzing naar een cel met de tekstreeks.
Hoe gebruik je deze formule?
1. Selecteer een lege cel om het resultaat uit te voeren. In dit geval selecteer ik D3.
2. Voer de onderstaande formule in en druk op Enter sleutel. En sleep deze resultaatcel helemaal naar beneden om de formule op andere cellen toe te passen.
=TRIM(REPLACE(B3,MIN(FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")),0," "))
Opmerkingen:
- In de formule is B3 de cel van de tekenreeks waaraan u ruimte toevoegt tussen de tekst en het getal;
- Deze formule kan alleen een spatie toevoegen voor het eerste getal. Deze formule verandert bijvoorbeeld B34C12G45 in B 34C12G45.
Hoe werkt deze formule?
=TRIM(REPLACE(B3,MIN(FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")),0," "))
1. FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")
- B3&"1234567890": geeft het resultaat terug als: "KutoolsforExcel634211234567890";
- FIND({1,2,3,4,5,6,7,8,9,0}, "KutoolsforExcel634211234567890"): De functie FIND zoekt de positie van "1-0" cijfers in KutoolsforExcel634211234567890 en retourneert het resultaat als {20,19,17,18,25,16,27,28,29,30}.
Note: Het resultaat {20,19,17,18,25,16,27,28,29,30} betekent dat nummer 1 op de 20e positie staat in KutoolsforExcel634211234567890, nummer 2 staat op de 19e positie in KutoolsforExcel634211234567890 ...
2. MIN({20,19,17,18,25,16,27,28,29,30})
- De MIN-functie haalt de minimumwaarde van de array op. Hier is het resultaat 16.
3. REPLACE(KutoolsforExcel63421,16,0," ")
- Gebruik hier de functie VERVANG om een spatie toe te voegen aan de 16e positie in KutoolsforExcel63421 en retourneer het resultaat als KutoolsforExcel 63421.
4. =TRIM("KutoolsforExcel 63421")
- De TRIM-functie Verwijdert alle spaties uit tekst behalve enkele spaties tussen woorden. En houdt geen voorloop- en volgspaties van de tekst.
Voeg ruimte toe tussen nummer en tekst - het nummer komt altijd op de eerste plaats
Een ander geval zoals de onderstaande schermafbeelding laat zien, er is een lijst met tekstreeksen met nummer en tekst waarbij het nummer altijd eerst komt, u kunt de onderstaande matrixformule toepassen om een spatie toe te voegen tussen het nummer en de tekst.
Generieke formule
=TRIM(REPLACE(text_string,MAX(IFERROR(FIND({0,1,2,3,4,5,6,7,8,9},text_string,ROW(INDIRECT("1:"&LEN(text_string)))),0))+1,0," ")) + Ctrl + Shift + Enter
argumenten
Tekst reeks: De tekstreeks die u toevoegt tussen de tekst en het cijfer. Het kan zijn:
- De tekstreeks tussen aanhalingstekens;
- Of een verwijzing naar een cel met de tekstreeks.
Hoe gebruik je deze formule?
1. Selecteer een lege cel (in dit geval D3) om het resultaat uit te voeren.
2. Voer de onderstaande formule erin in en druk vervolgens op Ctrl + Shift + Enter toetsen tegelijk.
=TRIM(REPLACE(B3,MAX(IFERROR(FIND({0,1,2,3,4,5,6,7,8,9},B3,ROW(INDIRECT("1:"&LEN(B3)))),0))+1,0," "))
3. Selecteer de resultaatcel en sleep deze helemaal naar beneden om de formule op andere cellen toe te passen, zoals de onderstaande schermafbeelding laat zien.
Opmerkingen:
- In de formule is B3 de cel van de tekenreeks waaraan u ruimte toevoegt tussen de tekst en het getal;
- Deze matrixformule kan alleen een spatie toevoegen na het laatste getal. Deze formule verandert bijvoorbeeld 34C12GHH in 34C12 GHH.
Gerelateerde functies
Excel TRIM-functie
De Excel TRIM-functie verwijdert alle extra spaties uit de tekstreeks en houdt alleen enkele spaties tussen woorden.
Excel REPLACE-functie
De Excel REPLACE-functie zoekt en vervangt tekens op basis van de opgegeven locatie uit een tekstreeks door een nieuwe tekst.
Excel MIN-functie
De Excel MIN-functie retourneert het kleinste getal in een reeks waarden.
Excel FIND-functie
De Excel FIND-functie wordt gebruikt om een string binnen een andere string te zoeken, en geeft de startpositie van de string in een andere string terug.
Excel MAX-functie
De Excel MAX-functie retourneert het grootste getal in een reeks waarden.
Excel IFERROR-functie
De functie ALS.FOUT wordt gebruikt om een aangepast resultaat te retourneren wanneer een formule een fout evalueert, en om een normaal resultaat te retourneren wanneer er geen fout is opgetreden.
Excel RIJ-functie
De Excel ROW-functie retourneert het rijnummer van een verwijzing.
Excel INDIRECTE functie
De Excel INDIRECT-functie converteert een tekstreeks naar een geldige verwijzing.
Excel LEN-functie
De Excel LEN-functie retourneert het aantal tekens in een tekstreeks.
Gerelateerde formules
Voeg een komma toe na het eerste woord in een cel in Excel
Om alleen in een cel een komma toe te voegen na het eerste woord, kan de formule in deze tutorial je een plezier doen.
Voeg een specifiek teken toe voor elk woord in een cel
In dit artikel wordt uitgelegd hoe u een specifiek teken toevoegt vóór elk woord in een cel met formule in Excel.
Voeg streepjes toe aan het telefoonnummer
In dit artikel wordt uitgelegd hoe u streepjes aan het telefoonnummer in een bepaalde cel kunt toevoegen met een formule in Excel.
Voeg een komma toe tussen de namen
Om een komma tussen namen in een cel toe te voegen, kan de formule in deze tutorial je een plezier doen.
De beste tools voor kantoorproductiviteit
Kutools for Excel - Helpt u zich te onderscheiden van de menigte
Kutools voor Excel beschikt over meer dan 300 functies, Ervoor zorgen dat wat u nodig heeft slechts één klik verwijderd is...
Office-tabblad - Schakel lezen en bewerken met tabbladen in Microsoft Office in (inclusief Excel)
- Een seconde om te schakelen tussen tientallen geopende documenten!
- Verminder elke dag honderden muisklikken voor u, zeg maar dag tegen muishand.
- Verhoogt uw productiviteit met 50% bij het bekijken en bewerken van meerdere documenten.
- Brengt efficiënte tabbladen naar Office (inclusief Excel), net als Chrome, Edge en Firefox.
