Outlook: hoe u automatisch een e-mail opnieuw kunt verzenden als er geen reactie is

Wanneer u een e-mail verzendt naar een collega, samenwerkingspartner of iemand anders en dringend een reactie nodig heeft, kunt u automatisch opnieuw laten verzenden als er vóór een bepaald tijdstip nog geen antwoord is ontvangen.

Gebruik een herinnering en VBA om automatisch opnieuw te verzenden bij geen reactie

---

Gebruik een herinnering en VBA om automatisch opnieuw te verzenden bij geen reactie

Deel 1: stel een herinnering in om op een bepaald moment eraan te herinneren

1. Klik met de rechtermuisknop op een e-mail uit de map Verzonden items die u automatisch opnieuw wilt verzenden als er geen reactie komt, en kies in het contextmenu „Follow-up” > „Herinnering toevoegen”.

2. Laat in het venster „Aangepast” dat verschijnt het selectievakje „Herinnering” aangevinkt. Kies vervolgens in de onderstaande vervolgkeuzelijsten een datum en tijd waarop de reactie vóór moet zijn binnengekomen, of typ deze direct in de desbetreffende vakken. Klik daarna op „OK”.

Deel 2: Voeg een VBA-code in om e-mails opnieuw te verzenden als er binnen de opgegeven tijd geen reactie is

3. Druk op Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

4. Dubbelklik in het deelvenster „Project – Project1” op „ThisOutlookSession” om een leeg script te openen en plak de onderstaande VBA-code erin.

VBA: e-mail opnieuw verzenden bij geen reactie

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Sla de code op en keer terug naar de hoofdinterface. Klik op „Bestand” > „Opties”. Klik in het venster „Outlook-opties” in het linkerdeelvenster op „Trustcentrum” en klik vervolgens op „Trustcentrum-instellingen” om het venster „Trustcentrum” te openen. Klik op „Macro-instellingen” en zorg ervoor dat in het rechtergedeelte de optie „Alle macro’s inschakelen (niet aanbevolen; mogelijk gevaarlijke code kan worden uitgevoerd)” is geselecteerd. Klik op „OK” > „OK”.

6. Als de verzonden e-mail waarvoor een herinnering is ingesteld op het opgegeven tijdstip nog steeds geen reactie heeft ontvangen, verschijnt er een dialoogvenster dat vraagt of u de e-mail opnieuw wilt verzenden om een melding te sturen.

7. Klik op „Ja” – er verschijnt dan een berichtvenster met de vorige e-mail als bijlage. U kunt de inhoud bewerken en op „Verzenden” klikken om de e-mail opnieuw te versturen.

8. Klik op „Nee” om de herinnering te verwijderen.

Opmerking: als de e-mail al is beantwoord vóór het opgegeven tijdstip, verwijdert de VBA-code de herinnering automatisch.