Hoe wijzigingen bijhouden zonder werkboek te delen?

Normaal gesproken, wanneer je de functie Wijzigingen bijhouden in Excel gebruikt, wordt het werkboek tegelijkertijd gedeeld. Dit kan vervelend zijn omdat sommige functies in Excel dan worden uitgeschakeld. Hoe kun je wijzigingen bijhouden zonder het werkboek te delen? Hier zal ik een VBA-code aanbevelen.

Wijzigingen bijhouden zonder werkboek te delen met VBA-code

Tekst omzetten naar tabel in Outlook

Er is geen directe manier om dit probleem op te lossen, maar je kunt een flexibele VBA-code gebruiken. Volg deze stappen:

1. Klik met de rechtermuisknop op het tabblad van het werkblad waarvan je de gewijzigde cellen wilt volgen, en kies Weergave Code in het contextmenu. In het venster Microsoft Visual Basic for Applications dat verschijnt, kopieer en plak de volgende code in de lege Module:

VBA-code: Wijzigingen bijhouden zonder werkboek te delen:

Private Sub Worksheet_Change(ByVal Target As Range)
  'Updateby Extendoffice
    Const xRg As String = "A1:Z1000"
    Dim strOld As String
    Dim strNew As String
    Dim strCmt As String
    Dim xLen As Long
    With Target(1)
        If Intersect(.Cells, Range(xRg)) Is Nothing Then Exit Sub
        strNew = .Text
        Application.EnableEvents = False
        Application.Undo
        strOld = .Text
        .Value = strNew
        Application.EnableEvents = True
        strCmt = "Edit: " & Format$(Now, "dd Mmm YYYY hh:nn:ss") & " by " & _
        Application.UserName & Chr(10) & "Previous Text :- " & strOld
        If Target(1).Comment Is Nothing Then
            .AddComment
        Else
            xLen = Len(.Comment.Shape.TextFrame.Characters.Text)
        End If
        With .Comment.Shape.TextFrame
            .AutoSize = True
            .Characters(Start:=xLen + 1).Insert IIf(xLen, vbLf, "") & strCmt
        End With
    End With
End Sub

Opmerking: In de bovenstaande code is A1:Z1000 het gegevensbereik waarvoor je wijzigingen wilt bijhouden.

2. Sla daarna het codevenster op en sluit het. Nu, wanneer je de waarden in een van de cellen binnen het gespecificeerde bereik wijzigt, worden de wijzigingen bijgehouden zonder het werkboek te delen. Zie screenshot: