Skip to main content

Ontdek vandaag nog de nieuwe, gratis versie van Kutools voor Outlook!

Hoe maak je een dynamische top 10 of n-lijst in Excel?

Author: Xiaoyang Last Modified: 2025-05-29

Een top lijst wordt gebruikt om bedrijven of individuen te rangschikken op basis van waarden. Stel dat je een lijst hebt met de cijfers van studenten in een klas, en nu wil je een dynamische top 10-lijst van de studenten maken zoals in onderstaande schermafbeelding te zien is. In dit artikel introduceer ik enkele formules om een top 10- of n-lijst te maken in een Excel werkblad.

Maak een dynamische top 10-lijst in Excel

In Excel 2019 en eerdere versies, om de top 10-lijst of top 10-lijst met criteria te extraheren, moet je de volgende formules toepassen:

Formules om een dynamische top 10-lijst te maken

1. Eerst moet je de top 10 waarden uit het gegevensbereik halen. Gebruik hiervoor de volgende formule in een lege cel - G2, en sleep de vulgreep naar beneden om de top 10 waarden te krijgen, zie screenshot:

=GROOT($B$2:$B$20,RIJEN(B$2:B2))
Opmerking: In deze formule is B2:B20 het gegevensbereik waaruit je de top 10 waarden wilt verkrijgen, en B2 is de eerste cel van het gegevensbereik.

apply a formula to extract the top 10 values

2. Pas vervolgens de volgende formule toe in cel - F2, en druk tegelijkertijd op Ctrl + Shift + Enter om het eerste resultaat te krijgen, zie screenshot:

=INDEX($A$2:$A$20,KLEINSTE(ALS($B$2:$B$20=G2,RIJ($B$2:$B$20)-RIJ($B$1)),AANTAL.ALS($G$2:G2,G2)))
Opmerking: In de bovenstaande formule is A2:A20 het gegevensbereik waaruit je de namen van de top 10 waarden wilt halen, B2:B20 is het gegevensbereik dat alle waarden bevat, G2 is de cel van de grootste waarde die uit kolom B is gehaald en B1 is de kopcel van de waarde lijst.

use a formula to get relative item

3. Nadat je het eerste resultaat hebt gekregen, selecteer je de formulecel en sleep je de vulgreep naar beneden om andere namen in één keer te krijgen, zie screenshot:

drag and fill the formula to other cells

a screenshot of kutools for excel ai

Ontdek de Magie van Excel met Kutools AI

  • Slimme Uitvoering: Voer celbewerkingen uit, analyseer gegevens en maak diagrammen – allemaal aangestuurd door eenvoudige commando's.
  • Aangepaste Formules: Genereer op maat gemaakte formules om uw workflows te versnellen.
  • VBA-codering: Schrijf en implementeer VBA-code moeiteloos.
  • Formule-uitleg: Begrijp complexe formules gemakkelijk.
  • Tekstvertaling: Overbrug taalbarrières binnen uw spreadsheets.
Verhoog uw Excel-mogelijkheden met AI-aangedreven tools. Download Nu en ervaar een ongekende efficiëntie!
Formules om een dynamische top 10-lijst met criteria te maken

Soms moet je mogelijk de top 10-lijst op basis van criteria krijgen. Bijvoorbeeld, om de top 10 namen en scores van Klas1 te krijgen zoals in onderstaande schermafbeelding te zien is.

create a dynamic top 10 list with criteria

1. Om de top 10-lijst te krijgen, moet je ook de top 10 scores met deze formule extraheren:

=GROOT(ALS($B$2:$B$25=$F$2,$C$2:$C$25),RIJ(I2)-RIJ(I$1))

2. Druk vervolgens tegelijkertijd op Ctrl + Shift + Enter om het eerste resultaat te krijgen, en sleep dan deze formule naar beneden om andere waarden weer te geven, zie screenshot:

apply a formula to extract the top 10 values based on criteria

3. Kopieer en plak vervolgens de volgende formule in cel - I2, en druk tegelijkertijd op Ctrl + Shift + Enter om het eerste resultaat te extraheren, en sleep dan deze formule om deze in andere cellen in te vullen, en de top 10 namen worden weergegeven.

=INDEX($A$2:$A$25,KLEINSTE(ALS(($C$2:$C$25=J2)*($B$2:$B$25=$F$2),RIJ($C$2:$C$25)-RIJ($C$1)),AANTAL.ALS(J2:$J$2,J2)))

Maak een dynamische top 10-lijst in Office 365

De bovenstaande formules kunnen voor ons moeilijk te begrijpen zijn. Als je Office 365 gebruikt, kun je met de functies INDEX, SORTEREN en REEKSEN eenvoudige formules maken om deze taak te voltooien.

Formule om een dynamische top 10-lijst te maken

Om de top 10-lijst van gegevens te krijgen, gebruik dan de volgende formule:

=INDEX(SORTEREN(A2:B20,2,-1),REEKS(10),{1,2})

Druk vervolgens op de Enter-toets, en alle gegevens van de top 10-lijst worden tegelijkertijd weergegeven, zie screenshot:

use a formula to create a dynamic top 10 list in Office 365

Tips:

SORTEREN-functie:

=SORTEREN(matrix, [sorteer_index], [sorteervolgorde], [op_kolom])

  • matrix: Het bereik van cellen dat je wilt sorteren;
  • [sorteer_index]: Het kolom- of rijnummer om de matrix op te sorteren. Bijvoorbeeld, om te sorteren op de tweede kolom van het gegevensbereik, zou de sorteervolgorde-index 2 zijn;
  • [sorteervolgorde]: Het getal 1 (of weggelaten) geeft aan dat er in oplopende volgorde gesorteerd moet worden; het getal -1, sorteert in aflopende volgorde;
  • [op_kolom]: De richting van het sorteren. WAAR, sorteert op kolommen, ONWAAR of weggelaten, sorteert op rijen.

In de formule gebruiken we de SORTEREN-functie als volgt:

SORTEREN(A2:B20,2,-1): Betekent dat het celbereik A2:A20 op de tweede kolom in aflopende volgorde wordt gesorteerd.

REEKS-functie:

=REEKS(rijen, [kolommen], [start], [stap])

  • rijen: Het aantal rijen dat moet worden geretourneerd,
  • [kolommen]: Het aantal kolommen dat moet worden geretourneerd. Indien weggelaten, wordt er een enkele kolom geretourneerd.
  • [start]: Het eerste nummer in de reeks. Indien weggelaten, begint het bij 1.
  • [stap]: De stapgrootte tussen elk nummer. Indien weggelaten, zal elke stap 1 zijn.

In deze formule gebruiken we REEKS(10) om een lijst van 1 tot 10 te maken.

Tot slot, plaats beide SORTEREN- en REEKS-functies in de INDEX-functie: =INDEX(SORTEREN(A2:B20,2,-1),REEKS(10),{1,2}), dit retourneert de eerste 10 records uit het gegevensbereik en retourneert kolommen 1 en 2.

Formule om een dynamische top 10-lijst met criteria te maken

Om de top 10-lijst met criteria weer te geven, moet je de FILTER-functie in de SORTEREN-functie nesten zoals hier:

=INDEX(SORTEREN(FILTER(A2:C25,B2:B25=F2),3,-1),REEKS(10),{1,3})

Druk gewoon op de Enter-toets, en alle gegevens van de top 10-lijst op basis van de gegeven criteria worden tegelijkertijd weergegeven, zie screenshot:

another formula to create a dynamic top 10 list with criteria in office 365

Tips:

FILTER-functie:

=FILTER(matrix, inclusief, [indien_leeg])

  • matrix: Het bereik van cellen dat gefilterd moet worden.
  • inclusief: De voorwaarde die je gebruikt om de matrix te filteren om een array van WAAR of ONWAAR resultaten te krijgen, zodat de WAAR-waarden behouden blijven in het filter.
  • [indien_leeg]: De waarde die wordt weergegeven als er geen overeenkomende resultaten worden geretourneerd.

In deze formule: =FILTER(A2:C25,B2:B25=F2) wordt gebruikt om te filteren in het bereik A2:C25, waarbij de waarden van B2:B25 gelijk zijn aan de specifieke cel F2.

Beste Office-productiviteitstools

🤖 Kutools AI Assistent: Breng een revolutie teweeg in data-analyse Methode: Intelligente uitvoering |Code genereren |Aangepaste formules maken |Gegevens analyseren en grafieken genereren |Kutools-functies gebruiken…
Populaire functies: Dubbele waarden markeren, markeren of identificeren | Verwijder lege rijen | Kolommen of cellen samenvoegen zonder gegevensverlies | Afronden ...
Super ZOEKEN: VLookup met meerdere criteria | VLookup met meerdere waarden | Meervoudig-blad opzoeken | Fuzzy Match ...
Geavanceerde keuzelijst: Snel keuzelijst maken | Afhankelijke keuzelijst | Meervoudige selectie keuzelijst ...
Kolombeheer: Specifiek aantal kolommen toevoegen | Kolommen verplaatsen | Zichtbaarheid van verborgen kolommen wisselen | Bereik & kolommen vergelijken ...
Uitgelichte functies: Rasterfocus | Ontwerpweergave | Verbeterde formulebalk | Werkboek- & Werkbladbeheer | AutoTekstbibliotheek | Datumkiezer | Gegevens samenvoegen | Cellen coderen/decoderen | E-mail verzenden per lijst | Superfilter | Speciaal filter (filter cellen met vetgedrukt/cursief/doorhalen...) ...
Top15 toolsets:12 Teksttools (Tekst toevoegen, Specifieke tekens verwijderen, ...) |50+ Grafiek type (Gantt-diagram, ...) |40+ Praktische formules (Leeftijd berekenen op basis van geboortedatum, ...) |19 Invoegtools (QR-code invoegen, Afbeelding invoegen vanaf pad, ...) | 12 Conversietools (Omzetten naar woorden, Valutaconversie, ...) | 7 Samenvoeg- & Opsplitstools (Geavanceerd samenvoegen van rijen, Cellen splitsen, ...) | ... en meer

Versterk je Excel-vaardigheden met Kutools voor Excel en ervaar ongeëvenaarde efficiëntie. Kutools voor Excel biedt meer dan300 geavanceerde functies om je productiviteit te verhogen en tijd te besparen. Klik hier om de functie te krijgen die je het meest nodig hebt...

Office Tab brengt een tabbladinterface naar Office en maakt je werk veel eenvoudiger

  • Schakel bewerken en lezen met tabbladen in Word, Excel, PowerPoint in
  • Open en maak meerdere documenten in nieuwe tabbladen van hetzelfde venster, in plaats van in nieuwe vensters.
  • Verhoog je productiviteit met50% en bespaar dagelijks honderden muisklikken!