Hoe stelt u verschillende handtekeningen in voor antwoorden en doorsturen in Outlook?

Normaal gesproken kunt u verschillende handtekeningen instellen voor verschillende accounts in uw Outlook, maar heeft u ooit geprobeerd om verschillende handtekeningen toe te passen voor antwoorden en doorsturen? Dit betekent dat wanneer u op een e-mail antwoordt, handtekening1 wordt ingevoegd, en wanneer u een e-mail doorstuurt, handtekening2 wordt toegepast. Hoe kunt u deze taak in Outlook oplossen?

Stel verschillende handtekeningen in voor antwoorden en doorsturen met VBA-code

---

Stel verschillende handtekeningen in voor antwoorden en doorsturen met VBA-code

De volgende VBA-code helpt u om verschillende handtekeningen in te stellen voor antwoorden en doorstuurberichten. Volg de onderstaande stappen één voor één:

1. Houd de toetsen ALT + F11 ingedrukt om het venster Microsoft Visual Basic for Applications te openen.

2. Klik vervolgens op Invoegen > Module en kopieer de onderstaande code naar de geopende lege module. Zie de schermafbeelding:

VBA-code: Stel verschillende handtekeningen in voor antwoorden en doorsturen:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

Opmerking: In de bovenstaande code zijn Signature1 en Signature2 de twee handtekeningnamen die u wilt gebruiken voor beantwoorden en doorsturen. Pas de namen naar wens aan.

3. Blijf in het venster Microsoft Visual Basic for Applications, klik op Extra > Verwijzingen om naar het dialoogvenster Verwijzingen – Project1 te gaan, en vink de optie Microsoft Scripting Runtime aan in het lijstvak Beschikbare verwijzingen. Zie de schermafbeelding:

4. Klik vervolgens op OK om het dialoogvenster te sluiten. Vanaf nu wordt Signature1 automatisch ingevoegd wanneer u op een e-mail antwoordt. Zie de schermafbeelding:

En wanneer u een bericht doorstuurt, wordt Signature2 ingevoegd zoals op de volgende schermafbeelding wordt weergegeven: