Skip to main content

Kutools voor Office — Eén Suite. Vijf Tools. Verwezenlijkt Meer.

Unieke en verschillende waarden gemakkelijk tellen – 7 voorbeelden

Author Xiaoyang Last modified

Normaal gesproken zijn in Excel de unieke waarden de waarden die slechts één keer voorkomen in de lijst zonder duplicaten, en verschillende waarden zijn alle verschillende waarden (unieke waarden + eerste duplicaatvoorkomens). Bij het werken met een grote dataset moet u mogelijk het aantal unieke en verschillende waarden onder duplicaten tellen vanuit een lijst met cellen zoals in onderstaande schermafbeelding te zien is. Deze handleiding introduceert enkele snelle trucs om de unieke en verschillende waarden in Excel te tellen.

Count unique values or distinct values in a list

Unieke waarden tellen in Excel

Verschillende waarden tellen (uniek en eerste duplicaatvoorkomens) in Excel

Voorbeeldbestand downloaden

Unieke en verschillende waarden tellen

Unieke waarden tellen in Excel

In deze sectie bespreken we enkele formulevoorbeelden voor het tellen van het aantal unieke waarden, inclusief tekst en getallen in een lijst.

Unieke waarden tellen met formules

Stel dat ik een lijst met namen heb die enkele dubbele namen bevat binnen de naamlijst. Nu moet ik het aantal unieke namen krijgen (die gevuld zijn met geel) zoals in onderstaande schermafbeelding te zien is:

sample data

Om dit probleem op te lossen, kan de volgende matrixformule u helpen:

Stap 1: Formule invoeren

Voer of kopieer de onderstaande formule in een lege cel in waar u het resultaat wilt tonen:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 Opmerking: In de bovenstaande formule is "A2:A12" de gegevenslijst waarvan u de unieke waarden wilt tellen.

Stap 2: Druk op Ctrl + Shift + Enter om het juiste resultaat te krijgen:

Count unique values with formula

Opmerkingen:

  1. Als uw lijst met cellen andere soorten gegevens bevat, zoals getallen, Booleaanse waarden, foutwaarden, etc., zal de bovenstaande formule het aantal unieke waarden tellen ongeacht het gegevenstype.
  2. Wanneer de gegevenslijst lege cellen bevat, zal deze formule de lege cellen uitsluiten.
  3. Om alleen de unieke tekstwaarden te tellen als er andere soorten gegevens zijn, kunt u de onderstaande matrixformule toepassen en vervolgens op "Ctrl" + "Shift" + "Enter" drukken om het resultaat te retourneren: 
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Om alleen unieke getallen te tellen uit een lijst met cellen die elk type gegevens bevat, gebruikt u de volgende matrixformule en drukt u op "Ctrl" + "Shift" + "Enter" om het resultaat te retourneren: 
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Unieke waarden tellen met enkele klikken met Kutools voor Excel

Het kan lastig zijn om de formules te onthouden wanneer u ze de volgende keer moet toepassen. Maar als u "Kutools voor Excel" heeft, kunt u met de optie "Unieke waarden tellen" in "Formulehulp" het resultaat krijgen met slechts enkele klikken. Zie onderstaande demo:

  1. Klik op een cel om het resultaat weer te geven;
  2. Activeer deze functie door te klikken op "Kutools" > "Formulehulp" > "Formulehulp" > "Statistisch" > "Unieke waarden tellen";
  3. Selecteer de lijst met gegevens > "OK".
    Count unique values with kutools
Tips:
  1. Om deze functie te gebruiken, moet u Kutools voor Excel downloaden en installeren.
  2. De functie "Formulehulp" verzamelt meer dan 40 veelgebruikte formules, zoals "Unieke waarden extraheren", "Cellen met unieke waarden extraheren (inclusief de eerste duplicaten)", "Het aantal waarden gescheiden door komma's tellen", "Som op basis van dezelfde tekst", en meer...

Unieke waarden tellen in Excel 365/2021 met formules

Als u Excel 365 of Excel 2021 gebruikt, is er een nieuwe UNIEKE functie die u kan helpen om eenvoudigere formules te maken om unieke waarden in een set gegevens te tellen.

Bijvoorbeeld, om het aantal unieke namen in het bereik A2:A12 te tellen, voert u de volgende formule in:

Stap 1: Kopieer of voer de onderstaande formule in

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Opmerking: In deze formule is "A2:A12" de gegevenslijst waarvan u de unieke waarden wilt tellen.

Stap 2: Druk op Enter om het resultaat te krijgen:

Count unique values in Excel 365/2021 with formula

Tips:

  1. Als de gegevenslijst andere soorten gegevens bevat, zoals tekst, getallen, Booleaanse waarden, foutwaarden, etc., zal deze formule het aantal unieke waarden tellen ongeacht het gegevenstype.
  2. De bovenstaande formule telt unieke waarden inclusief lege cellen. Als u de lege cellen wilt uitsluiten, past u de onderstaande formule toe en drukt u gewoon op "Enter": 
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Verschillende waarden tellen (uniek en eerste duplicaatvoorkomens) in Excel

Om de verschillende waarden (unieke waarden en eerste duplicaatvoorkomens) in een lijst met cellen te tellen, zal ik hier andere formules introduceren om deze taak te voltooien.

Verschillende waarden tellen met formules

In Excel kunt u een van de onderstaande formules toepassen om het aantal verschillende waarden te retourneren.

Stap 1: Voer een van de onderstaande formules in

Formule 1: Nadat u de formule hebt ingevoerd, drukt u op "Enter".

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formule 2: Nadat u de formule hebt ingevoerd, drukt u op "Ctrl" + "Shift" + "Enter".

=SUM(1/COUNTIF(A2:A12,A2:A12))
Opmerking: In deze formules is "A2:A12" de gegevenslijst waarvan u de verschillende waarden wilt tellen.

Resultaat:

Count distinct values with formula

Tips:

  1. Als de gegevenslijst andere soorten gegevens bevat, zoals getallen, Booleaanse waarden, foutwaarden, etc., zal deze formule de verschillende waarden tellen ongeacht het gegevenstype.
  2. Bij het gebruik van de bovenstaande formule krijgt u de foutwaarde #DEEL/0 als de gegevenslijst lege cellen bevat. Om dit te corrigeren en lege cellen te negeren, moet u een van de onderstaande formules toepassen:
    Formule 1: Nadat u de formule hebt ingevoerd, drukt u op "Enter". 
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formule 2: Nadat u de formule hebt ingevoerd, drukt u op "Ctrl" + "Shift" + "Enter". 
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Count distinct values exclude blank cells with formula

  3. Om alleen het aantal verschillende tekstwaarden binnen een lijst met gegevens te krijgen, past u de onderstaande matrixformule toe en drukt u op "Ctrl" + "Shift" + "Enter" om het resultaat te krijgen: 
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Om alleen verschillende numerieke waarden te tellen, gebruikt u de volgende matrixformule en drukt u op "Ctrl" + "Shift" + "Enter" om het resultaat te krijgen: 
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Verschillende waarden tellen met enkele klikken met Kutools voor Excel

Als u de formules vaak in uw werkboek moet toepassen, kan het lastig zijn om de formules te onthouden wanneer u ze de volgende keer moet toepassen. Maar als u "Kutools voor Excel" heeft, kunt u met de optie "Cellen met unieke waarden tellen (inclusief de eerste duplicaat)" in "Formulehulp" het resultaat krijgen met slechts enkele klikken. Zie onderstaande demo:

  1. Klik op een cel om het resultaat weer te geven;
  2. Activeer deze functie door te klikken op "Kutools" > "Formulehulp" > "Statistisch" > "Unieke cellen met unieke waarden tellen (inclusief de eerste duplicaat)";
  3. Selecteer de lijst met gegevens > "OK".
    Count distinct values with kutools
Tips:
  1. Om deze functie te gebruiken, moet u Kutools voor Excel downloaden en installeren.
  2. De functie "Formulehulp" verzamelt meer dan 40 veelgebruikte formules, zoals "Unieke waarden extraheren", "Cellen met unieke waarden extraheren (inclusief de eerste duplicaten)", "Het aantal waarden gescheiden door komma's tellen", "Som op basis van dezelfde tekst", en meer...

Verschillende waarden tellen met Draaitabel

In Excel kan de Draaitabel ook helpen om het aantal verschillende waarden uit een lijst met gegevens te krijgen. Volg de volgende stappen:

Stap 1: Maak een draaitabel

  1. Selecteer de gegevenslijst en klik vervolgens op "Invoegen" > "Draaitabel" in de menubalk, zie onderstaande schermafbeelding:
    create a pivottable for selected data
  2. In het pop-upvenster "Draaitabel" uit tabel of bereik dialoogvenster:
    (1). Kies een nieuw werkblad of bestaand werkblad waar u de draaitabel wilt plaatsen;
    (2). Vink vervolgens het selectievakje "Voeg deze gegevens toe aan het Gegevensmodel" aan.
    (3). Klik vervolgens op de knop "OK".
    set options in PivotTable from table or range dialog box

Stap 2: Rangschik het veld en kies de optie Verschillend Tellen

  1.  Een "Draaitabelvelden" paneel wordt weergegeven, sleep het veld "Namen" naar het gebied "Waarden", zie onderstaande demo:
    Arrange the field for pivottable
  2. Klik vervolgens op de vervolgkeuzelijst "Aantal Namen" en kies "Waardeveldinstellingen", zie onderstaande schermafbeelding:
    click value Field Settings option
  3. Er wordt een dialoogvenster "Waardeveldinstellingen" geopend, selecteer "Verschillend Tellen" uit de lijst onder het tabblad "Waarde samenvatten door" en klik op "OK", zie onderstaande schermafbeelding:
    select Distinct Count option

Resultaat:

Nu toont de gemaakte draaitabel het verschillend aantal van de gegevenslijst zoals in onderstaande schermafbeelding te zien is:

PivotTable result to count distinct values

Tips:

  1. Als u uw brongegevens bijwerkt, hoeft u alleen met de rechtermuisknop op de draaitabel te klikken en "Vernieuwen" te selecteren om de laatste telling te krijgen.
  2. Deze optie "Verschillend Tellen" is alleen beschikbaar in Excel 2013 en later.

Verschillende waarden tellen in Excel 365/2021 met formules

In Excel 365 of Excel 2021 kunt u de nieuwe UNIEKE functie met de normale AANTAL.ALS functie gebruiken om een eenvoudige formule te maken.

Kopieer of voer de onderstaande formule in een lege cel in en druk op "Enter" om het resultaat te krijgen:

=COUNTA(UNIQUE(A2:A12))
Opmerking: In deze formule is "A2:A12" de gegevenslijst waarvan u de verschillende waarden wilt tellen.

Count distinct values in Excel 365/2021 with formula

Tips:

  1. Als de gegevenslijst andere soorten gegevens bevat, zoals tekst, getallen, Booleaanse waarden, foutwaarden, etc., zal deze formule het aantal verschillende waarden tellen ongeacht het gegevenstype.
  2. De bovenstaande formule telt verschillende waarden inclusief lege cellen. Als u de lege cellen wilt uitsluiten, past u de onderstaande formule toe en drukt u op "Enter" om het resultaat te krijgen: 
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Count distinct values in Excel 365/2021 with formula exclude blank cells

Gerelateerde artikelen:

  • Unieke waarden tellen in draaitabel
  • Standaard worden bij het maken van een draaitabel op basis van een bereik met gegevens dat enkele dubbele waarden bevat, alle records ook geteld. Maar soms willen we alleen de unieke waarden tellen op basis van één kolom om het juiste resultaat te krijgen. In dit artikel bespreek ik hoe u de unieke waarden in een draaitabel kunt tellen.
  • Unieke waarden tellen in een gefilterde kolom
  • Als u een lijst met namen heeft die met enkele duplicaten in een gefilterde kolom is gevuld, en nu wilt u het aantal unieke namen alleen uit deze gefilterde lijst tellen. Heeft u goede oplossingen om deze taak snel af te handelen in Excel?
  • Unieke waarden tellen met meerdere criteria
  • Hier is een bereik met gegevens dat verschillende namen, projecten en locaties bevat, en wat u moet doen is de namen vinden die overeenkomen met de criteria die u hebt opgegeven, en vervolgens elk overeenkomstig item één keer tellen zoals in onderstaande schermafbeelding te zien is. Heeft u trucs om deze taak op te lossen? In dit artikel introduceer ik de trucs.
  • Unieke waarden samenvoegen
  • Als ik een lange lijst met waarden heb die met enkele dubbele gegevens is gevuld, wil ik nu alleen de unieke waarden vinden en deze samenvoegen in één cel. Hoe kan ik dit probleem snel en gemakkelijk in Excel oplossen?