Hoe maakt u een afspraak op basis van Excel-gegevens?

Stel dat u een tabel met afspraakgegevens hebt in een Excel-werkblad, zoals op de onderstaande schermafbeelding is weergegeven. Hoe importeert u deze gegevens snel in uw Outlook-agenda?

Afspraken maken vanuit Excel-gegevens met VBA-code

---

Afspraken maken vanuit Excel-gegevens met VBA-code

Om afspraken te plannen op basis van uw Excel-gegevens, past u eenvoudig de volgende VBA-code toe. Volg deze stappen:

1. Start Outlook en houd de toetsen ALT + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

2. Klik op Invoegen > Module en plak de volgende code in het Module-venster.

VBA-code: Excel-gegevens importeren naar afspraak:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Blijf in het venster Microsoft Visual Basic for Applications, klik op Extra > Verwijzingen om naar het dialoogvenster Verwijzingen – Project1 te gaan. Schakel vervolgens de optie Microsoft Excel Object Library in het vak Beschikbare verwijzingen in, zie de schermafbeelding:

4. Klik daarna op de knop OK en druk vervolgens op de toets F5 om deze code uit te voeren. Er verschijnt dan het venster Selecteer een bestand, waarin u het Excel-bestand selecteert dat u wilt importeren in Outlook. Zie de schermafbeelding:

5.Klik vervolgens op OK, waarna het volgende meldingsvenster wordt weergegeven:

6. Klik daarna op OK, waarna de Excel-gegevens zijn geïmporteerd in de agenda, zoals op de volgende schermafbeelding is weergegeven: