Hoe markeert u e-mails automatisch op basis van een specifieke bijlage in Outlook?

Wanneer u e-mails ontvangt met een belangrijke bijlage, wilt u die mogelijk markeren om ze snel en gemakkelijk terug te vinden voor vervolgacties. In dit artikel bespreek ik een eenvoudige methode om automatisch e-mails te markeren waarvan de bijlagen een specifieke bestandsnaam hebben.

Automatisch e-mails markeren op basis van een specifieke bijlage met VBA-code

---

Automatisch e-mails markeren op basis van een specifieke bijlage met VBA-code

Om e-mails automatisch te markeren die een specifieke bijlage bevatten, past u de volgende VBA-code toe:

1. Start Outlook en houd de toetsencombinatie Alt + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

2. Dubbelklik in het venster „Microsoft Visual Basic for Applications” op „ThisOutlookSession” in het deelvenster „Project1 (VbaProject.OTM)” om een nieuwe module te openen, en plak daarna de volgende code in de lege module.

VBA-code: Markeer e-mails automatisch op basis van een specifieke bijlage:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Opmerking: In de bovenstaande code kunt u de bestandsextensie en bestandsnaam van de bijlage naar wens aanpassen.

3. Sla de code vervolgens op en start Outlook opnieuw om de code actief te maken. Vanaf nu markeert Outlook automatisch elke ontvangen e-mail waarvan de bijlagen een opgegeven tekst in de bestandsnaam bevatten, voor vervolgactie. Zie onderstaande schermafbeelding: