Hoe vouw je automatisch alle mappen uit bij het opstarten van Outlook?

Normaal gesproken behoudt een map in Outlook na het afsluiten van het programma zijn uitgevouwen of samengevouwen status in de navigatie. Maar wat als u wilt dat alle mappen automatisch worden uitgevouwen telkens wanneer u Outlook opstart? Dit artikel biedt een VBA-oplossing om dat voor elkaar te krijgen.

Automatisch Alle mappen uitvouwen bij het opstarten van Outlook met VBA

---

Automatisch Alle mappen uitvouwen bij het opstarten van Outlook met VBA

In deze handleiding leest u hoe u met een VBA-script automatisch alle mappen in de navigatie uitvouwt telkens wanneer u Outlook opstart. Volg deze stappen om het VBA-script toe te passen:

1. Druk tegelijkertijd op Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.
2. Vouw Project 1en Microsoft Outlook-objectenuit in het Project-deelvenster, dubbelklik om het venster ThisOutlookSessionte openen en plak vervolgens de onderstaande VBA-code hierin.

   

   VBA: Automatisch Alle mappen uitvouwen in Outlook

   Public WithEvents GEx As Explorer
   Public GFlag As Boolean
   Private Sub Application_Startup()
     'Update by ExtendOffice 2023/12/08
     Set GEx = Application.ActiveExplorer
     GFlag = False
   End Sub
   
   Private Sub GEx_SelectionChange()
     If GFlag = False Then
       ExpandAllFolders
     End If
     GFlag = True
   End Sub
   
   Public Sub ExpandAllFolders()
     Dim xNameSpace As Outlook.NameSpace
     Dim xFlds As Outlook.Folders
     Dim xCurrFld As Outlook.MAPIFolder
     Dim xFld As Outlook.MAPIFolder
     Dim xExpandDefaultStoreOnly As Boolean
     Dim xModule As NavigationModule
     On Error Resume Next
     xExpandDefaultStoreOnly = False
     Set xNameSpace = Application.Session
     Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
     Set xCurrFld = Application.ActiveExplorer.CurrentFolder
     If xExpandDefaultStoreOnly = True Then
       Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
       Set xFld = xFld.Parent
       Set xFlds = xFld.Folders
       LoopFolders xFlds, True
     Else
       LoopFolders xNameSpace.Folders, True
       LoopFolders xNameSpace.Folders, False
     End If
     DoEvents
     Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
     Set Application.ActiveExplorer.CurrentFolder = xCurrFld
     Set xNameSpace = Nothing
     Set xModule = Nothing
     Set xCurrFld = Nothing
   End Sub
   
   Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
     Dim xFld As Outlook.MAPIFolder
     On Error Resume Next
     For Each xFld In Flds
       Select Case All
         Case True
           If xFld.DefaultItemType = olMailItem Then
             Set Application.ActiveExplorer.CurrentFolder = xFld
             DoEvents
             If xFld.Folders.Count > 0 Then
               LoopFolders xFld.Folders, All
             End If
           End If
         Case False
           Set Application.ActiveExplorer.CurrentFolder = xFld
           DoEvents
           If xFld.Folders.Count > 0 Then
             LoopFolders xFld.Folders, All
           End If
       End Select
     Next
   End Sub

3. Sla de code op en sluit het Microsoft Visual Basic for Applications-venster.

Vanaf nu worden alle mappen automatisch uitgevouwen zodra u Outlook opnieuw start.

---

Gerelateerde artikelen