Hoe schakelt u de waarschuwing uit dat er geen onderwerp is ingevuld in Outlook?

Wanneer u Outlook 2010 of 2013 gebruikt, verschijnt er bij het verzenden van e-mails zonder onderwerp automatisch een waarschuwingsvenster ter herinnering. Als u bewust geen onderwerp wilt invullen, kan deze melding ‘geen onderwerp’ behoorlijk hinderlijk zijn. In de volgende handleiding geven we u een handige tip om deze waarschuwing definitief uit te schakelen.

Waarschuwing voor geen onderwerp uitschakelen in Outlook

---

Waarschuwing voor geen onderwerp uitschakelen in Outlook

In Outlook 2007 wordt er geen waarschuwing weergegeven wanneer u een e-mail verzendt zonder onderwerp. Deze functie is standaard ingeschakeld in Outlook 2010 en 2013, maar er is geen ingebouwde optie om de waarschuwing direct uit te schakelen. In deze handleiding laten we u VBA-code zien waarmee u dit alsnog kunt regelen.

1. Druk op de toetsencombinatie Alt + F11 om het dialoogvenster Microsoft Visual Basic for Applications te openen.

2. Vouw "Project1" > „Microsoft Outlook-objecten" uit door er dubbel op te klikken en open vervolgens „ThisOutlookSession" met een dubbelklik om het venster „VbaProject.OTM" te openen.

3. Kopieer en plak de onderstaande VBA-code in het venster.

VBA: Waarschuwing voor geen onderwerp uitschakelen

Option Explicit
Private WithEvents oInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set oInspectors = Outlook.Inspectors
End Sub

Private Sub oInspectors_NewInspector(ByVal Inspector As Inspector)
    Dim oItem As Object
    On Error GoTo ExitProc
    Set oItem = Inspector.CurrentItem
    If oItem.Sent = False Then
        If oItem.Subject = "" Then oItem.Subject = " "
    End If
ExitProc:
    Set oItem = Nothing
    Set Inspector = Nothing
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    On Error Resume Next
    Item.Subject = Trim(Item.Subject)
End Sub

Private Sub Application_Quit()
    Set oInspectors = Nothing
End Sub

4. Klik op de knop „Opslaan" om uw VBA-code veilig op te slaan.

5. Start de Outlook-toepassing opnieuw.

De VBA-code wordt dan geactiveerd. Vanaf nu verschijnt het waarschuwingsvenster voor ‘geen onderwerp’ niet meer wanneer u een bericht verzendt zonder onderwerp.

Opmerking: Zorg ervoor dat de optie „Alle macro's inschakelen" is aangevinkt. (Controleer dit via "Bestand" > "Opties" > "Trustcentrum" > „Trustcentrum-instellingen" en kies in het dialoogvenster „Trustcentrum" de optie "Macro-instellingen" > „Alle macro's inschakelen"), zie screenshot: