Volg onderstaande stappen om de Outlook-mapstructuur naar het bureaublad of Windows Verkenner te kopiëren.

1. Klik in het navigatiedeelvenster om de opgegeven map te markeren waarvan u de mapstructuur wilt kopiëren, en druk op anders + F11 -toetsen om het venster Microsoft Visual Basic for Applications te openen.

2. klikken Tools > Referenties om het dialoogvenster Verwijzingen te openen. Vink vervolgens in het dialoogvenster het Microsoft Scripting-runtime optie en klik op de OK knop. Zie screenshot:

3. klikken Invoegen > Module, en kopieer en plak onder VBA-code in het nieuwe modulevenster.

VBA: kopieer de Outlook-mapstructuur naar Windows Verkenner

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. druk op F5 toets of klik op de lopen knop om deze VBA uit te voeren.

5. Selecteer in het pop-upvenster Bladeren naar map de opgegeven map waarin u de gekopieerde mapstructuur wilt plaatsen en klik op de knop OK knop. Zie screenshot:

Ga nu naar de opgegeven map, u zult zien dat de mapstructuur naar de opgegeven harde schijf wordt gekopieerd. Zie schermafbeelding:

Note: de mapitems, zoals e-mails, afspraken, taken, etc. worden ook gekopieerd naar de overeenkomstige mappen op de harde schijf.

Hoe de mapstructuur naar een nieuw PST-gegevensbestand in Outlook te kopiëren?