Hoe verplaatst u automatisch verzonden vergaderuitnodigingen naar een specifieke map in Outlook?

Normaal gesproken worden zowel e-mails als verzonden vergaderuitnodigingen opgeslagen in de map Verzonden items, waardoor deze map snel rommelig en onoverzichtelijk raakt. In dit artikel introduceer ik een methode om verzonden vergaderingen automatisch naar een andere map te verplaatsen zodra ze zijn verzonden.

Verzendvergaderingen automatisch verplaatsen naar een specifieke map met VBA-code

---

Verzendvergaderingen automatisch verplaatsen naar een specifieke map met VBA-code

Om alle verzonden vergaderuitnodigingen automatisch naar een andere map te verplaatsen, gebruikt u de volgende code. Volg deze stappen:

1. Houd de toetsen ALT + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

2. Dubbelklik in het venster Microsoft Visual Basic for Applications op ThisOutlookSession in het deelvenster Project1 (VbaProject.OTM) om de module te openen, en plak vervolgens de volgende code in de lege module.

VBA-code: Verzendvergaderingen automatisch verplaatsen naar een specifieke map

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

3. Sluit vervolgens het codavenster met Opslaan en sluiten. Vanaf nu wordt een verzonden vergaderingsmail automatisch verplaatst naar een map met de naam Meetings onder de map Verzonden Items, zie de schermafbeelding: