Hoe kun je automatisch de grootte van een vorm wijzigen op basis van/afhankelijk van een bepaalde celwaarde in Excel?

Als je de grootte van een vorm automatisch wilt wijzigen op basis van de waarde van een bepaalde cel, kan dit artikel je helpen.

Automatisch de grootte van een vorm wijzigen op basis van een bepaalde celwaarde met VBA-code

Automatisch de grootte van een vorm wijzigen op basis van een bepaalde celwaarde met VBA-code

De volgende VBA-code kan je helpen om de grootte van een bepaalde vorm te wijzigen op basis van een bepaalde celwaarde in het huidige werkblad. Volg de onderstaande stappen.

1. Klik met de rechtermuisknop op het tabblad van het blad met de vorm waarvan je de grootte wilt wijzigen en klik vervolgens op Weergave Code in het rechtsklikmenu.

2. In het Microsoft Visual Basic for Applications-venster kopieer en plak je de volgende VBA-code in het Code-venster.

VBA-code: Automatisch de grootte van een vorm wijzigen op basis van een bepaalde celwaarde in Excel

Private Sub Worksheet_Change(ByVal Target As Range)
    On Error Resume Next
    If Target.Row = 2 And Target.Column = 1 Then
        Call SizeCircle("Oval 2", Val(Target.Value))
    End If
End Sub
Sub SizeCircle(Name As String, Diameter)
    Dim xCenterX As Single
    Dim xCenterY As Single
    Dim xCircle As Shape
    Dim xDiameter As Single
    On Error GoTo ExitSub
    xDiameter = Diameter
    If xDiameter > 10 Then xDiameter = 10
    If xDiameter < 1 Then xDiameter = 1
    Set xCircle = ActiveSheet.Shapes(Name)
    With xCircle
        xCenterX = .Left + (.Width / 2)
        xCenterY = .Top + (.Height / 2)
        .Width = Application.CentimetersToPoints(xDiameter)
        .Height = Application.CentimetersToPoints(xDiameter)
        .Left = xCenterX - (.Width / 2)
        .Top = xCenterY - (.Height / 2)
    End With
ExitSub:
End Sub

Opmerking: In de code is “Oval 2” de naam van de vorm waarvan je de grootte gaat wijzigen. En Rij = 2, Kolom = 1 betekent dat de grootte van vorm “Oval 2” zal veranderen met de waarde in A2. Pas deze waarden aan zoals je nodig hebt.

Om meerdere vormen automatisch te herschalen op basis van verschillende celwaarden, pas dan de onderstaande VBA-code toe.

VBA-code: Automatisch meerdere vormen herschalen op basis van verschillende gespecificeerde cellenwaarden in Excel

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim xAddress As String
    On Error Resume Next
    If Target.CountLarge = 1 Then
        xAddress = Target.Address(0, 0)
        If xAddress = "A1" Then
            Call SizeCircle("Oval 1", Val(Target.Value))
        ElseIf xAddress = "A2" Then
            Call SizeCircle("Smiley Face 3", Val(Target.Value))
        ElseIf xAddress = "A3" Then
            Call SizeCircle("Heart 2", Val(Target.Value))
        End If
    End If
End Sub

Sub SizeCircle(Name As String, Diameter)
    Dim xCenterX As Single
    Dim xCenterY As Single
    Dim xCircle As Shape
    Dim xDiameter As Single
    On Error GoTo ExitSub
    xDiameter = Diameter
    If xDiameter > 10 Then xDiameter = 10
    If xDiameter < 1 Then xDiameter = 1
    Set xCircle = ActiveSheet.Shapes(Name)
    With xCircle
        xCenterX = .Left + (.Width / 2)
        xCenterY = .Top + (.Height / 2)
        .Width = Application.CentimetersToPoints(xDiameter)
        .Height = Application.CentimetersToPoints(xDiameter)
        .Left = xCenterX - (.Width / 2)
        .Top = xCenterY - (.Height / 2)
    End With
ExitSub:
End Sub

Opmerkingen:

3. Druk gelijktijdig op Alt + Q toetsen om het Microsoft Visual Basic for Applications-venster te sluiten.

Vanaf nu zal, wanneer je de waarde in cel A2 wijzigt, de grootte van vorm Oval 2 automatisch veranderen. Zie screenshot:

Of wijzig de waarden in cel A1, A2 en A3 om de bijbehorende vormen "Oval 1", "Smiley Face 3" en "Heart 3" automatisch te herschalen. Zie screenshot:

Opmerking: De grootte van de vorm zal niet langer veranderen wanneer de celwaarde groter is dan 10.

Gerelateerde artikelen:

• Hoe voeg je een muis-over tip toe aan een bepaalde vorm in Excel?
• Hoe vul je een vorm met een transparante achtergrondkleur in Excel?
• Hoe verberg je of maak je een bepaalde vorm zichtbaar op basis van een bepaalde celwaarde in Excel?