Hoe vindt u een map, inclusief het volledige bestandspad, op basis van de mapnaam in Outlook?

Volg onderstaande stappen om mappen te zoeken op basis van mapnaam met VBA in Outlook.

1. Druk tegelijkertijd op Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

2. Klik op 'Invoegen' > 'Module' en plak daarna de onderstaande VBA-code in het nieuwe modulevenster.

VBA: Zoek en Map openen op basis van Mapnaam in Outlook

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. Druk op de toets F5 of klik op de knop Uitvoeren om deze VBA-code uit te voeren.

4. Typ in het verschijnende dialoogvenster „Map zoeken" de mapnaam waarnaar u wilt zoeken en klik op de knop „OK".

Opmerking: Deze VBA ondersteunt het jokerteken asterisk (*). U kunt bijvoorbeeld „tes*” typen om alle mappen te vinden waarvan de naam begint met „tes”.

5. Er verschijnt nu een dialoogvenster met het bestandspad van de gevonden map. Klik op de knop ‘Ja’ om de map direct te openen.

De gevonden map wordt nu geopend in het Navigatie, zoals hieronder in de schermafbeelding is weergegeven:

Opmerking: Als er meerdere mappen zijn met de opgegeven naam, kan deze VBA-code er maar één vinden en openen.

Als u „Kutools voor Outlook” heeft geïnstalleerd, kunt u met de functie „Ga naar” razendsnel alle mappen zoeken op basis van een specifieke mapnaam en direct een van de gevonden mappen openen.

1. Klik op „KUTOOLS PLUS” > „Ga naar” om deze functie te activeren.

2. Typ in het dialoogvenster „Ga naar” de opgegeven mapnaam in het vak „Zoeken”, selecteer een map in de zoekresultaten en klik op de knop „OK”.

De opgegeven map met de betreffende mapnaam wordt nu direct gevonden en geopend.