Hoe haal ik het e-mailadres van de afzender uit een of meer e-mails in Outlook?

Heeft u ooit geprobeerd het e-mailadres uit het veld "Van" van een of meer ontvangen e-mails in Outlook te extraheren? Dit artikel bevat een VBA-code om u te helpen deze taak uit te voeren.

Haal het e-mailadres van de afzender uit een of meer e-mails in Outlook

Voer de volgende VBA-code uit om het e-mailadres uit het veld "Van" van een of meer ontvangen e-mails in Outlook te extraheren.

1. Open een e-mailmap, selecteer een e-mailbericht waarvan u het e-mailadres van de afzender wilt ontvangen. druk de anders + F11 toetsen om de te openen Microsoft Visual Basic voor toepassingen venster.

Tips: Om meerdere e-mails te selecteren, houdt u de . ingedrukt Ctrl toets en selecteer vervolgens de e-mails een voor een.

2. In de Microsoft Visual Basic voor toepassingen venster klikt Invoegen > Moduleen kopieer vervolgens de volgende VBA-code naar het venster Module (code).

VBA-code: haal het e-mailadres van de afzender uit een of meer e-mails in Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. klikken Tools > Referenties, controleer dan de Microsoft Scripting-runtime box aan de Referenties – Project1 dialoog venster.

4. druk de F5 sleutel om de code uit te voeren. Dan een Kutools for Outlook dialoogvenster verschijnt met alle e-mailadressen van de afzender van de geselecteerde e-mails.

Tips:

Als u de adreslijst naar een txt-bestand wilt exporteren, klikt u op de Ja knop.

Of klik op de Nee knop om het proces te beëindigen.

5. Na het klikken op de Ja knop, een Blader naar de map dialoogvenster verschijnt. Kies een map om het bestand op te slaan en klik op de OK knop.

6. Ten slotte, een Kutools for Outlook dialoogvenster verschijnt met het pad van het geëxporteerde bestand. Klik OK om het te sluiten.

7. Ga naar de map waar het geëxporteerde bestand is opgeslagen en open het .txt-bestand met de naam Adres om de e-mailadressen van de geselecteerde e-mails van de afzender te zien.