Hoe importeert u verjaardagen uit Excel naar uw Outlook-agenda?

Als u een lange lijst met verjaardagsgegevens in een werkblad hebt en deze verjaardagen snel als afspraken in uw Outlook-agenda wilt importeren, hoe doet u dat dan het efficiëntst?

---

Verjaardagen vanuit Excel naar de Outlook-agenda importeren met VBA-code

Normaal gesproken kunt u verjaardagen niet direct importeren in uw Outlook-agenda — maar met de volgende VBA-code lost u dit probleem eenvoudig op. Volg hiervoor deze stappen:

1. Open het werkblad met de verjaardagen die u naar Outlook wilt importeren en druk daarna op ALT + F11 om het venster Microsoft Visual Basic for Applications te openen.

2. Klik op Invoegen > Module en plak de volgende code in het modulevenster.

VBA-code: Verjaardagen importeren in de Outlook-agenda

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Blijf in het venster Microsoft Visual Basic for Applications en klik op Extra > Verwijzingen. In het venster Verwijzingen – VBAProject dat verschijnt, vinkt u de optie Microsoft Outlook 16,0 Object Library aan in de lijst Beschikbare verwijzingen, zie de schermafbeelding:

4. Klik vervolgens op OK om dit venster te sluiten. Druk nu op de F5-toets om deze code uit te voeren. Er verschijnt een dialoogvenster waarin u de kolommen voor naam en verjaardag kunt selecteren. Selecteer deze alstublieft, zie de schermafbeelding:

5. Klik daarna op de knop OK, waarna de verjaardagen direct in uw Outlook-agenda worden geïmporteerd. Open Outlook om het resultaat te bekijken – zie de schermafbeelding: