Hoe stelt u Outlook-herinneringen in vanuit een Excel-werkblad?

Dit artikel laat zien hoe u Outlook-herinneringen kunt maken op basis van gegevens uit een Excel-werkblad.

Outlook-herinneringen maken vanuit een Excel-werkblad met VBA-code

---

Outlook-herinneringen maken vanuit een Excel-werkblad met VBA-code

Volg onderstaande stappen om Outlook-herinneringen te maken vanuit Excel.

1. Maak een werkblad met kolomkoppen en de bijbehorende herinneringsvelden, zoals weergegeven in de schermafbeelding hieronder.

Opmerking: In de kolom „Bezetstatus” geeft het getal „2” aan dat de herinnering als „Bezet” wordt weergegeven in uw Outlook-agenda. Indien gewenst kunt u dit wijzigen in „1 (Voorlopig)”, „3 (Afwezig)”, „4 (Elders aan het werk)” of „5 (Vrij)”.

2. Druk op Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

3. Klik in het venster „Microsoft Visual Basic for Applications” op „Invoegen” > „Module” en plak daarna de volgende VBA-code in het codovenster.

VBA-code: Outlook-herinneringen maken vanuit een Excel-werkblad

Sub AddAppointments()
'Update by Extendoffice 20180608
    Dim I As Long
    Dim xRg As Range
    Dim xOutApp As Object
    Dim xOutItem As Object
    Set xOutApp = CreateObject("Outlook.Application")
    Set xRg = Range("A2:G2")
    For I = 1 To xRg.Rows.Count
        Set xOutItem = xOutApp.CreateItem(1)
        Debug.Print xRg.Cells(I, 1).Value
        xOutItem.Subject = xRg.Cells(I, 1).Value
        xOutItem.Location = xRg.Cells(I, 2).Value
        xOutItem.Start = xRg.Cells(I, 3).Value
        xOutItem.Duration = xRg.Cells(I, 4).Value
        If Trim(xRg.Cells(I, 5).Value) = "" Then
            xOutItem.BusyStatus = 2
        Else
            xOutItem.BusyStatus = xRg.Cells(I, 5).Value
        End If
        If xRg.Cells(I, 6).Value > 0 Then
            xOutItem.ReminderSet = True
            xOutItem.ReminderMinutesBeforeStart = xRg.Cells(I, 6).Value
        Else
            xOutItem.ReminderSet = False
        End If
        xOutItem.Body = xRg.Cells(I, 7).Value
        xOutItem.Save
        Set xOutItem = Nothing
    Next
    Set xOutApp = Nothing
End Sub

Opmerking: In de bovenstaande code is „A2:G2” het gegevensbereik waarop u afspraken wilt baseren.

4. Druk op „F5” of klik op de knop „Uitvoeren” om de code uit te voeren — en alle afspraken met de opgegeven velden worden direct toegevoegd aan uw Outlook-agenda.

U kunt daarna de agenda in uw Outlook openen om de resultaten te bekijken. Zie de schermafbeelding: