Hoe controleert u de ontvangeradressen voordat u een e-mail verzendt via Outlook?

Soms vergeet u belangrijke ontvangers toe te voegen aan de velden Aan, CC of BCC bij het verzenden van e-mails via Outlook. Hieronder introduceer ik een methode om te controleren of het specifieke e-mailadres is toegevoegd voordat u de e-mail verzendt.

Controleer adressen vóór verzenden met VBA-code

---

Controleer adressen vóór verzenden met VBA-code

Hier zijn twee codes die u kunnen helpen bij deze taak; kies er één naar behoefte.

1. Druk op Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

2. Dubbelklik op ThisOutlookSession in het deelvenster Project1 om de code-editor te openen en plak de onderstaande code in de editor.

VBA: controleer ontvangeradres in het Aan-veld vóór verzenden

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'UpdatebyExtendoffice20180523
Dim xAddressArr() As Variant
Dim xAddress As String
Dim xRecipient As Recipient
Dim xPrompt As String
Dim xYesNo As Integer
Dim xDictionary As Scripting.Dictionary
On Error Resume Next
Set xDictionary = New Scripting.Dictionary
xAddressArr = Array("example1@126.com", "example2@126.com", "example3@126.com")
For i = LBound(xAddressArr) To UBound(xAddressArr)
    xDictionary.Add xAddressArr(i), True
Next i
For Each xRecipient In Item.Recipients
    If xRecipient.Type = olTo Then
        If xDictionary.Exists(xRecipient.Address) Then xDictionary.Remove xRecipient.Address
    End If
Next
If xDictionary.Count = 0 Then GoTo L1
For i = 0 To xDictionary.Count - 1
    If xAddress = "" Then
        xAddress = xDictionary.Keys(i)
    Else
        xAddress = xAddress + "; " & xDictionary.Keys(i)
    End If
Next i
xPrompt = "You are not sending this to: " & xAddress & ". Are you sure you want to send the Mail?"
xYesNo = MsgBox(xPrompt, vbQuestion + vbYesNo, "Kutools for Outlook")
If xYesNo = vbNo Then Cancel = True
L1:
  Set xRecipient = Nothing
  Set xDictionary = Nothing
End Sub

In de code kunt u ("example1@126.com", "example2@126.com", „example3@126.com") eenvoudig vervangen door de daadwerkelijke ontvangers die u nodig heeft.

3. Ga vervolgens in het venster Microsoft Visual Basic for Applications naar Extra > Verwijzingen. Schakel in het dialoogvenster Verwijzingen - Project1 het selectievakje Microsoft Scripting Runtime in.

4. Klik op OK en sla de code op.

Als de opgegeven ontvangers niet in het Aan-veld staan bij het verzenden van e-mails, verschijnt er nu een dialoogvenster dat vraagt of u de e-mail alsnog wilt verzenden.

Met de bovenstaande code wordt alleen het Aan-veld gecontroleerd. Als u ook de velden Aan, CC en BCC wilt controleren, kunt u de onderstaande code gebruiken.

VBA: controleer ontvangeradres in de Aan/CC/BCC-velden vóór verzenden

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'UpdatebyExtendoffice20180523
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim xPos As Integer
Dim xYesNo As Integer
Dim xPrompt As String
Dim xAddress As String
On Error Resume Next
If Item.Class <> olMail Then Exit Sub
Set xRecipients = Item.Recipients
xAddress = "example1@gmail.com"
For Each xRecipient In xRecipients
    xPos = InStr(LCase(xRecipient.Address), xAddress)
    If xPos = 0 Then
        xPrompt = "You sending this to " & xAddress & ". Are you sure you want to send it?"
        xYesNo = MsgBox(xPrompt, vbYesNo + vbQuestion + 4096, "Kutools for Outlook")
        If xYesNo = vbNo Then Cancel = True
    End If
Next xRecipient
End Sub

Met deze code hoeft u het selectievakje Microsoft Scripting Runtime niet in te schakelen; sla de code gewoon direct op om het effectief te maken.