Hoe wijzigt u automatisch uw handtekening in Outlook op basis van de ontvangers?

Standaard beschikt Outlook over een ingebouwde functie waarmee gebruikers automatisch de handtekening kunnen wijzigen wanneer ze e-mails verzenden via verschillende e-mailaccounts. Maar daarbuiten laat ik u hier een methode zien om automatisch de handtekening te wijzigen op basis van de verschillende ontvangers in het veld Aan in Outlook.

Wijzig automatisch de handtekening op basis van ontvangers met VBA-code

---

Wijzig automatisch de handtekening op basis van ontvangers met VBA-code

Volg de onderstaande stappen om bij het verzenden van e-mails in Outlook verschillende handtekeningen toe te passen op de bijbehorende ontvangers.

1. Schakel eerst de functie voor automatisch bijgevoegde handtekeningen in Outlook uit. Klik hiervoor op Bestand > Opties om het venster Outlook-opties te openen.

2. Selecteer in het venster Outlook-opties aan de linkerkant E-mail en klik vervolgens op de knop Handtekeningen in het gedeelte Berichten opstellen. Zie de afbeelding hieronder:

3. Ga in het dialoogvenster Handtekeningen en briefpapier naar het gedeelte Standaardhandtekening kiezen onder het tabblad E-mailhandtekening. Selecteer een e-mailaccount in de keuzelijst E-mailaccount, en kies vervolgens (geen) in de keuzelijsten Nieuwe berichten en Antwoorden/doorschrijven. Herhaal deze stappen totdat alle accounts zijn ingesteld op (geen). Klik daarna op de knop OK.

Opmerking: In dit dialoogvenster kunt u ook de gewenste handtekeningen aanmaken via Handtekeningen en briefpapier.

4. Klik op de knop OK wanneer u terugkeert naar het venster Outlook-opties.

5. Druk op de toetsencombinatie Alt+F11 om het venster Microsoft Visual Basic for Applications te openen.

6. Dubbelklik in het venster Microsoft Visual Basic for Applications in het linkerdeelvenster op ThisOutlookSession om het codevenster te openen en plak de onderstaande VBA-code in dit venster. Zie de afbeelding hieronder:

VBA-code: Wijzig automatisch de handtekening op basis van ontvangers in Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

Opmerkingen:

• 1). Vervang in de VBA-code het gedeelte "E-mailadres 1/2/3/4" door het specifieke e-mailadres van de ontvangers.
• 2). "aaa.htm", "bbb.htm„ en "ccc.htm" zijn de opgegeven handtekeningen die u naar de respectievelijke ontvangers zult sturen.
• 3). In dit geval wordt handtekening "aaa„ verzonden naar "E-mailadres 1„, handtekening "bbb„ naar "E-mailadres 2„ en "E-mailadres 3", terwijl "E-mailadres 4„ de e-mail ontvangt met daarin de ingebedde handtekening "ccc". Pas deze instellingen aan op basis van uw behoeften.
• 4). Als er meerdere ontvangers in een e-mail staan, houdt de code alleen rekening met de eerste ontvanger; de overige ontvangers ontvangen dan dezelfde handtekening als de eerste.

7. Klik vervolgens op Extra > Referenties om het dialoogvenster Referenties – Project te openen. Schakel in dit dialoogvenster zowel de optie Microsoft Word Object Library als Microsoft Scripting Runtime in en klik daarna op de knop OK. Zie onderstaande afbeelding:

8. Druk op de toetsencombinatie Alt+Q om het venster Microsoft Visual Basic for Applications te sluiten.

Vanaf nu wordt, zodra u een e-mail hebt opgesteld en op Verzenden klikt, automatisch de bijbehorende handtekening aan het einde van de e-mailbody ingevoegd op basis van het e-mailadres in het veld Aan.

---