Excel-handleiding: tekst-, getal- en datumcellen splitsen (opdelen in meerdere kolommen)
Bij het werken met Excel kan het nodig zijn om tekst uit één cel op te splitsen in meerdere cellen voor verschillende doeleinden. Deze handleiding bestaat uit drie delen: tekstcellen splitsen, getalcellen splitsen en datumcellen splitsen. Elk deel bevat verschillende voorbeelden om je te helpen de juiste aanpak te kiezen wanneer je voor een vergelijkbaar probleem komt te staan.
Inhoudsopgave: [ Verbergen ]
1 Tekstcellen splitsen
In dit deel worden de situaties verzameld waarin je een tekstcel in meerdere kolommen wilt splitsen, met de bijbehorende methoden.
Voorbeeld #1 Cellen splitsen op komma, spatie of ander(e) scheidingsteken(s)
Om een tekstcel in meerdere kolommen te splitsen op een specifiek scheidingsteken zoals een komma, spatie, streepje, enzovoort, kun je een van de onderstaande methoden gebruiken.
Cellen splitsen op scheidingsteken met de functie Tekst naar kolommen
De functie Tekst naar kolommen, een ingebouwde functie in Excel, wordt vaak gebruikt om cellen te splitsen. Zoals te zien in de onderstaande schermafbeelding, kun je om cellen in de kolom Tekststrings op komma te splitsen, de functie Tekst naar kolommen als volgt toepassen.
1. Selecteer het kolombereik dat je wilt splitsen op komma, klik op Gegevens > Tekst naar kolommen.
2. In het dialoogvenster Tekst naar kolommen wizard – Stap1 van3, laat je de optie Gescheiden geselecteerd en klik je op de knop Volgende.
3. In het dialoogvenster Tekst naar kolommen wizard – Stap2 van3, geef je een scheidingsteken op naar wens (in dit geval vink ik alleen het vakje Komma aan) en klik je op de knop Volgende.
4. In het laatste stap dialoogvenster, klik op de 
knop om een cel te selecteren waar de gescheiden teksten moeten worden geplaatst, en klik vervolgens op de Voltooien knop.
Daarna worden de teksten in het geselecteerde bereik gesplitst op komma en in verschillende kolommen geplaatst zoals hieronder weergegeven.
Cellen splitsen op scheidingsteken met formule
Je kunt onderstaande formule toepassen om teksten in cellen te splitsen op een opgegeven scheidingsteken in Excel.
Algemene formule
=TRIM(MID(SUBSTITUTE(A1,delim,REPT(" ",LEN(A1))),(N-1)*LEN(A1)+1,LEN(A1)))
Argumenten
Ga vervolgens verder met het toepassen van deze formule.
1. Zoals te zien in de onderstaande schermafbeelding, moet je eerst een hulprij maken met de getallen1,2,3... in verschillende cellen.
Opmerking: Hier staan1,2,3... voor het eerste, tweede en derde deel van de tekststring.
2. Selecteer een cel onder de cel met het getal1, kopieer of voer onderstaande formule in en druk op Enter om het eerste deel van de tekststring te krijgen. Selecteer de resultaatcel, sleep de vulgreep naar rechts en naar beneden om de andere delen te krijgen. Zie schermafbeelding:
=TRIM(MID(SUBSTITUTE($B5,",",REPT(" ",LEN($B5))),(D$4-1)*LEN($B5)+1,LEN($B5)))
Opmerking: In de formule is “,” het scheidingsteken dat wordt gebruikt om de tekststring in B5 te splitsen. Je kunt dit aanpassen naar wens.
Cellen splitsen op scheidingsteken met een handig hulpmiddel
Hier raden we de functie Cellen splitsen van Kutools voor Excel aan om eenvoudig cellen in aparte kolommen of rijen te splitsen op een bepaald scheidingsteken in Excel.
1. Na installatie van Kutools voor Excel selecteer je het bereik waarin je de tekststrings wilt splitsen en klik je op Kutools > Samenvoegen & Splitsen > Cellen splitsen.
2. In het dialoogvenster Cellen splitsen moet je het volgende instellen.
3. In het volgende dialoogvenster Cellen splitsen selecteer je een cel om de delen te plaatsen en klik je op OK.
Daarna worden de delen gesplitst in verschillende kolommen of rijen op basis van je instellingen in stap2 hierboven.
Splitsen naar kolommen:
Splitsen naar rijen:
Voorbeeld #2 Cellen splitsen op bepaalde lengte
Om tekststrings op een bepaalde lengte te splitsen, kun je de volgende methoden gebruiken.
Cellen splitsen op bepaalde lengte met de functie Tekst naar kolommen
De functie Tekst naar kolommen biedt een optie Specificeer breedte om tekststrings in geselecteerde cellen op een bepaalde lengte te splitsen in Excel.
Zoals te zien in de onderstaande schermafbeelding, kun je om de teksten in bereik B5:B9 elke3 tekens in kolommen te splitsen, als volgt te werk gaan.
1. Selecteer de cellen waarin je de tekststrings wilt splitsen.
2. Klik op Gegevens > Tekst naar kolommen.
3. In het dialoogvenster Tekst naar kolommen wizard – stap1 van3, selecteer je de optie Specificeer breedte en klik je op Volgende.
4. Vervolgens verschijnt het dialoogvenster Stap2 van3. In het gedeelte Voorbeeld klik je op de gewenste positie op de as om een breeklijn te maken (een lijn met pijl). Na het maken van alle breeklijnen klik je op de knop Volgende om verder te gaan.
In dit geval maak ik breeklijnen voor elke3 tekens in de tekststring.
5. In de laatste stap van de wizard selecteer je een cel om de gescheiden teksten te plaatsen en klik je op de knop Voltooien.
Nu zijn de tekststrings in de geselecteerde cellen gesplitst per3 tekens zoals te zien in de onderstaande schermafbeelding.
Cellen splitsen op bepaalde lengte met een handig hulpmiddel
Om cellen op een bepaalde lengte te splitsen in Excel kun je de functie Cellen splitsen van Kutools voor Excel gebruiken om dit eenvoudig te doen.
1. Selecteer de tekststringcellen die je wilt splitsen op bepaalde lengte, klik op Kutools > Samenvoegen & Splitsen > Cellen splitsen.
2. In het dialoogvenster Cellen splitsen moet je het volgende instellen.
3. In het volgende dialoogvenster Cellen splitsen selecteer je een cel om de gesplitste teksten te plaatsen en klik je op OK.
Daarna worden de tekststrings in de geselecteerde cellen gesplitst op bepaalde lengte en in verschillende kolommen geplaatst.
Voorbeeld #3 Cellen splitsen op een bepaald woord
Zoals te zien in de onderstaande schermafbeelding kun je om tekststrings in bereik B5:B9 te splitsen op het volledige woord “sales”, de in deze sectie gegeven formules gebruiken.
Het deel vóór een bepaald woord in een cel ophalen
Een formule gebaseerd op de functies LINKS en VIND.ALLES kan helpen om het deel vóór een bepaald woord in een tekststring te krijgen.
Algemene formule
=LEFT(A1,FIND("certain_word", A1)-1)
Argumenten
1. Selecteer een lege cel, kopieer of voer onderstaande formule in en druk op Enter om het deel vóór het bepaalde woord te krijgen. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de formule toe te passen op andere cellen.
=LEFT(B5,FIND("sales",B5)-1)
Het deel na een woord in een cel ophalen
Nadat je het deel vóór het woord hebt opgehaald, moet je onderstaande formule toepassen om het deel erna te krijgen.
Algemene formule
=TRIM(MID(A1,SEARCH("certain_word",A1)+LEN("certain_word"),255))
Argumenten
1. Selecteer een lege cel naast de eerste resultaatcel (D5).
2. Kopieer of voer onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de andere resultaten te krijgen.
=TRIM(MID(B5,SEARCH("sales",B5)+LEN("sales"),255))
Nu heb je tekststrings gesplitst in verschillende kolommen op een volledig woord.
Voorbeeld #4 Cellen splitsen op regeleinde
In deze sectie worden verschillende methoden getoond om tekstcellen op regeleinde te splitsen in Excel.
Cellen splitsen op regeleinde met de functie Tekst naar kolommen
De functie Tekst naar kolommen kan worden gebruikt om cellen op regeleinde te splitsen in Excel. Je kunt als volgt te werk gaan.
1. Selecteer het bereik van cellen waarin je de teksten op regeleinde wilt splitsen.
2. Klik op Gegevens > Tekst naar kolommen.
3. In het dialoogvenster Tekst naar kolommen wizard – Stap1 van3, kies je de optie Gescheiden en klik je op Volgende;
4. In het dialoogvenster Stap2 van3, deselecteer je alle bestaande scheidingstekens, vink je het vakje Overig aan en druk je op de sneltoets Ctrl + J. Je ziet nu een klein puntje in het tekstvak, en in het vak Voorbeeld worden de teksten gesplitst op regeleinden. Klik op de knop Volgende.
5. In de laatste stap van de wizard selecteer je een bestemmingscel om de gescheiden teksten te plaatsen en klik je op de knop Voltooien.
Daarna worden de teksten in de geselecteerde cellen gesplitst in verschillende kolommen op regeleinden.
Cellen splitsen op regeleinde met formule
De volgende formules kunnen ook helpen om cellen op regeleinde te splitsen in Excel.
Met hetzelfde voorbeeld als hierboven krijg je na het splitsen drie delen in verschillende kolommen.
Het deel vóór het eerste regeleinde ophalen
We kunnen eerst een formule gebaseerd op de functies LINKS en ZOEKEN gebruiken om het deel vóór het eerste regeleinde in de cel te splitsen.
Algemene formule
=LEFT(cell, SEARCH(CHAR(10),cell,1)-1)
Argumenten
1. Selecteer een lege cel (D5 in dit geval), kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de delen vóór het eerste regeleinde van andere cellen te krijgen.
=LEFT(B5, SEARCH(CHAR(10),B5,1)-1)
Het deel tussen het eerste en tweede regeleinde ophalen
Om het deel tussen het eerste en tweede regeleinde in een cel te krijgen, kun je de volgende formule gebruiken.
Algemene formule
=MID(cell,SEARCH(CHAR(10),cell)+1,SEARCH(CHAR(10),cell,SEARCH(CHAR(10),cell)+1)-SEARCH(CHAR(10),cell)-1)
Argumenten
1. Selecteer een cel (E5) naast D5, kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de delen tussen het eerste en tweede regeleinde van andere cellen te krijgen.
=MID(B5, SEARCH(CHAR(10),B5) +1, SEARCH(CHAR(10),B5,SEARCH(CHAR(10),B5)+1) - SEARCH(CHAR(10),B5) -1)
Het deel na het tweede regeleinde ophalen
De eerste stap is het deel na het tweede regeleinde ophalen met onderstaande formule.
Algemene formule
=RIGHT(cell,LEN(cell) - SEARCH(CHAR(10),cell, SEARCH(CHAR(10), cell) +1))
Argumenten
1. Selecteer een cel (F5 in dit geval), kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de delen na het tweede regeleinde van andere cellen te krijgen.
=RIGHT(B5,LEN(B5) - SEARCH(CHAR(10), B5, SEARCH(CHAR(10), B5) +1))
Cellen splitsen op regeleinde met VBA
In deze sectie vind je een VBA-code om eenvoudig teksten in geselecteerde cellen op regeleinde te splitsen in Excel.
1. Druk op de toetsen Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.
2. In het venster Microsoft Visual Basic for Applications klik je op Invoegen > Module. Kopieer vervolgens onderstaande VBA in het codevenster.
VBA-code: cellen splitsen op regeleinde in Excel
Sub ExtendOffice_SplitRangeTex()
'Updated by Extendoffice 20211116
Dim xStr() As String
Dim xRg As Range
Dim xCell As Range
Dim xI As Integer
Set xRg = Application.InputBox("Please select the range of cells where you want to split by line break:", "Kutools for Excel", "", , , , , 8)
If xRg Is Nothing Then Exit Sub
For xI = 1 To xRg.Count
Set xCell = xRg.Item(xI)
xStr = VBA.Split(xCell.Value, vbLf)
xCell.Resize(1, UBound(xStr) + 1).Offset(0, 1) = xStr
Next
End Sub
3. Druk op de F5-toets om de code uit te voeren. Vervolgens verschijnt er een Kutools voor Excel-dialoogvenster waarin je het bereik van cellen selecteert dat je wilt splitsen op regeleinde, en klik je ten slotte op de knop OK.
Daarna worden de teksten in geselecteerde cellen direct gesplitst in verschillende kolommen op regeleinden.
Cellen splitsen op regeleinde met een handig hulpmiddel
Hier introduceren we een handig hulpmiddel – de functie Cellen splitsen van Kutools voor Excel. Met deze tool kun je teksten in geselecteerde cellen in bulk splitsen op regeleinde met slechts enkele klikken.
1. Selecteer het bereik van cellen waarin je de teksten op regeleinde wilt splitsen.
2. Klik op Kutools > Samenvoegen & Splitsen > Cellen splitsen om de functie in te schakelen.
3. In het dialoogvenster Cellen splitsen moet je de volgende instellingen maken.
4. In het volgende dialoogvenster Cellen splitsen selecteer je een lege cel om de gescheiden teksten te plaatsen en klik je op OK.
Daarna worden de teksten in de geselecteerde cellen gesplitst in verschillende kolommen op regeleinden zoals hieronder weergegeven.
Kutools voor Excel - Boost Excel met meer dan 300 essentiële tools. Geniet van permanent gratis AI-functies! Nu verkrijgen
Voorbeeld #5 Cellen splitsen op alleen het eerste of laatste scheidingsteken
Soms wil je een cel in twee delen splitsen op alleen het eerste of laatste scheidingsteken. Je kunt onderstaande formules proberen.
Cellen splitsen op het eerste scheidingsteken met formules
Zoals te zien in de onderstaande schermafbeelding kun je om elke cel in bereik B5:B9 in twee delen te splitsen op de eerste spatie, twee formules toepassen.
Het deel vóór de eerste spatie splitsen
Om het deel vóór de eerste spatie te splitsen kun je een formule gebruiken op basis van de functie LINKS en VIND.ALLES.
Algemene formule
=LEFT(cell,FIND("delimiter",cell)-1)
Argumenten
1. Selecteer een cel (D5 in dit geval) om het deel te plaatsen, kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om het deel van andere cellen te krijgen.
=LEFT(B5,FIND(" ",B5)-1)
Het deel na de eerste spatie splitsen
Pas vervolgens onderstaande formule toe om het deel na de eerste spatie in een cel te krijgen.
Algemene formule
=RIGHT(cell,LEN(cell)-FIND("delimiter",cell))
Argumenten
1. Kopieer of voer onderstaande formule in cel E5 in en druk op Enter om het resultaat te krijgen. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om het deel na de laatste spatie van andere cellen te krijgen.
=RIGHT(B5,LEN(B5)-FIND(" ",B5))
Opmerking: In de formules kun je de celverwijzing naar de tekststring en het scheidingsteken aanpassen naar wens.
Cellen splitsen op het laatste scheidingsteken met formules
Om teksten in het bereik van cellen (B5:B9) in twee delen te splitsen op de laatste spatie zoals te zien in de schermafbeelding, kun je de twee formules in deze sectie gebruiken.
De tekst links van het laatste scheidingsteken ophalen
Om de tekst links van het laatste scheidingsteken in een cel te krijgen, kun je onderstaande formule toepassen.
Algemene formule
=LEFT(B5,SEARCH("^",SUBSTITUTE(cell,"delimiter","^",LEN(cell)-LEN(SUBSTITUTE(cell,"delimiter",""))))-1)
Argumenten
1. Selecteer een cel om het linker deel te plaatsen, kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de formule toe te passen op andere cellen.
=LEFT(B5,SEARCH("^",SUBSTITUTE(B5," ","^",LEN(B5)-LEN(SUBSTITUTE(B5," ",""))))-1)
De tekst rechts van het laatste scheidingsteken ophalen
Nu moeten we de tekst rechts van de laatste spatie in dit geval ophalen.
Algemene formule
=TRIM(RIGHT(SUBSTITUTE(cell,"delimiter",REPT("delimiter",LEN(cell))),LEN(cell)))
Argumenten
1. Selecteer een cel om het rechter deel te plaatsen, kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de formule toe te passen op andere cellen.
=TRIM(RIGHT(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))),LEN(B5)))
Opmerking: In de formules kun je de celverwijzing naar de tekststring en het scheidingsteken aanpassen naar wens.
Voorbeeld #6 Cellen splitsen op hoofdletter
In deze sectie wordt een gebruikersgedefinieerde functie geïntroduceerd om woorden in cellen te splitsen op hoofdletter.
1. Druk op de toetsen Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.
2. In het venster Microsoft Visual Basic for Applications klik je op Invoegen > Module, en kopieer je onderstaande VBA-code in het codevenster.
VBA-code: cellen splitsen op hoofdletter in Excel
Function GetName(s As String, Num As Long) As String
'Updated by Extendoffice 20211116
With CreateObject("VBSCript.RegExp")
.Global = True
.Pattern = "[A-Z][a-z]+|[A-Z]"
GetName = .Execute(s).Item(Num - 1)
End With
End Function3. Druk op de toetsen Alt + Q om het venster Microsoft Visual Basic for Applications te sluiten.
4. Selecteer een cel (D5 in dit geval) om het woord links van de eerste hoofdletter te plaatsen, voer onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar rechts en vervolgens naar beneden om de andere woorden te krijgen.
=IFERROR(GetName($B5,COLUMNS($D:D)),"")
Opmerking: In de code is $B5 de cel die je wilt splitsen, $D:D is de kolom van de resultaatcel. Pas deze aan op basis van je eigen gegevens.
Voorbeeld #7 Namen splitsen in cellen
Stel dat je een werkblad hebt met een kolom vol met volledige namen en je wilt de volledige naam splitsen in aparte kolommen, bijvoorbeeld de voornaam en achternaam uit de volledige naam halen, of de voornaam, tussenvoegsel of achternaam splitsen. In deze sectie vind je gedetailleerde stappen om deze problemen op te lossen.
Volledige naam splitsen in voornaam en achternaam
Zoals te zien in de onderstaande schermafbeelding zijn de voornaam, tussenvoegsel en achternaam gescheiden door een enkele spatie. Om alleen de voornaam en achternaam uit een volledige naam te splitsen en in verschillende kolommen te plaatsen, kun je een van de volgende methoden gebruiken.
1) Volledige naam splitsen in voornaam en achternaam met formules
Je moet twee formules afzonderlijk toepassen om een volledige naam te splitsen in voornaam en achternaam.
De voornaam uit een volledige naam splitsen
Je kunt een formule gebaseerd op de functies LINKS en ZOEKEN gebruiken om de voornaam uit een volledige naam te splitsen.
Algemene formule
=LEFT(cell, SEARCH(" ", cell) -1)
1. Selecteer een cel om de voornaam te plaatsen.
2. Kopieer of voer onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de voornamen uit andere volledige namen te splitsen.
=LEFT(B5, SEARCH(" ", B5) -1)
Nu heb je alle voornamen uit de volledige namen in het opgegeven bereik gesplitst. Ga verder met onderstaande formule om de achternamen te splitsen.
De achternaam uit een volledige naam splitsen
Algemene formule
=RIGHT(cell, LEN(cell) - SEARCH("^", SUBSTITUTE(cell," ", "^", LEN(cell) - LEN(SUBSTITUTE(cell, " ", "")))))
1. Selecteer een cel naast de voornaamcel.
2. Kopieer of voer onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de achternamen uit andere volledige namen te krijgen.
=RIGHT(B5, LEN(B5) - SEARCH("^", SUBSTITUTE(B5," ", "^", LEN(B5) - LEN(SUBSTITUTE(B5, " ", "")))))
Opmerking: In de formules is B5 de volledige naamcel die je wilt splitsen. Je kunt dit aanpassen naar wens.
2) Volledige naam splitsen in voornaam en achternaam met een handig hulpmiddel
Formules zijn lastig te onthouden voor veel Excel-gebruikers. Daarom raden we de functie Naam splitsen van Kutools voor Excel aan. Met deze functie kun je eenvoudig een volledige naam splitsen in voornaam en achternaam met slechts enkele klikken.
1. Selecteer het bereik met volledige namen, klik op Kutools > Samenvoegen & Splitsen > Naam splitsen.
2. In het dialoogvenster Naam splitsen vink je alleen het vakje Voornaam en het vakje Achternaam aan in het gedeelte Splitsingstype, en klik je op OK.
Tips: Het geselecteerde bereik wordt weergegeven in het vak Bereik splitsen, je kunt dit aanpassen naar wens.
3. Vervolgens verschijnt er nog een dialoogvenster Naam splitsen, selecteer een bestemmingscel en klik op OK.
Daarna wordt de volledige naam in de geselecteerde cellen in bulk gesplitst in voornaam en achternaam zoals hieronder weergegeven.
Kutools voor Excel - Boost Excel met meer dan 300 essentiële tools. Geniet van permanent gratis AI-functies! Nu verkrijgen
Volledige naam splitsen in voornaam, tussenvoegsel en achternaam
Zoals te zien in de onderstaande schermafbeelding is er een kolom met volledige namen waarbij voornaam, tussenvoegsel en achternaam gescheiden zijn door een enkele spatie. Om de volledige naam te splitsen in voornaam, tussenvoegsel en achternaam en deze in verschillende kolommen te plaatsen, kun je onderstaande methoden gebruiken.
1) Volledige naam splitsen in voornaam, tussenvoegsel en achternaam met Tekst naar kolommen
De ingebouwde functie Tekst naar kolommen kan je eenvoudig helpen om een volledige naam te splitsen in voornaam, tussenvoegsel en achternaam in Excel.
Je kunt de hierboven beschreven stappen volgen om de functie Tekst naar kolommen toe te passen.
Opmerking: In stap2 van3 van de wizard vink je alleen het vakje Spatie aan.
2) Volledige naam splitsen in voornaam, tussenvoegsel en achternaam met formules
Je kunt ook formules toepassen om een volledige naam te splitsen in voornaam, tussenvoegsel en achternaam in Excel.
Algemene formules om volledige naam te splitsen
De voornaam splitsen
=LEFT(cell,SEARCH(" ", cell)-1)
Het tussenvoegsel splitsen
=MID(cell, SEARCH(" ", cell) +1, SEARCH(" ", cell, SEARCH(" ", cell)+1) - SEARCH(" ", cell)-1)
De achternaam splitsen
=RIGHT(cell,LEN(cell) - SEARCH(" ",cell, SEARCH(" ",cell,1)+1))
Pas vervolgens de formules in verschillende cellen toe om de voornaam, het tussenvoegsel en de achternaam te krijgen.
1. Voer in cel D5 onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de voornamen uit andere volledige namen te krijgen.
=LEFT(B5,SEARCH(" ", B5)-1)
2. Voer onderstaande formule in cel E5 in en druk op Enter om het eerste tussenvoegsel te krijgen. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de andere tussenvoegsels te krijgen.
=MID(B5, SEARCH(" ", B5) +1, SEARCH(" ", B5, SEARCH(" ", B5)+1) - SEARCH(" ", B5)-1)
3. Voer onderstaande formule in cel F5 in om de achternamen te krijgen en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep over de cellen die je nodig hebt.
=RIGHT(B5,LEN(B5) - SEARCH(" ",B5, SEARCH(" ",B5,1)+1))
3) Volledige naam splitsen in voornaam, tussenvoegsel en achternaam met een handig hulpmiddel
Hier volgt een introductie van de functie Naam splitsen van Kutools voor Excel, waarmee je een volledige naam in één keer kunt splitsen in voornaam, tussenvoegsel en achternaam met slechts een paar klikken.
1. Selecteer de volledige naamcellen die je wilt splitsen en klik op Kutools > Samenvoegen & Splitsen > Naam splitsen.
2. In het dialoogvenster Naam splitsen moet je het volgende instellen.
3. In het volgende dialoogvenster Naam splitsen selecteer je een bestemmingscel om de gescheiden teksten te plaatsen en klik je op OK. Zie onderstaande demo.
Kutools voor Excel - Boost Excel met meer dan 300 essentiële tools. Geniet van permanent gratis AI-functies! Nu verkrijgen
Voorbeeld #8 Tekst en getallen splitsen in cellen
Stel dat er een lijst is met tekststrings waarin tekst en getallen zijn gecombineerd, zoals te zien in de onderstaande schermafbeelding. Om de tekst en getallen te scheiden en in verschillende kolommen te plaatsen, bieden we vier methoden.
Tekst en getallen splitsen met formules
Met de volgende formules kun je de tekst en getallen uit één cel splitsen in twee aparte cellen.
Algemene formules
Tekst uit cel halen
=LEFT(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))-1)
Getallen uit cel halen
=RIGHT(cell,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))+1)
Pas deze twee formules toe in verschillende cellen om de tekst en getallen apart te krijgen.
1. Selecteer een lege cel om de tekst van de eerste tekststring in de lijst te plaatsen, kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de tekst van andere tekststrings in de lijst te krijgen.
=LEFT(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))-1)
2. Selecteer een cel (E5) naast de eerste resultaatcel (D5), kopieer of voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de getallen van andere tekststrings in de lijst te krijgen.
=RIGHT(B5,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))+1)
Tekst en getallen splitsen met Flash Fill (2013 en latere versies)
Als je Excel2013 of een latere versie gebruikt, kun je de ingebouwde functie Flash Fill gebruiken om tekst en getallen uit één cel in twee kolommen te splitsen.
Opmerking: Om de functie Flash Fill te laten werken, moeten de resultaatkolommen naast de oorspronkelijke tekststringkolom staan. Bijvoorbeeld: als de oorspronkelijke tekststrings in kolom B staan, moeten de gescheiden tekst en getallen in kolom C en D worden geplaatst. Zie schermafbeelding:
1. Typ handmatig de tekst van de eerste tekststringcel (D5) in cel C5.
2. Blijf de tekst van de tweede tekststringcel (D6) in cel C6 typen.
3. Activeer cel C7, klik op Gegevens > Flash Fill.
Daarna worden de teksten van andere tekststrings automatisch in de cellen ingevuld zoals te zien in de onderstaande schermafbeelding.
4. Herhaal stap1 tot3 om de getallen in kolom D te krijgen.
Opmerkingen:
Tekst en getallen splitsen met een gebruikersgedefinieerde functie
Als de tekststrings in een lijst niet regelmatig zijn, kunnen de bovenstaande twee methoden verkeerde resultaten opleveren zoals te zien in de onderstaande schermafbeelding.
Hier introduceren we een gebruikersgedefinieerde functie om tekst en getallen uit een cel in twee kolommen te splitsen, ongeacht waar de getallen zich in de tekststring bevinden. Zie schermafbeelding:
1. Druk op de toetsen Alt + F11.
2. In het geopende venster Microsoft Visual Basic for Applications klik je op Invoegen > Module, en kopieer je onderstaande VBA in het codevenster.
VBA-code: tekst en getallen uit een cel splitsen in twee kolommen
Public Function SplitText(pWorkRng As Range, pIsNumber As Boolean) As String
'Update by Extendoffice 20211105
Dim xLen As Long
Dim xStr As String
xLen = VBA.Len(pWorkRng.Value)
For i = 1 To xLen
xStr = VBA.Mid(pWorkRng.Value, i, 1)
If ((VBA.IsNumeric(xStr) And pIsNumber) Or (Not (VBA.IsNumeric(xStr)) And Not (pIsNumber))) Then
SplitText = SplitText + xStr
End If
Next
End Function
3. Druk op de toetsen Alt + Q om het venster Microsoft Visual Basic for Applications te sluiten.
4. Selecteer een cel om de tekst van de eerste tekststring te plaatsen, voer onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de tekst van andere tekststrings in dezelfde lijst te krijgen.
=SplitText(B5,FALSE)
5. Selecteer een cel naast de eerste tekstresultaatcel om de getallen te plaatsen, voer onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de getallen van andere tekststrings te krijgen.
=SplitText(B5,TRUE)
Tekst en getallen splitsen met een handig hulpmiddel
Hier raden we de eenvoudigste manier aan om tekst en getallen tegelijk uit een cel in twee kolommen te splitsen. Met de functie Cellen splitsen van Kutools voor Excel kun je dit probleem met slechts enkele klikken oplossen.
1. Selecteer de tekststringcellen waarin je de tekst en getallen in twee kolommen wilt splitsen.
2. Klik op Kutools > Samenvoegen & Splitsen > Cellen splitsen.
3. In het dialoogvenster Cellen splitsen moet je de volgende instellingen doen.
knop klikken om indien nodig een nieuw bereik te selecteren;
4. In het volgende dialoogvenster Cellen splitsen selecteer je een cel om de gescheiden tekst en getallen te plaatsen en klik je op OK.
Daarna zie je dat de tekst en getallen in de geselecteerde cellen direct in twee kolommen zijn gesplitst zoals te zien in de onderstaande schermafbeelding.
Kutools voor Excel - Boost Excel met meer dan 300 essentiële tools. Geniet van permanent gratis AI-functies! Nu verkrijgen
2. Getalcellen splitsen
In dit deel wordt uitgelegd hoe je getalcellen splitst in twee situaties: een getal met meer dan één cijfer splitsen in afzonderlijke cijfers en een getal splitsen op decimaal om het gehele en decimale deel te scheiden.
Voorbeeld #1: Cellen splitsen op cijfers
Als je een getal met meer dan één cijfer in afzonderlijke cijfers in verschillende kolommen wilt splitsen, probeer dan een van de onderstaande methoden.
Een getal in een cel splitsen in afzonderlijke cijfers met formule
De onderstaande formule kan helpen om een getal in afzonderlijke cijfers te splitsen en deze in verschillende kolommen te plaatsen.
Algemene formule
=MID($A1, COLUMNS($A$1:A$1),1)
Argument
1. Selecteer een lege cel om het eerste cijfer te plaatsen, voer onderstaande formule in en druk op Enter.
=MID($B3, COLUMNS($B$3:B$3),1)
2. Selecteer deze resultaatcel en sleep de vulgreep naar rechts om de andere cijfers te krijgen. Houd alle resultaatcellen geselecteerd en sleep vervolgens de vulgreep naar beneden om de afzonderlijke cijfers van andere getallen te krijgen.
Opmerking: In deze formule is B3 de cel met het getal dat je wilt splitsen in afzonderlijke cijfers. Je kunt dit aanpassen naar wens.
Een getal in een cel splitsen in afzonderlijke cijfers met VBA
De onderstaande VBA-code kan ook helpen om een getal in een cel in afzonderlijke cijfers te splitsen in Excel. Je kunt als volgt te werk gaan.
1. Druk op de toetsen Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.
2. In het venster Microsoft Visual Basic for Applications klik je op Invoegen > Module, en kopieer je onderstaande VBA in het codevenster.
VBA-code: getal splitsen in afzonderlijke cijfers in Excel
Sub SplitNumberIntoDigits()
'Updateby Extendoffice 2021118
Dim Rng As Range
Dim InputRng As Range, OutRng As Range
xTitleId = "Kutools for Excel"
Set InputRng = Application.Selection
Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
Set OutRng = Application.InputBox("Out put to (single cell):", xTitleId, Type:=8)
xInt = InputRng.Row
Application.ScreenUpdating = False
For Each Rng In InputRng
xValue = Rng.Value
xRow = (Rng.Row - xInt) + 1
For I = 1 To VBA.Len(xValue)
OutRng.Cells(xRow, I).Value = VBA.Mid(xValue, I, 1)
Next
Next
Application.ScreenUpdating = True
End Sub
3. Druk op de F5-toets om de code uit te voeren. Vervolgens verschijnt er een Kutools voor Excel-dialoogvenster waarin je het bereik van getalcellen selecteert dat je wilt splitsen en klik je op de knop OK.
4. Het tweede Kutools voor Excel-dialoogvenster verschijnt, selecteer een cel om de afzonderlijke cijfers te plaatsen en klik op OK.
Opmerking: Deze code kan ook een woord splitsen in afzonderlijke letters.
Daarna worden de getallen in geselecteerde cellen gesplitst in afzonderlijke cijfers en in verschillende kolommen geplaatst.
Eenvoudig een getal splitsen in afzonderlijke cijfers met een handig hulpmiddel
De functie Cellen splitsen van Kutools voor Excel is een handig hulpmiddel om eenvoudig een getal in afzonderlijke cijfers te splitsen in Excel.
1. Na installatie van Kutools voor Excel selecteer je het bereik met getalcellen dat je wilt splitsen, klik je op Kutools > Samenvoegen & Splitsen > Cellen splitsen.
2. In het dialoogvenster Cellen splitsen doe je het volgende.
knop klikken om het bereik indien nodig te wijzigen;
3. In het geopende dialoogvenster Cellen splitsen selecteer je een lege cel om de cijfers te plaatsen en klik je op OK.
Daarna worden de getallen in geselecteerde cellen direct gesplitst in afzonderlijke cijfers.
Kutools voor Excel - Boost Excel met meer dan 300 essentiële tools. Geniet van permanent gratis AI-functies! Nu verkrijgen
Voorbeeld #2 Getal splitsen op decimaal
In deze sectie worden enkele methoden besproken om een getal in gehele en decimale delen te splitsen in Excel.
Getal splitsen op decimaal met formules
De functie TRUNC kan worden gebruikt om een getal op decimaal te splitsen in Excel. Je kunt als volgt te werk gaan.
Algemene formules
Het gehele deel ophalen
=TRUNC(A1)
Het decimale deel ophalen
=A1-TRUNC(A1)
Argument
Nu kun je deze twee formules toepassen om getallen in een opgegeven bereik van cellen op decimaal te splitsen in Excel.
1. Selecteer een cel om het gehele deel van de eerste getalcel te plaatsen, voer onderstaande formule in en druk op Enter. Selecteer de resultaatcel en sleep de vulgreep naar beneden om de gehele delen van andere getalcellen te krijgen.
=TRUNC(B5)
2. Selecteer een cel naast de eerste resultaatcel om het decimale deel te plaatsen, voer onderstaande formule in en druk op Enter. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de decimalen van andere getalcellen te krijgen.
=B5-TRUNC(B5)
Getal splitsen op decimaal met Tekst naar kolommen
Je kunt de functie Tekst naar kolommen gebruiken om een getal op decimaal te splitsen in Excel.
1. Selecteer het bereik van getalcellen dat je wilt splitsen op decimaal en klik op Gegevens > Tekst naar kolommen.
2. In het dialoogvenster Tekst naar kolommen wizard – Stap1 van3 selecteer je de optie Gescheiden en klik je op de knop Volgende.
3. In het dialoogvenster Stap2 van3 vink je alleen het vakje Overig aan, voer je een punt in het tekstvak in en klik je op de knop Volgende.
4. In de Stap3 van3 dialoogvenster, klik op de 
knop om een bestemmingscel te selecteren om de gesplitste gehele en decimale delen te plaatsen en klik ten slotte op de Voltooien knop. Zie schermafbeelding:
Daarna zie je dat de gehele en decimale delen uit de geselecteerde cellen zijn gesplitst zoals te zien in de onderstaande schermafbeelding. Let op: het decimale deel verliest het negatieve teken, wat mogelijk nodig is voor de gebruiker.
Getal splitsen op decimaal met Flash Fill (2013 en latere versies)
In het bovenstaande voorbeeld hebben we het gebruik van de functie Flash Fill geïntroduceerd om tekst en getallen in cellen te splitsen. Hier laten we dezelfde methode zien om een getal op decimaal te splitsen.
1. Voer een paar voorbeelden in. In dit geval voeren we het gehele deel van B5 in C5 in en het gehele deel van B6 in C6. Zie schermafbeelding:
Opmerking: Vergeet bij negatieve getallen niet het minteken mee te nemen.
3. Selecteer de cellen met de ingevoerde voorbeelden in de kolom die je wilt invullen, klik op Gegevens > Flash Fill.
Daarna worden de gehele delen uit de opgegeven getalcellen gehaald zoals te zien in de onderstaande schermafbeelding.
4. Herhaal bovenstaande stappen om de decimalen uit dezelfde getalcellen te splitsen.
3. Datumcellen splitsen
Een andere veelvoorkomende situatie is het splitsen van datumcellen. Als je datumcellen wilt splitsen in aparte dag, maand en jaar, of datumcellen wilt splitsen in aparte datum en tijd, gebruik dan de onderstaande oplossing afhankelijk van je behoefte.
Voorbeeld #1 Datumcellen splitsen in aparte dag, maand en jaar
Stel dat je een lijst met datums hebt in bereik B5:B9 en elke datumwaarde wilt splitsen in drie aparte kolommen voor dag, maand en jaar. Hier zijn drie methoden om het resultaat te bereiken.
Datumcellen splitsen in dag, maand en jaar met formules
Je kunt drie formules gebruiken op basis van de DATUM functie, MAAND functie en JAAR functie om een datum te splitsen in aparte dag, maand en jaar in Excel.
Algemene formules
=DATE(A1)
=MONTH(A1)
=YEAR(A1)
Argument
1. Maak drie kolommen om de aparte dag, maand en jaar te plaatsen.
2. Selecteer de eerste cel in de kolom Dag, voer onderstaande formule in en druk op Enter om de dag van de eerste datumcel (B5) te krijgen. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de dagen van andere datumcellen te krijgen.
=DAY(B5)
3. Voer dezelfde handeling uit als stap1 om de volgende formules toe te passen in de kolommen Maand en Jaar om de aparte maand en jaar uit de datumcellen te krijgen.
De maand van een datum ophalen
=MONTH(B5)
Het jaar van een datum ophalen
=YEAR(B5)
Datumcellen splitsen in dag, maand en jaar met Tekst naar kolommen
Je kunt de bovenstaande stappen volgen om de functie Tekst naar kolommen toe te passen om datumcellen te splitsen in aparte dag, maand en jaar in Excel.
Opmerking: In het dialoogvenster Stap2 van3 vink je alleen het vakje Overig aan en typ je een /-symbool in het tekstvak.
Datumcellen splitsen in dag, maand en jaar met een handig hulpmiddel
De onderstaande demo laat zien hoe je een datum in aparte maand, dag en jaar splitst met de functie Cellen splitsen van Kutools voor Excel.
Met deze functie kun je het resultaat van datums splitsen in bulk bereiken met slechts enkele klikken.
Klik voor meer informatie over deze functie.
Kutools voor Excel - Boost Excel met meer dan 300 essentiële tools. Geniet van permanent gratis AI-functies! Nu verkrijgen
Voorbeeld #2 Datum en tijd splitsen in een cel
Stel dat er een lijst met datum en tijd is in B5:B9 en je wilt de datums en tijden in aparte kolommen splitsen. In deze sectie worden verschillende manieren getoond om dit te doen.
Datum en tijd splitsen in een cel met formule
Je kunt de volgende formules gebruiken om datum en tijd in verschillende kolommen te splitsen in Excel.
1. Maak twee kolommen om de datums en tijden te plaatsen.
2. Je moet de datumkolom instellen op het formaat Datum en de tijdkolom op het formaat Tijd.
3. Selecteer de eerste cel in de Datum kolom, voer onderstaande formule in en druk op Enter om de datum van B5 te krijgen. Selecteer deze resultaatcel en sleep de vulgreep naar beneden om de andere datums te krijgen.
=INT(B5)
4. Pas de volgende formule toe in de kolom Tijd om de tijden in B5:B9 te krijgen.
=B5-D5
Datum en tijd splitsen in een cel met Flash Fill (2013 en latere versies)
Als je Excel2013 of een latere versie gebruikt, kun je de ingebouwde functie Flash Fill gebruiken om datum en tijd in verschillende kolommen te splitsen.
1. Maak de kolommen Datum en Tijd aan en voer een paar voorbeelden in zoals je wilt dat het resultaat eruitziet. In de kolom Datum voeren we de datum van B5 in C5 in en de datum van B6 in C6. In de kolom Tijd voeren we de tijd van B5 in D5 in en de tijd van B6 in D6. Zie schermafbeelding:
2. Selecteer de kolom Datum (inclusief de voorbeelden) die je wilt invullen, klik op Gegevens > Flash Fill.
3. Selecteer de kolom Tijd (inclusief de voorbeelden) die je wilt invullen en schakel ook de functie Flash Fill in. Daarna worden de datums en tijden in B5:B9 gesplitst in aparte kolommen zoals te zien in de onderstaande demo.
Nu heb je geleerd hoe je cellen in Excel kunt splitsen met verschillende methoden in verschillende situaties. Je kunt nu de beste keuze maken afhankelijk van jouw specifieke scenario.
Beste productiviteitstools voor Office
Verbeter je Excel-vaardigheden met Kutools voor Excel en ervaar ongeëvenaarde efficiëntie. Kutools voor Excel biedt meer dan300 geavanceerde functies om je productiviteit te verhogen en tijd te besparen. Klik hier om de functie te kiezen die je het meest nodig hebt...
Office Tab brengt een tabbladinterface naar Office en maakt je werk veel eenvoudiger
- Activeer tabbladbewerking en -lezen in Word, Excel, PowerPoint, Publisher, Access, Visio en Project.
- Open en maak meerdere documenten in nieuwe tabbladen van hetzelfde venster, in plaats van in nieuwe vensters.
- Verhoog je productiviteit met50% en bespaar dagelijks honderden muisklikken!
Alle Kutools-invoegtoepassingen. Eén installatieprogramma
Kutools for Office-suite bundelt invoegtoepassingen voor Excel, Word, Outlook & PowerPoint plus Office Tab Pro, ideaal voor teams die werken met Office-toepassingen.
- Alles-in-één suite — invoegtoepassingen voor Excel, Word, Outlook & PowerPoint + Office Tab Pro
- Eén installatieprogramma, één licentie — in enkele minuten geïnstalleerd (MSI-ready)
- Werkt beter samen — gestroomlijnde productiviteit over meerdere Office-toepassingen
- 30 dagen volledige proef — geen registratie, geen creditcard nodig
- Beste prijs — bespaar ten opzichte van losse aanschaf van invoegtoepassingen