Note: The other languages of the website are Google-translated. Back to English
Inloggen Registreren

Tel eenvoudig unieke en verschillende waarden – 6 voorbeelden

Normaal gesproken zijn in Excel de unieke waarden de waarden die slechts één keer in de lijst voorkomen zonder enige duplicatie, en verschillende waarden zijn alle verschillende waarden (unieke waarden + 1e dubbele exemplaren). Wanneer u aan een grote gegevensset werkt, moet u mogelijk het aantal unieke en verschillende waarden tellen onder duplicaten uit een lijst met cellen, zoals onderstaand screenshot. Deze zelfstudie introduceert enkele snelle trucs voor het tellen van de unieke en verschillende waarden in Excel.

Tel unieke waarden in Excel

Tel verschillende waarden (unieke en eerste dubbele exemplaren) in Excel

Download voorbeeldbestand

Tel unieke afzonderlijke waarden

Tel unieke waarden in Excel

In dit gedeelte worden enkele formulevoorbeelden besproken voor het tellen van het aantal unieke waarden, inclusief teksten en getallen in een lijst.

Tel unieke waarden met formules

Stel dat ik een lijst met namen heb die enkele dubbele namen bevat in de namenlijst. Nu moet ik alleen het aantal unieke namen krijgen (die zijn gevuld met gele kleur), zoals onderstaand screenshot laat zien:

Om dit probleem op te lossen, kan de volgende matrixformule u een plezier doen:

Stap 1: invoerformule

Typ of kopieer de onderstaande formule naar een lege cel waar u het resultaat wilt uitvoeren:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 Opmerking:: In de bovenstaande formule, A2: A12 is de gegevenslijst die u als uniek wilt tellen.

Stap 2: druk op Ctrl + Shift + Enter toetsen om het juiste resultaat te krijgen:

Tips:

  1. Als uw lijst met cellen een aantal andere soorten gegevens bevat, zoals getallen, Booleans, foutwaarden, enz., krijgt het bij het toepassen van de bovenstaande formule het aantal unieke waarden, ongeacht het gegevenstype.
  2. Wanneer de gegevenslijst lege cellen bevat, sluit deze formule de lege cellen uit.
  3. Naar tel alleen de unieke tekstwaarden als er andere soorten gegevens zijn, past u de onderstaande matrixformule toe en drukt u vervolgens op Ctrl + Shift + Enter toetsen om het resultaat te retourneren: 
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Naar tel alleen unieke nummers uit een lijst met cellen die elk type gegevens bevat, gebruikt u de volgende matrixformule en drukt u vervolgens op Ctrl + Shift + Enter toetsen om het resultaat te retourneren: 
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Tel unieke waarden met een paar klikken door Kutools voor Excel

Het kan pijnlijk voor u zijn om de formules te onthouden wanneer u ze de volgende keer moet toepassen. Maar als je dat hebt Kutools for Excel, Met Tel unieke waarden optie van Formules Helper, kunt u het resultaat met slechts een paar klikken krijgen. Zie onderstaande demo:

  1. Klik op een cel om het resultaat uit te voeren;
  2. Schakel deze functie in door te klikken Kutools > Formule Helper > Formule Helper > Statistisch > Tel unieke waarden;
  3. Selecteer de lijst met gegevens > OK.
Tips:
  1. Om deze functie toe te passen, zou u dat moeten doen download en installeer het in de eerste plaats.
  2. De Formules Helper functie verzamelt meer dan 40 veelgebruikte formules, zoals Extraheer unieke waarden, Extraheer cellen met unieke waarden (inclusief de eerste duplicaten), Tel het aantal waarden gescheiden door komma's, Som op basis van dezelfde tekst, en meer...

Tel unieke waarden in Excel 365/2021 met formules

Als u Excel 365 of Excel 2021 gebruikt, is er een nieuwe UNIEKE functie die u kan helpen eenvoudigere formules te maken om unieke waarden in een gegevensset te tellen.

Om bijvoorbeeld het aantal unieke namen in het bereik van A2:A12 te tellen, voert u de volgende formule in:

Stap 1: Kopieer of voer de onderstaande formule in

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Opmerking:: In deze formule, A2: A12 is de gegevenslijst waarvan u unieke waarden wilt tellen.

Stap 2: druk op Enter sleutel om het resultaat te krijgen:

Tips:

  1. Als de gegevenslijst andere soorten gegevens bevat, zoals tekst, getallen, booleans, foutwaarden, enz., krijgt deze formule het aantal unieke waarden, ongeacht het gegevenstype.
  2. De bovenstaande formule telt unieke waarden, inclusief lege cellen. Als u de lege cellen wilt uitsluiten, past u de onderstaande formule toe en hoeft u alleen maar op te drukken Enter key: 
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Tel verschillende waarden (unieke en eerste dubbele exemplaren) in Excel

Om de verschillende waarden (unieke waarden en eerste dubbele exemplaren) in een lijst met cellen te tellen, zal ik hier andere formules introduceren om deze taak te volbrengen.

Tel verschillende waarden met formules

In Excel kunt u een van de onderstaande formules toepassen om het aantal verschillende waarden te retourneren.

Stap 1: Voer een van de onderstaande formules in

Formule 1: Druk na het invoeren van de formule op Enter sleutel.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formule 2: Druk na het invoeren van de formule op Ctrl + Shift + Enter sleutels.

=SUM(1/COUNTIF(A2:A12,A2:A12))
Opmerking:: In deze formules, A2: A12 is de gegevenslijst waarvan u verschillende waarden wilt tellen.

Resultaat:

Tips:

  1. Als de gegevenslijst andere soorten gegevens bevat, zoals getallen, booleans, foutwaarden, enz., krijgt deze formule de afzonderlijke waarden, ongeacht het gegevenstype.
  2. Wanneer u de bovenstaande formule gebruikt, krijgt u de foutwaarde #DIV/0 als de gegevenslijst lege cellen bevat. Lege cellen repareren en negeren, moet u een van de onderstaande formules toepassen:
    Formule 1: Druk na het invoeren van de formule op Enter sleutel. 
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formule 2: Druk na het invoeren van de formule op Ctrl + Shift + Enter sleutels. 
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

  3. Naar krijg alleen het aantal verschillende tekstwaarden pas binnen een lijst met gegevens de onderstaande matrixformule toe en druk op Ctrl + Shift + Enter toetsen om het resultaat te krijgen: 
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Naar tellen alleen afzonderlijke numerieke waarden, gebruik dan de volgende matrixformule en druk op Ctrl + Shift + Enter toetsen om het resultaat te krijgen: 
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Tel verschillende waarden met een paar klikken door Kutools voor Excel

Als u de formules in uw werkmap vaak moet toepassen, kan het pijnlijk voor u zijn om de formules te onthouden wanneer u ze de volgende keer moet toepassen. Maar als je dat hebt Kutools for Excel, Met Tel cellen met unieke waarden (inclusief het eerste duplicaat) optie van Formules Helper, kunt u het resultaat krijgen met slechts enkele klikken. Zie onderstaande demo:

  1. Klik op een cel om het resultaat uit te voeren;
  2. Schakel deze functie in door te klikken Kutools > Formule Helper > Statistisch > Tel unieke cellen met unieke waarden (inclusief het eerste duplicaat);
  3. Selecteer de lijst met gegevens > OK.
Tips:
  1. Om deze functie toe te passen, zou u dat moeten doen download en installeer het in de eerste plaats.
  2. De Formules Helper functie verzamelt meer dan 40 veelgebruikte formules, zoals Extraheer unieke waarden, Extraheer cellen met unieke waarden (inclusief de eerste duplicaten), Tel het aantal waarden gescheiden door komma's, Som op basis van dezelfde tekst, en meer...

Tel verschillende waarden in Excel 365/2021 met formules

In Excel 365 of Excel 2021 kunt u de nieuwe UNIQUE-functie gebruiken met de normale COUNTA-functie om een ​​eenvoudige formule te maken.

Kopieer of voer de onderstaande formule in een lege cel in en druk op Enter sleutel om het resultaat te krijgen:

=COUNTA(UNIQUE(A2:A12))
Opmerking:: In deze formule, A2: A12 is de gegevenslijst waarvan u afzonderlijke waarden wilt tellen.

Tips:

  1. Als de gegevenslijst andere typen gegevens bevat, zoals tekst, getallen, Booleans, foutwaarden, enz., telt deze formule het aantal afzonderlijke waarden, ongeacht het gegevenstype.
  2. De bovenstaande formule telt verschillende waarden, inclusief lege cellen. Als u de lege cellen wilt uitsluiten, past u de onderstaande formule toe en drukt u op Enter sleutel om het resultaat te krijgen: 
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

Gerelateerde artikelen:

  • Tel unieke waarden in de draaitabel
  • Wanneer we een draaitabel maken op basis van een gegevensbereik dat enkele dubbele waarden bevat, worden standaard alle records ook geteld, maar soms willen we alleen de unieke waarden tellen op basis van één kolom om het juiste te krijgen screenshot resultaat. In dit artikel zal ik het hebben over het tellen van de unieke waarden in de draaitabel.
  • Tel unieke waarden in een gefilterde kolom
  • Als u een lijst met namen hebt die is gevuld met enkele duplicaten in een gefilterde kolom, en nu wilt u het aantal unieke namen alleen tellen uit deze gefilterde lijst. Heeft u goede oplossingen om deze klus snel in Excel af te handelen?
  • Tel unieke waarden met meerdere criteria
  • Hier is een reeks gegevens met verschillende namen, projecten en locaties, en wat u moet doen, is de namen vinden die overeenkomen met de criteria die ik heb, en vervolgens elke overeenkomende naam één keer tellen, zoals hieronder wordt getoond. Heb je trucjes om deze klus op te lossen? In dit artikel zal ik de trucs introduceren.
  • Unieke waarden samenvoegen
  • Als ik een lange lijst met waarden heb die gevuld is met enkele dubbele gegevens, wil ik nu alleen de unieke waarden vinden en ze vervolgens samenvoegen tot een enkele cel. Hoe kan ik dit probleem snel en gemakkelijk in Excel oplossen?
Heb je vragen? Stel ze hier. (0)
Nog geen beoordelingen. Beoordeel als eerste!
Er zijn nog geen reacties geplaatst

Volg ons

Copyright © 2009 - www.extendoffice.com. | Alle rechten voorbehouden. Aangedreven door ExtendOffice. | Sitemap
Microsoft en het Office-logo zijn handelsmerken of gedeponeerde handelsmerken van Microsoft Corporation in de Verenigde Staten en / of andere landen.
Beschermd door Sectigo SSL