Hoe drukt u taken af op basis van categorie in Outlook?

Stel dat uw Outlook-taken zijn onderverdeeld in verschillende kleurcategorieën en u de taaklijsten per categorie op afzonderlijke pagina’s wilt afdrukken. Hoe doet u dat in Outlook?

Taken op basis van categorieën handmatig één voor één op aparte pagina’s afdrukken

Taken op basis van categorieën met VBA-code op aparte pagina’s afdrukken

---

Taken op basis van categorieën handmatig één voor één op aparte pagina’s afdrukken

In Outlook kunt u taken handmatig, één voor één en gesorteerd per categorie, op afzonderlijke pagina’s afdrukken. Volg hiervoor deze stappen:

1. Start Outlook, ga naar het taakvenster en selecteer de taakmap die u wilt afdrukken. Druk vervolgens op Ctrl + E om het Zoekvak te activeren. Klik onder het tabblad Zoeken op het pictogram Gecategoriseerd en kies de kleurcategorie die u wilt afdrukken (zie schermafbeelding):

2. Alle taken met de geselecteerde kleurcategorie worden nu weergegeven (zie schermafbeelding):

3. Klik vervolgens op Bestand > Afdrukken om deze taaklijst af te drukken, zoals op de volgende schermafbeelding wordt getoond:

4. Herhaal de bovenstaande stappen om de takenlijsten handmatig één voor één af te drukken, elk met een andere kleurcategorie.

---

Taken op basis van categorieën met VBA-code op aparte pagina’s afdrukken

Hieronder vindt u een VBA-code waarmee u taken direct op aparte pagina’s kunt afdrukken, gesorteerd per categorie. Volg deze stappen:

1. Ga naar het Taakvenster en selecteer de taakmap die u wilt afdrukken.

2. Houd daarna de toetsen ALT + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

3. Klik vervolgens op Invoegen > Module en plak de onderstaande code in de geopende lege module:

VBA-code: Taken op basis van categorieën op aparte pagina’s afdrukken:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Klik daarna in het venster Microsoft Visual Basic for Applications op Extra > Verwijzingen. Schakel in het dialoogvenster Verwijzingen – Project1 bij de lijst Beschikbare verwijzingen de opties Microsoft Excel Object Library en Microsoft Scripting Runtime in (zie schermafbeelding):

5. Klik vervolgens op de knop OK en druk op de toets F5 om deze code uit te voeren. Nadat de code is uitgevoerd, worden de lijsten met taken per categorie op aparte pagina’s afgedrukt.