Hoe exporteert u de mapstructuur vanuit Outlook naar Excel?

In dit artikel leg ik uit hoe u de mapstructuur van een Outlook-account exporteert naar een Excel-bestand. Volg gewoon de instructies in dit artikel.

Exporteer Mapstructuur van een account vanuit Outlook naar Excel met behulp van VBA-code

---

Exporteer Mapstructuur van een account vanuit Outlook naar Excel met behulp van VBA-code

De volgende VBA-code helpt u verder. Volg de onderstaande stappen:

1. Start Excel en houd de toetsen ALT + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

2. Klik op Invoegen > Module en plak de volgende code in het Module-venster.

VBA-code: Exporteer Mapstructuur van een account vanuit Outlook naar Excel:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3.Blijf in het venster Microsoft Visual Basic for Applications, klik op Extra>Verwijzingenom naar het dialoogvenster Verwijzingen – Project1te gaan, en schakel de optie Microsoft Excel Object Libraryin de lijst Beschikbare verwijzingenin, zie de schermafbeelding:

4. Klik daarna op de knop OK en druk op de toets F5 om deze code uit te voeren. Vervolgens verschijnt het dialoogvenster Map selecteren, waarin u het e-mailaccount kiest waarvan u de mapstructuur wilt exporteren. Zie de schermafbeelding:

5. Klik daarna op de knop OK, waarna het venster Bestand opslaan wordt weergegeven. Geef hier een locatie en bestandsnaam op voor het geëxporteerde bestand, zie de schermafbeelding:

6. Klik ten slotte op de knop Opslaan en ga naar het specifieke Excel-werkboek waarin u het bestand hebt opgeslagen om de geëxporteerde mapstructuur te bekijken. Zie de schermafbeelding: