Hoe haalt u het e-mailadres van de afzender uit één of meerdere e-mails in Outlook?

AuteurSiluvia Wijzigingsdatum2024-09-13

Hebt u ooit geprobeerd het e-mailadres uit het veld 'Van' van één of meer ontvangen e-mails in Outlook te extraheren? Dit artikel biedt u een VBA-code om deze taak eenvoudig en efficiënt uit te voeren.

Haal het E-mailadres van de afzender uit één of meer e-mails in Outlook

Voer de volgende VBA-code uit om het e-mailadres uit het veld 'Van' van één of meerdere ontvangen e-mails in Outlook te extraheren.

1. Open een e-mailmap en selecteer een e-mailbericht waarvan u het e-mailadres van de afzender wilt ophalen. Druk op Alt+F11 om het venster Microsoft Visual Basic for Applications te openen.

Tips: Selecteer meerdere e-mails door de Ctrl-toets ingedrukt te houden en vervolgens de e-mails één voor één aan te klikken.

2. Klik in het venster Microsoft Visual Basic for Applications op Invoegen > Module en kopieer de volgende VBA-code naar het module-(code)venster.

stappen om het e-mailadres van de afzender op te halen uit één of meer e-mails in Outlook

VBA-code: haal het E-mailadres van de afzender uit één of meer e-mails in Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. Klik op Extra > Referenties en schakel vervolgens het selectievakje Microsoft Scripting Runtime in het dialoogvenster Referenties – Project1 in.

4. Druk op de F5-toets om de code uit te voeren. Er verschijnt dan een Kutools voor Outlook-dialoogvenster met alle e-mailadressen van de afzenders van de geselecteerde e-mails.

Tips:

Als u de Adreslijst naar een TXT-bestand wilt exporteren, klikt u op de knop Ja.

Of klik op de knop Neeom het proces te beëindigen.

5. Nadat u op de knop Ja hebt geklikt, verschijnt het dialoogvenster Map zoeken. Kies een map om het bestand op te slaan en klik op de knop OK.

6. Uiteindelijk verschijnt een Kutools voor Outlook-dialoogvenster met het pad van het geëxporteerde bestand. Klik op OK om het te sluiten.

7. Ga naar de map waar het geëxporteerde bestand is opgeslagen en open het .TXT-bestand met de naam Address om de e-mailadressen van de afzenders van de geselecteerde e-mails te bekijken.

Beste Office-productiviteitstools

Beleef de gloednieuwe Kutools voor Outlook met 100+ ongelooflijke functies!Klik nu om te downloaden!

🤖KUTOOLS AI:Gebruikt geavanceerde AI-technologie om e-mails moeiteloos te verwerken, waaronder beantwoorden, samenvatten, optimaliseren, uitbreiden, vertalen en opstellen van e-mails.

📧E-mailautomatisering: Automatisch antwoorden (beschikbaar voor POP en IMAP), e-mails plannen om te verzenden, automatisch CC/BCC toepassen op basis van regels bij het verzenden van e-mails, automatisch doorsturen (geavanceerde regels), automatisch een begroeting toevoegen en e-mails met meerdere ontvangers automatisch splitsen in afzonderlijke berichten…

📨E-mailbeheer: E-mail terughalen, spam-e-mails blokkeren op basis van onderwerp en andere criteria, dubbele e-mails verwijderen, geavanceerd zoeken en mappen organiseren…

📁Bijlagen Pro: Batch opslaan, batch loskoppelen, batch comprimeren, automatisch opslaan, automatisch loskoppelen en automatisch comprimeren…

🌟Interface-magie: 😊 Nog meer mooie en coole emoji’s / Waarschuwt u bij binnenkomst van belangrijke e-mails / Minimaliseert Outlook in plaats van het programma te sluiten...

👍Eénklikwonderen: Antwoord Allen met Bijlagen / Anti-phishing-e-mails / 🕘Huidige tijd van afzender-zone weergeven...

👩🏼‍🤝‍👩🏻Contacten & agenda: Batch Contact toevoegen vanuit geselecteerde e-mails / Een contactgroep splitsen in afzonderlijke groepen / Verjaardagsherinnering verwijderen…

Gebruik Kutools in uw voorkeurstaal – ondersteunt Engels, Spaans, Duits, Frans, Chinees en meer dan 40 andere talen!

Ontgrendel Kutools voor Outlook direct met één klik! Wacht niet langer—download nu en verhoog uw efficiëntie!

Functielijst van Kutools voor Outlook Nu downloaden Naar aankoop gaan

🚀 Eénklikdownload — Ontvang alle Office-invoegtoepassingen

Sterk aanbevolen: Kutools for Office (5-in-1)

Eén klik om vijf installatiebestandentegelijk te downloaden —Kutools voor Excel, Outlook, Word, PowerPointen Office Tab Pro.Klik nu om te downloaden!

✅Eénkliksgemak: Download alle vijf installatiepakketten in één keer.
🚀Klaar voor elke Office-taak: Installeer de invoegtoepassingen die u nodig heeft, precies op het moment dat u ze nodig heeft.
🧰Inbegrepen: Kutools voor Excel / Kutools voor Outlook / Kutools voor Word / Office Tab Pro / Kutools for PowerPoint

Over het pakket ⬇ Download het pakket 💳 Koop het pakket