Hoe een enkele of alle grafieken uit Excel-werkbladen naar PowerPoint exporteren?

Soms moet u mogelijk een grafiek of alle grafieken uit Excel naar PowerPoint exporteren voor een bepaald doel. Dit artikel gaat over hoe u dit kunt bereiken.

Exporteer een enkele grafiek of alle grafieken vanuit een Excel-werkblad naar PowerPoint met VBA-code

Exporteer een enkele grafiek of alle grafieken vanuit een Excel-werkblad naar PowerPoint met VBA-code

In deze sectie worden VBA-codes geïntroduceerd om een enkele grafiek of alle grafieken uit het werkboek naar PowerPoint te exporteren. Volg de onderstaande stappen.

1. Druk tegelijk op de toetsen Alt + F11 om het venster Microsoft Visual Basic for Applications te openen.

2. Klik in het venster Microsoft Visual Basic for Applications op Tools > References zoals in de onderstaande schermafbeelding te zien is.

3. Schuif in het dialoogvenster References – VBAProject omlaag om de optie Microsoft PowerPoint Object Library te vinden en aan te vinken, en klik vervolgens op de knop OK. Zie schermafbeelding:

4. Klik vervolgens op Insert > Module.

5. Als u een enkele grafiek naar PowerPoint wilt exporteren, selecteert u de grafiek in het werkblad, ga terug naar het venster Microsoft Visual Basic for Applications, kopieer en plak de onderstaande VBA-code in het Module-venster.

VBA-code: Exporteer een enkele grafiek vanuit een Excel-werkblad naar PowerPoint

Sub SingleActiveChartToPowerPoint_EarlyBinding1()
'Updated by Extendoffice 2017/9/15
  Dim pptApp As PowerPoint.Application
  Dim pptPres As PowerPoint.Presentation
  Dim pptSlide As PowerPoint.Slide
  Dim pptShape As PowerPoint.Shape
  Dim pptShpRng As PowerPoint.ShapeRange
  Dim xActiveSlideNow As Long
  On Error Resume Next
  If ActiveChart Is Nothing Then
    MsgBox "Select a chart and try again!", vbExclamation, "KuTools For Excel"
    Exit Sub
  End If
  Set pptApp = GetObject(, "PowerPoint.Application")
  If pptApp Is Nothing Then
    Set pptApp = CreateObject("PowerPoint.Application")
    Set pptPres = pptApp.Presentations.Add
    Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
  Else
    If pptApp.Presentations.Count > 0 Then
      Set pptPres = pptApp.ActivePresentation
      If pptPres.Slides.Count > 0 Then
        xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
        Set pptSlide = pptPres.Slides(xActiveSlideNow)
      Else
        Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
      End If
    Else
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    End If
  End If
  ActiveChart.ChartArea.Copy
  With pptSlide
    .Shapes.Paste
    Set pptShape = .Shapes(.Shapes.Count)
    Set pptShpRng = .Shapes.Range(pptShape.Name)
  End With
  With pptShpRng
    .Align msoAlignCenters, True
    .Align msoAlignMiddles, True
  End With
  pptShpRng.Select
End Sub

Als u alle grafieken uit het werkboek wilt exporteren, kopieert en plakt u de onderstaande VBA-code in het Module-venster.

VBA-code: Exporteer alle grafieken vanuit Excel-werkbladen naar PowerPoint

Option Explicit
'Updated by Extendoffice 2017/9/15
Dim pptApp As PowerPoint.Application
Dim pptPres As PowerPoint.Presentation
Dim pptSlide As PowerPoint.Slide
Dim pptSlideCount As Integer
Sub ChartsToPowerPoint()
    Dim xSheet As Worksheet
    Dim xChartsCount As Integer
    Dim xChart As Object
    Dim xActiveSlideNow As Integer
    On Error Resume Next
    For Each xSheet In ActiveWorkbook.Worksheets
        xChartsCount = xChartsCount + xSheet.ChartObjects.Count
    Next xSheet
    If xChartsCount = 0 Then
        MsgBox "Sorry, there are no charts to export!", vbCritical, "Ops"
        Exit Sub
    End If
    Set pptApp = GetObject(, "PowerPoint.Application")
    If pptApp Is Nothing Then
      Set pptApp = CreateObject("PowerPoint.Application")
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    Else
        If pptApp.Presentations.Count > 0 Then
          Set pptPres = pptApp.ActivePresentation
          If pptPres.Slides.Count > 0 Then
            xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
            Set pptSlide = pptPres.Slides(xActiveSlideNow)
          Else
            Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
          End If
        Else
          Set pptPres = pptApp.Presentations.Add
          Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
        End If
    End If
    For Each xSheet In ActiveWorkbook.Worksheets
        For Each xChart In xSheet.ChartObjects
            Call pptFormat(xChart.Chart)
        Next xChart
    Next xSheet
    For Each xChart In ActiveWorkbook.Charts
        Call pptFormat(xChart)
    Next xChart
    
    Set pptSlide = Nothing
    Set pptPres = Nothing
    Set pptApp = Nothing
    MsgBox "The charts were copied successfully to the new presentation!", vbInformation, "KuTools For Excel"
End Sub
Private Sub pptFormat(xChart As Chart)
    Dim xCharTiTle As String
    Dim I As Integer
    On Error Resume Next
    xCharTiTle = xChart.ChartTitle.Text
    xChart.ChartArea.Copy
    pptSlideCount = pptPres.Slides.Count
    Set pptSlide = pptPres.Slides.Add(pptSlideCount + 1, ppLayoutBlank)
    pptSlide.Select
    pptSlide.Shapes.PasteSpecial ppPasteJPG
    If xCharTiTle <> "" Then
        pptSlide.Shapes.AddTextbox msoTextOrientationHorizontal, 12.5, 20, 694.75, 55.25
    End If
    For I = 1 To pptSlide.Shapes.Count
        With pptSlide.Shapes(I)
            Select Case .Type
                Case msoPicture:
                    .Top = 87.84976
                    .left = 33.98417
                    .Height = 422.7964
                    .Width = 646.5262
                Case msoTextBox:
                    With .TextFrame.TextRange
                        .ParagraphFormat.Alignment = ppAlignCenter
                        .Text = xCharTiTle
                        .Font.Name = "Tahoma (Headings)"
                        .Font.Size = 28
                        .Font.Bold = msoTrue
                    End With
                End Select
        End With
    Next I
End Sub

6. Druk op de toets F5 of klik op de knop Run om de code uit te voeren. Er wordt een nieuw PowerPoint-venster geopend waarin de geselecteerde grafiek of alle grafieken zijn geïmporteerd. U krijgt ook een Kutools for Excel-dialoogvenster te zien zoals in de onderstaande schermafbeelding. Klik op de knop OK.

Ontdek de Magie van Excel met Kutools AI

• Slimme Uitvoering: Voer celbewerkingen uit, analyseer gegevens en maak diagrammen – allemaal aangestuurd door eenvoudige commando's.
• Aangepaste Formules: Genereer op maat gemaakte formules om uw workflows te versnellen.
• VBA-codering: Schrijf en implementeer VBA-code moeiteloos.
• Formule-uitleg: Begrijp complexe formules gemakkelijk.
• Tekstvertaling: Overbrug taalbarrières binnen uw spreadsheets.

Verhoog uw Excel-mogelijkheden met AI-aangedreven tools. Download Nu en ervaar een ongekende efficiëntie!

Gerelateerde artikelen:

• Hoe meerdere/alle werkbladen opslaan of exporteren naar afzonderlijke CSV- of tekstbestanden in Excel?
• Hoe een selectie of het hele werkboek opslaan als PDF in Excel?