Hoe het aantal pagina's in Pdf-bestanden te tellen met behulp van Excel?

Als je meerdere PDF-bestanden in een map hebt en hun bestandsnamen samen met de paginatelling in Excel wilt weergeven, kun je dit eenvoudig doen met een eenvoudige VBA-macro. Deze handleiding leidt je door de stappen om snel de PDF-bestandsnamen en hun bijbehorende paginanummers in een Excel-werkblad te extraheren en weer te geven.

PDF-bestandsnamen en paginanummers weergeven in Excel met VBA

PDF-bestandsnamen en paginanummers weergeven in Excel met VBA

De volgende VBA-code kan je helpen om alle PDF-bestandsnamen en hun paginanummers in een werkblad weer te geven. Volg deze stappen:

1. Open een werkblad waar je de Pdf-bestanden en paginanummers wilt ophalen.

2. Houd de toetsen "ALT" + "F11" ingedrukt, en er opent zich een venster met de naam "Microsoft Visual Basic for Applications".

3. Klik op "Invoegen" > "Module", en plak de volgende macro in het "Module"-venster.

VBA-code: Lijst met alle Pdf-bestandsnamen en paginanummers in werkblad:

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. Nadat je de code hebt geplakt, druk dan op de toets "F5" om de code uit te voeren. Er verschijnt een "Bladeren"-venster. Selecteer de map die de Pdf-bestanden bevat die je wilt weergeven en de paginanummers wilt tellen, zie screenshot:

5. Klik vervolgens op de knop "OK", alle Pdf-bestandsnamen en paginanummers worden weergegeven in het huidige werkblad, zie screenshot: