Hoe exporteert en print u de lijst van alle mappen en submappen in Outlook?

Over het algemeen toont u de lijst met alle mappen in de Navigatie van Outlook door op **Ctrl + 6** te drukken. Helaas kunt u deze maplijst niet direct afdrukken. Dit artikel presenteert twee VBA-scripts waarmee u de lijst van alle mappen en hun submappen in Outlook eenvoudig kunt exporteren en afdrukken.

• Exporteer en print de lijst van alle Outlook-mappen en hun submappen in Nieuwe Email
• Exporteer en print de lijst van alle Outlook-mappen en hun submappen in Kladblok

---

Exporteer en print de lijst van alle Outlook-mappen en hun submappen in Nieuwe Email

Deze methode gebruikt een VBA-script om de lijst van alle mappen en hun submappen van een opgegeven e-mailaccount naar een nieuw e-mailbericht in Outlook te exporteren, zodat u de maplijst gemakkelijk kunt afdrukken.

1. Druk op Alt + F11 om het Microsoft Visual Basic for Applications-venster te openen.

2. Klik op "Invoegen" > „Module" en plak de volgende VBA-code in het nieuwe modulevenster.

VBA: Exporteer de lijst van mappen en submappen in een Nieuwe Email in Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. Druk op F5 om de VBA-code uit te voeren.

4. Selecteer in het dialoogvenster **Map selecteren** het e-mailaccount waarvan u de maplijst wilt afdrukken en klik op **OK**.

5. De maplijst van het geselecteerde account wordt gekopieerd naar een nieuw e-mailbericht, zoals hieronder weergegeven. Klik op **Bestand** > **Afdrukken** om de maplijst af te drukken.

6. Sluit na het afdrukken de Nieuwe e-mail zonder op te slaan.

---

Exporteer en print de lijst van alle Outlook-mappen en hun submappen in Kladblok

Deze methode gebruikt een VBA-script om de lijst van alle mappen en hun submappen van een opgegeven e-mailaccount in Outlook naar Kladblok te exporteren, zodat u de maplijst eenvoudig kunt afdrukken.

1. Druk op Alt + F11 om het Microsoft Visual Basic for Applications-venster te openen.

2. Klik op 'Invoegen' > 'Module' en plak de volgende VBA-code in het nieuwe modulevenster.

VBA: Exporteer de lijst van alle Outlook-mappen en submappen van Outlook naar Kladblok

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. Druk op F5 om de VBA uit te voeren. Selecteer in het dialoogvenster **Map selecteren** het e-mailaccount waarvan u de maplijst wilt exporteren en afdrukken, en klik op **OK**.

4. Het dialoogvenster Uitvoer mapstructuur verschijnt. Klik op 'Ja' als u structuurspatiëring wilt opnemen, of op 'Nee' als dat niet het geval is.

Er is nu een Tekstbestand met de naam „Outlook-Folders” gemaakt en opgeslagen op uw bureaublad, zoals hieronder weergegeven:

5. Dubbelklik om het nieuwe tekstbestand te openen en kies daarna "Bestand" > „Afdrukken" om de geëxporteerde lijst met Outlook-mappen af te drukken.

Gerelateerde artikelen

Maplijstweergave tonen of verbergen in Outlook